I_InsurApplContrSubCvrgDcbl

@EndUserText.label: 'SubCoverage Dcbl of Contr in Insur Appl'
@VDM: {
  viewType:#COMPOSITE,
  lifecycle.contract.type:#PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   representativeKey: 'InsurPlcyDeductibleID',
   semanticKey: [ 'InsurPlcyDeductibleID' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #D,
     sizeCategory:   #XL
   },
   supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE ]
}
@Metadata: {
  allowExtensions:false,
  ignorePropagatedAnnotations:false
}
@Analytics: {
  technicalName: 'IAConSubCvrgDcbl'
}

define view entity I_InsurApplContrSubCvrgDcbl
  as select from P_InsurPolicyJournalKeys   as PlcyJrnl
    inner join   I_InsurPlcyDeductibleBasic as Deductible on  PlcyJrnl.InsurPlcyUUID                  =  Deductible.InsurPlcyUUID
                                                          and PlcyJrnl.InsurPlcyInsurContr            =  Deductible.InsurPlcyInsurContr
                                                          and PlcyJrnl.InsurPlcyContrDataDetnJrnlNmbr >= Deductible.InsurPlcyJrnlNmbr
                                                          and PlcyJrnl.InsurPlcyContrDataDetnJrnlNmbr <  Deductible.InsurPlcyJrnlEndNmbr

  association        to parent I_InsurApplContrCvrgSubCvrg as _InsurApplContrCvrgSubCvrg   on  $projection.InsurPlcyUUID                  = _InsurApplContrCvrgSubCvrg.InsurPlcyUUID
                                                                                           and $projection.InsurPlcyInsurContr            = _InsurApplContrCvrgSubCvrg.InsurPlcyInsurContr
                                                                                           and $projection.InsurPlcyCoveragePackageID     = _InsurApplContrCvrgSubCvrg.InsurPlcyCoveragePackageID
                                                                                           and $projection.InsurPlcyCoverageID            = _InsurApplContrCvrgSubCvrg.InsurPlcyCoverageID
                                                                                           and $projection.InsurPlcySubCvrgID             = _InsurApplContrCvrgSubCvrg.InsurPlcySubCvrgID
                                                                                           and $projection.InsurPlcyContrDataDetnJrnlNmbr = _InsurApplContrCvrgSubCvrg.InsurPlcyContrDataDetnJrnlNmbr

  association [1..1] to I_Currency                         as _Currency                    on  $projection.InsurPlcyDeductibleCurrency = _Currency.Currency
  association [1..*] to I_InsurPlcyTemplateT               as _InsurPlcyTemplateT          on  $projection.InsurPlcyDeductibleTemplate = _InsurPlcyTemplateT.InsurPlcyTemplate
  association [0..1] to I_InsurPlcyDcblAmountUnitLink      as _InsurPlcyDcblAmountUnit     on  $projection.InsurPlcyDeductibleAmountUnit = _InsurPlcyDcblAmountUnit.InsurPlcyDeductibleAmountUnit
                                                                                           and $projection.InsurPlcyDeductibleTemplate   = _InsurPlcyDcblAmountUnit.InsurPlcyDeductibleTemplate
  association [0..1] to I_InsurPlcyDcblCategoryLink        as _InsurPlcyDeductibleCategory on  $projection.InsurPlcyDeductibleCategory = _InsurPlcyDeductibleCategory.InsurPlcyDeductibleCategory
                                                                                           and $projection.InsurPlcyDeductibleTemplate = _InsurPlcyDeductibleCategory.InsurPlcyDeductibleTemplate

{

  key Deductible.InsurPlcyUUID,
  key Deductible.InsurPlcyInsurContr,
  key Deductible.InsurPlcyCoveragePackageID,
  key Deductible.InsurPlcyCoverageID,
  key Deductible.InsurPlcyInsuredObjectID,
  key Deductible.InsurPlcySubCvrgID,
  key Deductible.InsurPlcyDeductibleID,
  key cast( PlcyJrnl.InsurPlcyContrDataDetnJrnlNmbr as /pm0/vdm_contr_detn_jrnlnmbr preserving type ) as InsurPlcyContrDataDetnJrnlNmbr,
      Deductible.InsurPlcyJrnlNmbr,
      Deductible.InsurPlcyJrnlEndNmbr,
      @Consumption.hidden: true
      Deductible.InsurPlcyProductPackageID,
      @ObjectModel.text.association: '_InsurPlcyDeductibleCategory'
      Deductible.InsurPlcyDeductibleCategory,
      @Semantics.amount.currencyCode: 'InsurPlcyDeductibleCurrency'
      Deductible.InsurPlcyDeductibleAmount,
      Deductible.InsurPlcyDeductibleStartDate,
      Deductible.InsurPlcyDeductibleEndDate,
      @ObjectModel.text.association: '_InsurPlcyTemplateT'
      Deductible.InsurPlcyDeductibleTemplate,
      @ObjectModel.foreignKey.association: '_Currency'
      Deductible.InsurPlcyDeductibleCurrency,
      @ObjectModel.text.association: '_InsurPlcyDcblAmountUnit'
      Deductible.InsurPlcyDeductibleAmountUnit,
      Deductible.InsurPlcyDeductibleValue,
      @Semantics.systemDateTime.lastChangedAt: true
      Deductible.LastChangeDateTime,

      /* Associations */
      _InsurApplContrCvrgSubCvrg,
      @Consumption.hidden: true
      _InsurPlcyDeductibleCategory,
      @Consumption.hidden: true
      _Currency,
      @Consumption.hidden: true
      _InsurPlcyDcblAmountUnit,
      @Consumption.hidden: true
      _InsurPlcyTemplateT

}
where
      Deductible.InsurPlcyCoveragePackageID =  0
  and Deductible.InsurPlcyInsuredObjectID   =  0
  and Deductible.InsurPlcyCoverageID        <> 0
  and Deductible.InsurPlcySubCvrgID         <> 0
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSURPLCYDEDUCTIBLEBASIC",
"P_INSURPOLICYJOURNALKEYS"
],
"ASSOCIATED":
[
"I_CURRENCY",
"I_INSURAPPLCONTRCVRGSUBCVRG",
"I_INSURPLCYDCBLAMOUNTUNITLINK",
"I_INSURPLCYDCBLCATEGORYLINK",
"I_INSURPLCYTEMPLATET"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/