I_InsurApplContrSubCvrgClause

@EndUserText.label: 'SubCoverage Clause of Contr in Appl'
@VDM: {
  viewType:#COMPOSITE,
  lifecycle.contract.type:#PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   representativeKey: 'InsurPlcyClauseID',
   semanticKey: [ 'InsurPlcyClauseID' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #D,
     sizeCategory:   #XL
   },
   supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE ]
}
@Metadata: {
  allowExtensions:false,
  ignorePropagatedAnnotations:false
}
@Analytics: {
  technicalName: 'IACoSubCvrgCls'
}
define view entity I_InsurApplContrSubCvrgClause
  as select from P_InsurPolicyJournalKeys as PlcyJrnl
    inner join   I_InsurPlcyClauseBasic   as Clause on  PlcyJrnl.InsurPlcyUUID                  =  Clause.InsurPlcyUUID
                                                    and PlcyJrnl.InsurPlcyInsurContr            =  Clause.InsurPlcyInsurContr
                                                    and PlcyJrnl.InsurPlcyContrDataDetnJrnlNmbr >= Clause.InsurPlcyJrnlNmbr
                                                    and PlcyJrnl.InsurPlcyContrDataDetnJrnlNmbr <  Clause.InsurPlcyJrnlEndNmbr
  
    left outer to one join I_InsurPlcyClauseLongTxtBasic as LongText on Clause.InsurPlcyClauseDetailTextUUID = LongText.InsurPlcyClauseDetailTextUUID
                                                    
  association        to parent I_InsurApplContrCvrgSubCvrg as _InsurApplContrCvrgSubCvrg on  $projection.InsurPlcyUUID                  = _InsurApplContrCvrgSubCvrg.InsurPlcyUUID
                                                                                         and $projection.InsurPlcyInsurContr            = _InsurApplContrCvrgSubCvrg.InsurPlcyInsurContr
                                                                                         and $projection.InsurPlcyCoveragePackageID     = _InsurApplContrCvrgSubCvrg.InsurPlcyCoveragePackageID
                                                                                         and $projection.InsurPlcyCoverageID            = _InsurApplContrCvrgSubCvrg.InsurPlcyCoverageID
                                                                                         and $projection.InsurPlcySubCvrgID             = _InsurApplContrCvrgSubCvrg.InsurPlcySubCvrgID
                                                                                         and $projection.InsurPlcyContrDataDetnJrnlNmbr = _InsurApplContrCvrgSubCvrg.InsurPlcyContrDataDetnJrnlNmbr

  association [1..1] to I_InsurPlcyClauseTypeLink          as _InsurancePolicyClauseType on  $projection.InsurPlcyClauseType     = _InsurancePolicyClauseType.InsurPlcyClauseType
                                                                                         and $projection.InsurPlcyClauseTemplate = _InsurancePolicyClauseType.InsurPlcyClauseTemplate
  association [1..*] to I_InsurPlcyTemplateT               as _InsurPlcyTemplateT        on  $projection.InsurPlcyClauseTemplate = _InsurPlcyTemplateT.InsurPlcyTemplate

{

  key Clause.InsurPlcyUUID,
  key Clause.InsurPlcyInsurContr,
  key Clause.InsurPlcyCoveragePackageID,
  key Clause.InsurPlcyCoverageID,
  key Clause.InsurPlcySubCvrgID,
  key Clause.InsurPlcyInsuredObjectID,
  key Clause.InsurPlcyClauseID,
  key cast( PlcyJrnl.InsurPlcyContrDataDetnJrnlNmbr as /pm0/vdm_contr_detn_jrnlnmbr preserving type ) as InsurPlcyContrDataDetnJrnlNmbr,
      Clause.InsurPlcyJrnlNmbr,
      Clause.InsurPlcyJrnlEndNmbr,
      @Consumption.hidden: true
      Clause.InsurPlcyProductPackageID,
      @ObjectModel.text.association: '_InsurPlcyTemplateT'
      Clause.InsurPlcyClauseTemplate,
      Clause.InsurPlcyIndivClauseAgrmtText,
      Clause.InsurPlcyClauseDetailTextUUID,
      LongText.LongText,
      LongText.TextObjectCategory,
      LongText.TextObjectKey,
      LongText.Language,
      @ObjectModel.foreignKey.association: '_InsurancePolicyClauseType'
      Clause.InsurPlcyClauseType,
      @Semantics.businessDate.from: true
      Clause.InsurPlcyClauseStartDate,
      @Semantics.businessDate.to: true
      Clause.InsurPlcyClauseEndDate,
      @Semantics.systemDateTime.lastChangedAt: true
      Clause.LastChangeDateTime,

      /* Associations */
      _InsurApplContrCvrgSubCvrg,
      @Consumption.hidden: true
      _InsurancePolicyClauseType,
      @Consumption.hidden: true
      _InsurPlcyTemplateT

}
where
      Clause.InsurPlcyCoveragePackageID =  0
  and Clause.InsurPlcyCoverageID        <> 0
  and Clause.InsurPlcySubCvrgID         <> 0
  and Clause.InsurPlcyInsuredObjectID   =  0
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSURPLCYCLAUSEBASIC",
"I_INSURPLCYCLAUSELONGTXTBASIC",
"P_INSURPOLICYJOURNALKEYS"
],
"ASSOCIATED":
[
"I_INSURAPPLCONTRCVRGSUBCVRG",
"I_INSURPLCYCLAUSETYPELINK",
"I_INSURPLCYTEMPLATET"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/