I_InspectionSubsetTP_2

@AbapCatalog.sqlViewName: 'IINSPSUBSETTP2'
@AbapCatalog.compiler.compareFilter: true
@AccessControl: {
    authorizationCheck: #CHECK,
    personalData.blocking: #REQUIRED
}
@EndUserText.label: 'Inspection Subset 2'
@Metadata.ignorePropagatedAnnotations: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM: { viewType: #TRANSACTIONAL,
        lifecycle.contract.type: #SAP_INTERNAL_API } // Shall be set for #TRANSACTIONAL views

@ObjectModel: {
    semanticKey: ['InspectionLot','InspPlanOperationInternalID','InspectionSubsetInternalID'],
    compositionRoot: true,
    sapObjectNodeType.name: 'InspectionLot',
    createEnabled: true,
    updateEnabled: true,
    deleteEnabled: false,                               // Assume: Inspection Subsets shall never be deleted

    transactionalProcessingEnabled: true, 
    draftEnabled: false,                                // No draft, only 'active persistence'

    writeActivePersistence: 'VQAPP_ACTIVE', 
    entityChangeStateId: 'ChangedDateTime',
    lifecycle.enqueue: {
        expiryBehavior: #RELATIVE_TO_LAST_CHANGE,       // Default #RELATIVE_TO_LAST_CHANGE

        expiryInterval: 'PT15M'                         // Default 'PT15M'

    },
    lifecycle.processing: {
        expiryBehavior: #RELATIVE_TO_LAST_CHANGE,       // Default #RELATIVE_TO_LAST_CHANGE

        expiryInterval: 'PT30M'                         // Default 'PT30M'

    },
   
    usageType: { dataClass: #TRANSACTIONAL, sizeCategory: #L, serviceQuality: #C }
}

define view I_InspectionSubsetTP_2 as select from I_InspectionSubset 
           inner join I_InspectionLot as _InspLot                          on  I_InspectionSubset.InspectionLot               = _InspLot.InspectionLot
           inner join I_InspectionOperation as _InspOper                   on  I_InspectionSubset.InspectionLot               = _InspOper.InspectionLot 
                                                                           and I_InspectionSubset.InspPlanOperationInternalID = _InspOper.InspPlanOperationInternalID

  //Extension  

  association [1..1] to E_InspectionSubset   as _Extension                 on  $projection.InspectionLot                      = _Extension.InspectionLot
                                                                           and $projection.InspPlanOperationInternalID        = _Extension.InspPlanOperationInternalID
                                                                           and $projection.InspectionSubsetInternalID         = _Extension.InspectionSubsetInternalID
{

  key I_InspectionSubset.InspectionLot, 
  key I_InspectionSubset.InspPlanOperationInternalID, 
  key I_InspectionSubset.InspectionSubsetInternalID, 
  I_InspectionSubset.MaterialSample, 
  I_InspectionSubset.Equipment, 
  I_InspectionSubset.FunctionalLocation, 
  I_InspectionSubset.ShopFloorItem, 
  I_InspectionSubset.SelectedCodeSetPlant, 
  I_InspectionSubset.SelectedCodeSet, 
  I_InspectionSubset.InspSubsetUsageDcsnCodeGroup, 
  I_InspectionSubset.InspSubsetUsageDcsnCode, 
  @ObjectModel.readOnly: true   
  I_InspectionSubset.InspSubsetUsageDcsnValuation, 

//  initial time leads to SADL error - fiels is empty if type NE time 

// -> changing from NULL to 000000 does not matter

  case when InspectionSubsetTime < '000001'
       then cast( '000000' as vdm_qusrtims )
       else InspectionSubsetTime                      
  end as InspectionSubsetTime,    
  
  I_InspectionSubset.InspectionSubsetDate, 
  I_InspectionSubset.InspSubsetLongNumericKey, 
  I_InspectionSubset.InspSubsetShortNumericKey, 
  I_InspectionSubset.InspectionSubsetLongCharKey, 
  I_InspectionSubset.InspectionSubsetShortCharKey, 
  I_InspectionSubset.InspectionPartialLot, 
  I_InspectionSubset.Inspector,

  @Semantics.quantity.unitOfMeasure: 'InspectionSubsetQtyUnit'
  I_InspectionSubset.InspectionSubsetYieldQty, 
  @Semantics.quantity.unitOfMeasure: 'InspectionSubsetQtyUnit'
  I_InspectionSubset.InspectionSubsetScrapQty, 
  @Semantics.quantity.unitOfMeasure: 'InspectionSubsetQtyUnit'
  I_InspectionSubset.InspectionSubsetReworkQty, 
  @ObjectModel.foreignKey.association: '_Unit'
  @Semantics.unitOfMeasure: true
  I_InspectionSubset.InspectionSubsetQtyUnit, 
  
  @ObjectModel.readOnly: true
  I_InspectionSubset.InspSbstEquipProperty, 
  @ObjectModel.readOnly: true
  I_InspectionSubset.InspSbstFuncnlLocProperty, 
  @ObjectModel.readOnly: true
  I_InspectionSubset.InspSbstMatlSmplProperty, 
  @ObjectModel.readOnly: true
  I_InspectionSubset.InspectionSubsetSortKey, 
  @ObjectModel.readOnly: true
  I_InspectionSubset.InspSbstTimeFldProperty, 
  @ObjectModel.readOnly: true
  I_InspectionSubset.InspSbstDateFldProperty, 
  @ObjectModel.readOnly: true
  I_InspectionSubset.InspSbstLongNmbrFldProperty, 
  @ObjectModel.readOnly: true
  I_InspectionSubset.InspSbstShrtNmbrFldProperty, 
  @ObjectModel.readOnly: true
  I_InspectionSubset.InspSbstLongTxtFldProperty, 
  @ObjectModel.readOnly: true
  I_InspectionSubset.InspSbstShrtTxtFldProperty, 
   
  @ObjectModel.readOnly: true
  I_InspectionSubset.CreatedByUser, 
  @ObjectModel.readOnly: true
  I_InspectionSubset.CreationDate, 
  @ObjectModel.readOnly: true
  I_InspectionSubset.CreationTime, 
  @ObjectModel.readOnly: true
  I_InspectionSubset.LastChangedByUser, 
  @ObjectModel.readOnly: true
  I_InspectionSubset.LastChangeDate, 
  @ObjectModel.readOnly: true
  I_InspectionSubset.LastChangeTime, 
  @ObjectModel.readOnly: true
  I_InspectionSubset.ChangedDateTime,  //eTag


  @Consumption.hidden: true
  _InspLot.Plant,
  @Consumption.hidden: true
  _InspOper._WorkCenter.WorkCenter,
  @Consumption.hidden: true
  _InspLot.InspectionLotType,
  @Consumption.hidden: true
  _InspLot.InspectionSubsetType,
  @Consumption.hidden: true
  _InspLot.MatlQualityAuthorizationGroup,
  @Consumption.hidden: true
  _InspLot.IsBusinessPurposeCompleted, 
  
  I_InspectionSubset._Unit as _Unit
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSPECTIONLOT",
"I_INSPECTIONOPERATION",
"I_INSPECTIONSUBSET",
"I_WORKCENTER"
],
"ASSOCIATED":
[
"E_INSPECTIONSUBSET",
"I_UNITOFMEASURE"
],
"BASE":
[
"I_INSPECTIONSUBSET"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/