I_InspectionPartialLot

@AbapCatalog.sqlViewName: 'IINSPPARTIALLOT'
@AbapCatalog.compiler.compareFilter:true
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Partial Inspection Lot'
@VDM: {
    viewType: #BASIC,
    lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@ObjectModel.supportedCapabilities:
  [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]
@ObjectModel.representativeKey: 'InspectionPartialLot'
@ObjectModel.usageType: {
    dataClass: #MASTER,
    sizeCategory: #M, //expected number of rows < 100.000

    serviceQuality: #A 
}

define view I_InspectionPartialLot as select from qalt 

    association [1..1] to I_InspectionLot as _InspectionLot
      on $projection.InspectionLot = _InspectionLot.InspectionLot
   
   //Extension      

    association [1..1] to E_InspectionPartialLot as _Extension        
        on $projection.InspectionLot = _Extension.InspectionLot
        and $projection.InspectionPartialLot = _Extension.InspectionPartialLot

{
    @ObjectModel.foreignKey.association: '_InspectionLot'
    key qalt.prueflos as InspectionLot,
    key qalt.teillos as InspectionPartialLot,
    @Semantics.text: true
    qalt.ktexttlos as InspectionPartialLotText,
    
    // Alternative Id as GUID (only filled for some inspection origin)

    qalt.partial_lot_guid as InspectionPartialLotUUID,
    
    @Semantics.systemDate.lastChangedAt: true
    qalt.aenderdat                                                  as InspPrtlLotChangeDate,
    cast( qalt.aenderzeit as vdm_qaendezeit preserving type )       as InspPrtlLotChangeTime,
    @Semantics.user.lastChangedBy: true
    qalt.aenderer                                                   as InspPrtlLotChangedBy,
    @Semantics.systemDate.createdAt: true
    qalt.ersteldat                                                  as InspPrtlLotCreatedOnDate,
    cast( qalt.erstelzeit as vdm_qerstezeit preserving type )       as InspPrtlLotCreatedOnTime,
    @Semantics.user.createdBy: true
    qalt.ersteller                                                  as InspPrtlLotCreatedBy,
        
    _InspectionLot        
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"QALT"
],
"ASSOCIATED":
[
"E_INSPECTIONPARTIALLOT",
"I_INSPECTIONLOT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/