I_InspSubsetFieldCombination

@AbapCatalog: {
    sqlViewName: 'IINSPSSFCMB',
    preserveKey: true,
    compiler.compareFilter: true
}
@EndUserText.label: 'Inspection Point Field Combination'
@ClientHandling.algorithm: #SESSION_VARIABLE
@Analytics.dataCategory: #DIMENSION
@VDM: {
    viewType: #BASIC,
    lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.supportedCapabilities:
    [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #ANALYTICAL_DIMENSION ]
@ObjectModel.modelingPattern: #NONE
@ObjectModel: {
    representativeKey: 'InspSubsetFieldCombination',
    usageType: { serviceQuality: #A, sizeCategory: #S, dataClass: #CUSTOMIZING }
}
@Metadata.ignorePropagatedAnnotations: true
define view I_InspSubsetFieldCombination
  as select from tq79
  
  association [0..1] to I_InspectionSubsetType     as _InspectionSubsetType      on $projection.InspectionSubsetType = _InspectionSubsetType.InspectionSubsetType
  association [0..1] to I_Plant                    as _SelectedCodeSetPlant      on  $projection.SelectedCodeSetPlant = _SelectedCodeSetPlant.Plant
  association [0..1] to I_UsageDcsnSelectedCodeSet as _UsageDcsnSelectedCodeSet  on $projection.SelectedCodeSetPlant = _UsageDcsnSelectedCodeSet.SelectedCodeSetPlant
                                                                                 and $projection.SelectedCodeSet = _UsageDcsnSelectedCodeSet.SelectedCodeSet
  association [0..*] to I_InspSubsetFieldCombinationT as _Text                   on $projection.InspSubsetFieldCombination = _Text.InspSubsetFieldCombination
  
{
      @ObjectModel.text.association: '_Text'
  key slwbez                                                                    as InspSubsetFieldCombination,
      @ObjectModel.foreignKey.association: '_InspectionSubsetType'
      ppkttyp                                                                   as InspectionSubsetType,
      last_valid                                                                as InspSbstFieldCombnIsLastValid,
      cast(
        case tq79.ppkttyp
          when '1' then '1'  //Equipment

          when '2' then '1'  //Functional Location

          when '3' then '2'  //Sample

          else 'X'
        end as vdm_qkzrast preserving type )                                    as SamplingProcedureInspSubset,
      userc1akt                                                                 as InspSbstLongTxtFldProperty,
      userc2akt                                                                 as InspSbstShrtTxtFldProperty,
      usern1akt                                                                 as InspSbstLongNmbrFldProperty,
      usern2akt                                                                 as InspSbstShrtNmbrFldProperty,
      userd1akt                                                                 as InspSbstDateFldProperty,
      usert1akt                                                                 as InspSbstTimeFldProperty,
      @ObjectModel.foreignKey.association: '_UsageDcsnSelectedCodeSet'
      ppvemenge                                                                 as SelectedCodeSet,
      @ObjectModel.foreignKey.association: '_SelectedCodeSetPlant'
      ppvewerk                                                                  as SelectedCodeSetPlant,
      
      // Associations

      _InspectionSubsetType,
      _SelectedCodeSetPlant,
      _UsageDcsnSelectedCodeSet,
      _Text
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"TQ79"
],
"ASSOCIATED":
[
"I_INSPECTIONSUBSETTYPE",
"I_INSPSUBSETFIELDCOMBINATIONT",
"I_PLANT",
"I_USAGEDCSNSELECTEDCODESET"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/