I_InsOpApSubCoverageDeductible

@EndUserText.label: 'SubCoverage Dcbl of CvPcg in InsOpAppl'
@VDM: {
  viewType:#COMPOSITE,
  lifecycle.contract.type:#PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   representativeKey: 'InsurPlcyDeductibleID',
   semanticKey: [ 'InsurPlcyDeductibleID' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #D,
     sizeCategory:   #XL
   },
   supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE ]
}
@Metadata: {
  allowExtensions:false,
  ignorePropagatedAnnotations:false
}
@Analytics: {
  technicalName: 'IOASubCvrgDcbl'
}
define view entity I_InsOpApSubCoverageDeductible
  as select from           I_InsurPlcyDeductibleBasic as Deductible
    left outer to one join P_InsurOpenApplDcblLatest  as OpenApplJrnl on  (
        OpenApplJrnl.InsurPlcyUUID                                                                                    = Deductible.InsurPlcyUUID
        or OpenApplJrnl.InsurPlcyApplUUID                                                                             = Deductible.InsurPlcyUUID
      )
                                                                      and OpenApplJrnl.InsurPlcyInsurContr            = Deductible.InsurPlcyInsurContr
                                                                      and OpenApplJrnl.InsurPlcyCoveragePackageID     = Deductible.InsurPlcyCoveragePackageID
                                                                      and OpenApplJrnl.InsurPlcyCoverageID            = Deductible.InsurPlcyCoverageID
                                                                      and OpenApplJrnl.InsurPlcyInsuredObjectID       = Deductible.InsurPlcyInsuredObjectID
                                                                      and OpenApplJrnl.InsurPlcySubCvrgID             = Deductible.InsurPlcySubCvrgID
                                                                      and OpenApplJrnl.InsurPlcyDeductibleID          = Deductible.InsurPlcyDeductibleID
                                                                      and OpenApplJrnl.InsurPlcyJrnlNmbr              = Deductible.InsurPlcyJrnlNmbr
                                                                      and OpenApplJrnl.InsurPlcyContrDataDetnJrnlNmbr < Deductible.InsurPlcyJrnlEndNmbr

  association        to parent I_InsurOpenApplSubCoverage as _InsurOpenApplSubCoverage    on  $projection.InsurPlcyApplUUID              = _InsurOpenApplSubCoverage.InsurPlcyApplUUID
                                                                                          and $projection.InsuranceApplication           = _InsurOpenApplSubCoverage.InsuranceApplication
                                                                                          and $projection.InsurPlcyInsurContr            = _InsurOpenApplSubCoverage.InsurPlcyInsurContr
                                                                                          and $projection.InsurPlcyCoveragePackageID     = _InsurOpenApplSubCoverage.InsurPlcyCoveragePackageID
                                                                                          and $projection.InsurPlcyCoverageID            = _InsurOpenApplSubCoverage.InsurPlcyCoverageID
                                                                                          and $projection.InsurPlcySubCvrgID             = _InsurOpenApplSubCoverage.InsurPlcySubCvrgID
                                                                                          and $projection.InsurPlcyContrDataDetnJrnlNmbr = _InsurOpenApplSubCoverage.InsurPlcyContrDataDetnJrnlNmbr
  association [1..1] to I_Currency                        as _Currency                    on  $projection.InsurPlcyDeductibleCurrency = _Currency.Currency
  association [1..*] to I_InsurPlcyTemplateT              as _InsurPlcyTemplateT          on  $projection.InsurPlcyDeductibleTemplate = _InsurPlcyTemplateT.InsurPlcyTemplate
  association [0..1] to I_InsurPlcyDcblAmountUnitLink     as _InsurPlcyDcblAmountUnit     on  $projection.InsurPlcyDeductibleAmountUnit = _InsurPlcyDcblAmountUnit.InsurPlcyDeductibleAmountUnit
                                                                                          and $projection.InsurPlcyDeductibleTemplate   = _InsurPlcyDcblAmountUnit.InsurPlcyDeductibleTemplate
  association [0..1] to I_InsurPlcyDcblCategoryLink       as _InsurPlcyDeductibleCategory on  $projection.InsurPlcyDeductibleCategory = _InsurPlcyDeductibleCategory.InsurPlcyDeductibleCategory
                                                                                          and $projection.InsurPlcyDeductibleTemplate = _InsurPlcyDeductibleCategory.InsurPlcyDeductibleTemplate

{

  key OpenApplJrnl.InsurPlcyApplUUID,
  key cast( OpenApplJrnl.InsuranceApplication as /pm0/vdm_applicationnr_tt preserving type )              as InsuranceApplication,
  key Deductible.InsurPlcyInsurContr,
  key Deductible.InsurPlcyCoveragePackageID,
  key Deductible.InsurPlcyCoverageID,
  key Deductible.InsurPlcyInsuredObjectID,
  key Deductible.InsurPlcySubCvrgID,
  key Deductible.InsurPlcyDeductibleID,
  key cast( OpenApplJrnl.InsurPlcyContrDataDetnJrnlNmbr as /pm0/vdm_contr_detn_jrnlnmbr preserving type ) as InsurPlcyContrDataDetnJrnlNmbr,
      Deductible.InsurPlcyJrnlNmbr,
      Deductible.InsurPlcyJrnlEndNmbr,
      @Consumption.hidden: true
      Deductible.InsurPlcyProductPackageID,
      OpenApplJrnl.InsurPlcyUUID,
      @ObjectModel.text.association: '_InsurPlcyDeductibleCategory'
      Deductible.InsurPlcyDeductibleCategory,
      @Semantics.amount.currencyCode: 'InsurPlcyDeductibleCurrency'
      Deductible.InsurPlcyDeductibleAmount,
      Deductible.InsurPlcyDeductibleStartDate,
      Deductible.InsurPlcyDeductibleEndDate,
      @ObjectModel.text.association: '_InsurPlcyTemplateT'
      Deductible.InsurPlcyDeductibleTemplate,
      @ObjectModel.foreignKey.association: '_Currency'
      Deductible.InsurPlcyDeductibleCurrency,
      @ObjectModel.text.association: '_InsurPlcyDcblAmountUnit'
      Deductible.InsurPlcyDeductibleAmountUnit,
      Deductible.InsurPlcyDeductibleValue,
      @Semantics.systemDateTime.lastChangedAt: true
      Deductible.LastChangeDateTime,

      /* Associations */
      _InsurOpenApplSubCoverage,
      @Consumption.hidden: true
      _InsurPlcyDeductibleCategory,
      @Consumption.hidden: true
      _Currency,
      @Consumption.hidden: true
      _InsurPlcyDcblAmountUnit,
      @Consumption.hidden: true
      _InsurPlcyTemplateT

}
where
      Deductible.InsurPlcyInsuredObjectID   =  0
  and Deductible.InsurPlcyCoveragePackageID <> 0
  and Deductible.InsurPlcyCoverageID        <> 0
  and Deductible.InsurPlcySubCvrgID         <> 0
  and OpenApplJrnl.InsurPlcyApplUUID        is not initial //Perf. Tuning: Make inner Join out of left outer Join

  and OpenApplJrnl.InsuranceApplication     is not initial
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSURPLCYDEDUCTIBLEBASIC",
"P_INSUROPENAPPLDCBLLATEST"
],
"ASSOCIATED":
[
"I_CURRENCY",
"I_INSUROPENAPPLSUBCOVERAGE",
"I_INSURPLCYDCBLAMOUNTUNITLINK",
"I_INSURPLCYDCBLCATEGORYLINK",
"I_INSURPLCYTEMPLATET"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/