I_InsOpApCoverageBonusMalus

@EndUserText.label: 'Cvrg Bn Ml of Cvrg Pckg in InsurOpenAppl'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type:#PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
  privilegedAssociations: [ '_InsOpApCvrgBonusMalusOwner' ]
}
@ObjectModel: {
   representativeKey: 'InsurPlcyBonusMalusID',
   semanticKey: [ 'InsurPlcyBonusMalusID' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #D,
     sizeCategory:   #XL
   },
   supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE ]
}
@Metadata: {
  allowExtensions:false,
  ignorePropagatedAnnotations:false
}
@Analytics: {
  technicalName: 'IOACvPckgCvBnMl'
}

define view entity I_InsOpApCoverageBonusMalus
  as select from           I_InsurPlcyBonusMalusBasic as BonusMalus
  
    left outer to one join P_InsOpApBonusMalusLatest  as OpenApplJrnl on  (
        OpenApplJrnl.InsurPlcyUUID                                                                                    = BonusMalus.InsurPlcyUUID
        or OpenApplJrnl.InsurPlcyApplUUID                                                                             = BonusMalus.InsurPlcyUUID
      )
                                                                      and OpenApplJrnl.InsurPlcyInsurContr            = BonusMalus.InsurPlcyInsurContr
                                                                      and OpenApplJrnl.InsurPlcyCoveragePackageID     = BonusMalus.InsurPlcyCoveragePackageID
                                                                      and OpenApplJrnl.InsurPlcyCoverageID            = BonusMalus.InsurPlcyCoverageID
                                                                      and OpenApplJrnl.InsurPlcyBonusMalusID          = BonusMalus.InsurPlcyBonusMalusID
                                                                      and OpenApplJrnl.InsurPlcyJrnlNmbr              = BonusMalus.InsurPlcyJrnlNmbr
                                                                      and OpenApplJrnl.InsurPlcyContrDataDetnJrnlNmbr < BonusMalus.InsurPlcyJrnlEndNmbr

  association        to parent I_InsurOpenApplCoverage as _InsurOpenApplCoverage         on  $projection.InsurPlcyApplUUID              = _InsurOpenApplCoverage.InsurPlcyApplUUID
                                                                                         and $projection.InsuranceApplication           = _InsurOpenApplCoverage.InsuranceApplication
                                                                                         and $projection.InsurPlcyInsurContr            = _InsurOpenApplCoverage.InsurPlcyInsurContr
                                                                                         and $projection.InsurPlcyCoveragePackageID     = _InsurOpenApplCoverage.InsurPlcyCoveragePackageID
                                                                                         and $projection.InsurPlcyCoverageID            = _InsurOpenApplCoverage.InsurPlcyCoverageID
                                                                                         and $projection.InsurPlcyContrDataDetnJrnlNmbr = _InsurOpenApplCoverage.InsurPlcyContrDataDetnJrnlNmbr

  composition [0..*] of I_InsOpApCvrgBonusMalusOwner as _InsOpApCvrgBonusMalusOwner
  composition [0..*] of I_InsOpApCvrgBonusMalusCert  as _InsOpApCvrgBonusMalusCert
  composition [0..*] of I_InsOpApCvrgBnMlClmSrrndr   as _InsOpApCvrgBnMlClmSrrndr
  
  association [1..1] to I_InsurPlcyIntPremiumLevelLink  as _InsurPlcyIntPremiumLevelLink on $projection.InsurPlcyIntPremiumLevel      = _InsurPlcyIntPremiumLevelLink.InsurPlcyIntPremiumLevel
                                                                                         and $projection.InsurPlcyBonusMalusTemplate  = _InsurPlcyIntPremiumLevelLink.InsurPlcyBonusMalusTemplate
  association [1..1] to I_InsurPlcyExtPremiumLevelLink  as _InsurPlcyExtPremiumLevelLink on $projection.InsurPlcyExtPremiumLevel      = _InsurPlcyExtPremiumLevelLink.InsurPlcyExtPremiumLevel
                                                                                         and $projection.InsurPlcyBonusMalusTemplate  = _InsurPlcyExtPremiumLevelLink.InsurPlcyBonusMalusTemplate                                                                                    
  association [1..1] to I_InsurPlcyBnMlOriginNameLink   as _InsurPlcyBnMlOriginNameLink  on $projection.InsurPlcyBonusMalusOrigin     = _InsurPlcyBnMlOriginNameLink.InsurPlcyBonusMalusOrigin
                                                                                         and $projection.InsurPlcyBonusMalusTemplate  = _InsurPlcyBnMlOriginNameLink.InsurPlcyBonusMalusTemplate 
  association [1..1] to I_InsurPlcyClsfctnRsnNameLink   as _InsurPlcyClsfctnRsnNameLink  on $projection.InsurPlcyClassificationReason = _InsurPlcyClsfctnRsnNameLink.InsurPlcyClassificationReason
                                                                                         and $projection.InsurPlcyBonusMalusTemplate  = _InsurPlcyClsfctnRsnNameLink.InsurPlcyBonusMalusTemplate
  association [1..1] to I_InsurPlcyBnMlPremModelLink    as _InsurPlcyBnMlPremModelLink   on $projection.InsurPlcyBnMlPremiumModel     = _InsurPlcyBnMlPremModelLink.InsurPlcyBnMlPremiumModel
                                                                                         and $projection.InsurPlcyBonusMalusTemplate  = _InsurPlcyBnMlPremModelLink.InsurPlcyBonusMalusTemplate
  association [1..1] to I_InsurPlcyBnMlCategoryLink     as _InsurPlcyBnMlCategoryLink    on $projection.InsurPlcyBonusMalusCategory   = _InsurPlcyBnMlCategoryLink.InsurPlcyBonusMalusCategory
                                                                                         and $projection.InsurPlcyBonusMalusTemplate  = _InsurPlcyBnMlCategoryLink.InsurPlcyBonusMalusTemplate                                                                                                                                                                                                                                                                        
  association [1..1] to I_InsurPlcyPrvInsRatgModelLink  as _InsurPlcyPrvInsRatgModelLink on $projection.InsurPlcyPrevInsrrRatingModel = _InsurPlcyPrvInsRatgModelLink.InsurPlcyPrevInsrrRatingModel
                                                                                         and $projection.InsurPlcyBonusMalusTemplate  = _InsurPlcyPrvInsRatgModelLink.InsurPlcyBonusMalusTemplate
  association [1..1] to I_InsurPlcyIntRatingModelLink   as _InsurPlcyIntRatingModelLink  on $projection.InsurPlcyIntRatingModel       = _InsurPlcyIntRatingModelLink.InsurPlcyIntRatingModel
                                                                                         and $projection.InsurPlcyBonusMalusTemplate  = _InsurPlcyIntRatingModelLink.InsurPlcyBonusMalusTemplate
  association [1..*] to I_InsurPlcyTemplateT            as _InsurPlcyTemplateT           on  $projection.InsurPlcyBonusMalusTemplate  = _InsurPlcyTemplateT.InsurPlcyTemplate

{

  key OpenApplJrnl.InsurPlcyApplUUID,
  key cast( OpenApplJrnl.InsuranceApplication as /pm0/vdm_applicationnr_tt preserving type )              as InsuranceApplication,
  key BonusMalus.InsurPlcyInsurContr,
  key BonusMalus.InsurPlcyCoveragePackageID,
  key BonusMalus.InsurPlcyCoverageID,
  key BonusMalus.InsurPlcyBonusMalusID,
  key cast( OpenApplJrnl.InsurPlcyContrDataDetnJrnlNmbr as /pm0/vdm_contr_detn_jrnlnmbr preserving type ) as InsurPlcyContrDataDetnJrnlNmbr,
      BonusMalus.InsurPlcyJrnlNmbr,
      BonusMalus.InsurPlcyJrnlEndNmbr,
      @Consumption.hidden: true
      BonusMalus.InsurPlcyProductPackageID,
      OpenApplJrnl.InsurPlcyUUID,
      BonusMalus.InsuranceBonusMalus,
      BonusMalus.InsurPlcyBonusMalusPremiumRate,
      @ObjectModel.text.association: '_InsurPlcyTemplateT'
      BonusMalus.InsurPlcyBonusMalusTemplate,
      BonusMalus.InsurPlcyAssignmentMode,
      BonusMalus.InsurPlcyFirstClfnReason,
      @ObjectModel.foreignKey.association: '_InsurPlcyIntPremiumLevelLink'
      BonusMalus.InsurPlcyIntPremiumLevel,
      @ObjectModel.foreignKey.association: '_InsurPlcyExtPremiumLevelLink'
      BonusMalus.InsurPlcyExtPremiumLevel,
      BonusMalus.InsurPlcyPrevInsurerCompanyID,
      BonusMalus.InsurPlcyPrvInsBranchOfficeID,
      BonusMalus.InsurPlcyPrevInsurerCheckValue,
      BonusMalus.InsurPlcyInsuranceType,
      @ObjectModel.foreignKey.association: '_InsurPlcyBnMlOriginNameLink'
      BonusMalus.InsurPlcyBonusMalusOrigin,
      BonusMalus.InsurPlcyPeriodBeginDate,
      BonusMalus.InsurPlcyPeriodEndDate,
      @ObjectModel.foreignKey.association: '_InsurPlcyClsfctnRsnNameLink'
      BonusMalus.InsurPlcyClassificationReason,
      @ObjectModel.foreignKey.association: '_InsurPlcyBnMlPremModelLink'
      BonusMalus.InsurPlcyBnMlPremiumModel,
      BonusMalus.InsurPlcyRatingPremiumRate,
      @ObjectModel.foreignKey.association: '_InsurPlcyBnMlCategoryLink'
      BonusMalus.InsurPlcyBonusMalusCategory,
      @ObjectModel.foreignKey.association: '_InsurPlcyPrvInsRatgModelLink'
      BonusMalus.InsurPlcyPrevInsrrRatingModel,
      @ObjectModel.foreignKey.association: '_InsurPlcyIntRatingModelLink'
      BonusMalus.InsurPlcyIntRatingModel,
      BonusMalus.InsurPlcyIntNumberOfPauseDays,
      BonusMalus.InsurPlcyPrvInsNrOfPauseDays,
      BonusMalus.InsurPlcyNumberOfPauseDays,
      BonusMalus.InsurPlcyIntNumberOfClaims,
      BonusMalus.InsurPlcyPrvInsNumberOfClaims,
      BonusMalus.InsurPlcyNumberOfClaims,
      BonusMalus.InsurPlcyPrevInsrrContrEndDate,
      BonusMalus.InsurPlcyValidityBeginDate,
      BonusMalus.InsurPlcyBnMlLifeCycleStatus,
      BonusMalus.InsurPlcyBnMlExtPremiumRate,
      BonusMalus.InsurPlcyBnMlPrevInsrrAddition,
      BonusMalus.InsurPlcyBnMlInternalAddition,
      BonusMalus.InsurLicensePlateNumber,
      BonusMalus.InsurPlcyDriversLicenseIsChkd,
      BonusMalus.InsurPlcyPrevInsurerPolicyID,
      BonusMalus.InsurPlcyRefcdBonusMalus,
      BonusMalus.InsurPlcyInsrdVehNumberOfSeats,
      BonusMalus.InsurPlcyPrevInsrrDiscBaseYear,
      BonusMalus.InsurPlcyIntDiscountBaseYear,
      BonusMalus.InsurPlcyDiffntBnMlOwnerDesc,
      BonusMalus.InsurPlcyBnMlCertIsReceived,
      BonusMalus.InsurPlcyTypeOfRelatedContract,
      @Consumption.hidden: true
      BonusMalus.InsurPlcyBusinessObject,
      @Semantics.systemDateTime.lastChangedAt: true
      BonusMalus.LastChangeDateTime,

      /* Associations */
      _InsurOpenApplCoverage,
      _InsOpApCvrgBonusMalusOwner,
      _InsOpApCvrgBonusMalusCert,
      _InsOpApCvrgBnMlClmSrrndr,
      @Consumption.hidden: true
      _InsurPlcyIntPremiumLevelLink,
      @Consumption.hidden: true
      _InsurPlcyExtPremiumLevelLink,
      @Consumption.hidden: true
      _InsurPlcyBnMlOriginNameLink,
      @Consumption.hidden: true
      _InsurPlcyClsfctnRsnNameLink,
      @Consumption.hidden: true
      _InsurPlcyBnMlPremModelLink,
      @Consumption.hidden: true
      _InsurPlcyBnMlCategoryLink,
      @Consumption.hidden: true
      _InsurPlcyPrvInsRatgModelLink,
      @Consumption.hidden: true
      _InsurPlcyIntRatingModelLink,
      @Consumption.hidden: true
      _InsurPlcyTemplateT

}

where
      BonusMalus.InsurPlcyCoveragePackageID <> 0
  and BonusMalus.InsurPlcyCoverageID        <> 0
  and OpenApplJrnl.InsurPlcyApplUUID        is not initial //Perf. Tuning: Make inner Join out of left outer Join

  and OpenApplJrnl.InsuranceApplication     is not initial
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSURPLCYBONUSMALUSBASIC",
"P_INSOPAPBONUSMALUSLATEST"
],
"ASSOCIATED":
[
"I_INSOPAPCVRGBNMLCLMSRRNDR",
"I_INSOPAPCVRGBONUSMALUSCERT",
"I_INSOPAPCVRGBONUSMALUSOWNER",
"I_INSUROPENAPPLCOVERAGE",
"I_INSURPLCYBNMLCATEGORYLINK",
"I_INSURPLCYBNMLORIGINNAMELINK",
"I_INSURPLCYBNMLPREMMODELLINK",
"I_INSURPLCYCLSFCTNRSNNAMELINK",
"I_INSURPLCYEXTPREMIUMLEVELLINK",
"I_INSURPLCYINTPREMIUMLEVELLINK",
"I_INSURPLCYINTRATINGMODELLINK",
"I_INSURPLCYPRVINSRATGMODELLINK",
"I_INSURPLCYTEMPLATET"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/