I_InhRepairItemStatusText

@EndUserText.label: 'Status of In-House Repair Item - Text'
@VDM: {
    viewType: #BASIC,
    lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl: {
    authorizationCheck: #NOT_REQUIRED
}
@ObjectModel: {
    dataCategory: #TEXT,
    representativeKey: 'InhRepairItemStatus',
    usageType: {serviceQuality: #B, sizeCategory: #S, dataClass: #CUSTOMIZING}
}
@Metadata: {
    ignorePropagatedAnnotations: true
}
@ClientHandling: {
    algorithm: #SESSION_VARIABLE
}
@AbapCatalog: {
    sqlViewName: 'IIHRITEMSTATUST',
    compiler.compareFilter: true,
    preserveKey: true
}

define view I_InhRepairItemStatusText
  as select from I_CustMgmtLifecycleUserStsText
    inner join   I_CustMgmtLfcycUsrStsMapping on I_CustMgmtLfcycUsrStsMapping.CustMgmtLifecycleUserStatus = I_CustMgmtLifecycleUserStsText.CustMgmtLifecycleUserStatus
    inner join   I_CustMgmtDocItemCategory    on  I_CustMgmtDocItemCategory.CustMgmtDocItemObjectType = 'BUS2000257'
                                              and I_CustMgmtDocItemCategory.StatusProfile             = I_CustMgmtLfcycUsrStsMapping.StatusProfile

  association [0..1] to I_InhRepairItemStatus     as _InhRepairItemStatus   on  $projection.InhRepairItemStatus   = _InhRepairItemStatus.InhRepairItemStatus
                                                                            and $projection.InhRepairItemCategory = _InhRepairItemStatus.InhRepairItemCategory
  association [0..1] to I_Language                as _Language              on  $projection.Language = _Language.Language
  association [0..1] to I_CustMgmtDocItemCategory as _InhRepairItemCategory on  $projection.InhRepairItemCategory = _InhRepairItemCategory.CustMgmtDocItemCategory

{
      @Semantics.language: true
      @ObjectModel.foreignKey.association: '_Language'
  key Language,
      @ObjectModel.foreignKey.association: '_InhRepairItemStatus'
  key cast(I_CustMgmtLifecycleUserStsText.CustMgmtLifecycleUserStatus as crms4_repa_item_status_lbl preserving type) as InhRepairItemStatus,
      @ObjectModel.foreignKey.association: '_InhRepairItemCategory'
  key CustMgmtDocItemCategory                                                                                        as InhRepairItemCategory,

      @Semantics.text: true
      cast(CustMgmtLifecycleUserStsName as crms4_repa_item_status_dsc_lbl preserving type)                           as InhRepairItemStatusName,

      /* Associations */
      _InhRepairItemStatus,
      _Language,
      _InhRepairItemCategory
}
where
  I_CustMgmtLfcycUsrStsMapping.CustMgmtLifecycleUserStsField = 'STAT_LIFECYCLE'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CUSTMGMTDOCITEMCATEGORY",
"I_CUSTMGMTLFCYCUSRSTSMAPPING",
"I_CUSTMGMTLIFECYCLEUSERSTSTEXT"
],
"ASSOCIATED":
[
"I_CUSTMGMTDOCITEMCATEGORY",
"I_INHREPAIRITEMSTATUS",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/