I_InhRepairItemAvailyStatusTxt

@EndUserText.label: 'Availability of In-House Repair Item - Text'
@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@Analytics: {
  technicalName: 'IIHRITMAVAILSTST'
//  dataExtraction.enabled: true

}
@AccessControl: {
  authorizationCheck: #NOT_REQUIRED
}
@ObjectModel.supportedCapabilities: [
  #CDS_MODELING_ASSOCIATION_TARGET,
  #CDS_MODELING_DATA_SOURCE,
  #LANGUAGE_DEPENDENT_TEXT,
  #SEARCHABLE_ENTITY,
  #SQL_DATA_SOURCE
//  #EXTRACTION_DATA_SOURCE

]
@ObjectModel: {
  representativeKey: 'InhRepairItemAvailyStatus',
  dataCategory: #TEXT,
  modelingPattern: #LANGUAGE_DEPENDENT_TEXT,
  usageType: {serviceQuality: #A, sizeCategory: #S, dataClass: #META}
}
@Search: {
  searchable: true
}
@Metadata: {
  ignorePropagatedAnnotations: true
}

/*+[hideWarning] { "IDS" : [ "KEY_CHECK" ] }*/
define view entity I_InhRepairItemAvailyStatusTxt
  as select from dd07t
  association        to parent I_InhRepairItemAvailyStatus as _InhRepairItemAvailyStatus on $projection.InhRepairItemAvailyStatus = _InhRepairItemAvailyStatus.InhRepairItemAvailyStatus
  association [0..1] to I_Language                         as _Language                  on $projection.Language = _Language.Language
{
      @Semantics.language: true
      @ObjectModel.foreignKey.association: '_Language'
  key cast(dd07t.ddlanguage as spras preserving type)          as Language,
      @ObjectModel.foreignKey.association: '_InhRepairItemAvailyStatus'
      @ObjectModel.text.element: ['InhRepairItemAvailyStatusText']
  key cast(dd07t.domvalue_l as crms4_stat_repair_availability) as InhRepairItemAvailyStatus,
      @Analytics.hidden: true
      @Consumption.hidden: true
      dd07t.domvalue_l                                         as DomainValue,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @Semantics.text: true
      dd07t.ddtext                                             as InhRepairItemAvailyStatusText,

      _InhRepairItemAvailyStatus,
      _Language
}
where
      dd07t.domname  = 'CRMS4_STAT_REPAIR_AVAILABILITY'
  and dd07t.as4local = 'A'
  and dd07t.as4vers  = '0000'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_INHREPAIRITEMAVAILYSTATUS",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/