I_IN_MatlDocList

@AbapCatalog.sqlViewName: 'INMATLDOCLIST'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.dataClass:#TRANSACTIONAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Material Document for Subcon Challan'
@VDM: {
        private: false,
        viewType: #BASIC,
        lifecycle.contract.type: #SAP_INTERNAL_API
        }
define view I_IN_MatlDocList as select from matdoc 
  association [0..1] to I_Material                  as _Material                      on  $projection.Material = _Material.Material
  association [0..1] to I_Plant                     as _Plant                         on  $projection.Plant = _Plant.Plant
  association [0..1] to I_StorageLocation           as _StorageLocation               on  $projection.StorageLocation = _StorageLocation.StorageLocation
                                                                                      and $projection.Plant           = _StorageLocation.Plant
  association [0..1] to I_Supplier                  as _Supplier                      on  $projection.Supplier = _Supplier.Supplier
  association [0..1] to I_CompanyCode               as _CompanyCode                   on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_BusinessArea              as _BusinessArea                  on  $projection.BusinessArea = _BusinessArea.BusinessArea
{
  cast(mjahr as nsdm_mjahr preserving type) as MaterialDocumentYear,
  mblnr             as MaterialDocument,
  cast(zeile as nsdm_mblpo preserving type) as MaterialDocumentItem,
  werks             as Plant,
  matnr             as Material,
  lgort             as StorageLocation,
  lifnr             as Supplier,

  bwart             as GoodsMovementType,
  
  
  @Semantics.quantity.unitOfMeasure: 'EntryUnit'
  @DefaultAggregation: #NONE
  erfmg             as QuantityInEntryUnit,
  @Semantics.unitOfMeasure: true
  erfme             as EntryUnit,
  
  cast(sjahr as nsdm_sjahr preserving type) as ReversedMaterialDocumentYear,
  cast(smbln as nsdm_smbln preserving type) as ReversedMaterialDocument,
  cast(smblp as nsdm_smblp preserving type) as ReversedMaterialDocumentItem,
  xwsbr             as RvslOfGoodsReceiptIsAllowed,
  cast(reversal_movement as nsdm_xstbw preserving type) as IsReversalMovementType,
  cancelled         as GoodsMovementIsCancelled,
  cancellation_type as GoodsMovementCancellationType, 

  wempf             as GoodsRecipientName,
  ablad             as UnloadingPointName,
  kostl             as CostCenter,
  sakto             as GLAccount,
  kstrg             as CostObject,
  cast(paobjnr as nsdm_rkeobjnr) as ProfitabilitySegment,
  prctr             as ProfitCenter,
  kalnr             as CostEstimate,
  
  xblnr             as ReferenceDocument,
  serviceperformer  as ServicePerformer,
  pernr             as EmploymentInternalID,
  cast(knttp_gr as nsdm_knttp preserving type) as AccountAssignmentCategory,
  work_item_id      as WorkItem,
  fbuda             as ServicesRenderedDate,

  bukrs             as CompanyCode,
  gsber             as BusinessArea,
  @Semantics.businessDate.at: true
  budat             as PostingDate,
  @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
  @DefaultAggregation: #NONE
  dmbtr             as TotalGoodsMvtAmtInCCCrcy,
  @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
  @DefaultAggregation: #NONE
  dmbtr_stock       as GoodsMovementStkAmtInCCCrcy,
  @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
  @DefaultAggregation: #NONE
  dmbtr_cons        as GoodsMvtCnsmpnAmtInCCCrcy,
  @Semantics.currencyCode: true
  cast(waers as nsdm_comp_code_currency preserving type)  as CompanyCodeCurrency,

  cast(xauto as nsdm_xauto preserving type) as IsAutomaticallyCreated,
  usnam as UserName,
  _Material,
  _Plant,
  _StorageLocation,
  _Supplier,
  _CompanyCode,
  _BusinessArea
}
  
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"MATDOC"
],
"ASSOCIATED":
[
"I_BUSINESSAREA",
"I_COMPANYCODE",
"I_MATERIAL",
"I_PLANT",
"I_STORAGELOCATION",
"I_SUPPLIER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/