@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'IL AA Depreciation for Statutory Reporting - Cube'
@Metadata.ignorePropagatedAnnotations: true
@Metadata.allowExtensions: true
@ObjectModel.usageType:{
serviceQuality: #D,
sizeCategory: #S,
dataClass: #MIXED
}
@Analytics.dataCategory: #CUBE
@VDM.viewType: #COMPOSITE
@Analytics.internalName:#LOCAL
define view entity I_IL_AssetBalanceCube
with parameters
P_AssetAccountingKeyFigureSet : faa_key_figure_set,
P_FiscalYear : fis_gjahr,
P_FiscalPeriod : fis_period_to,
P_KeyDate : fagl_keydate,
P_CurrentDepreciationArea : glofaa_gb_depr_area_cur,
P_Ledger : fins_ledger
as select from I_AssetBalanceCube(P_AssetAccountingKeyFigureSet: $parameters.P_AssetAccountingKeyFigureSet,
P_FiscalYear : $parameters.P_FiscalYear,
P_FiscalPeriod: $parameters.P_FiscalPeriod,
P_KeyDate: $parameters.P_KeyDate )
{
@ObjectModel.foreignKey.association: '_CompanyCode'
key CompanyCode,
@ObjectModel.foreignKey.association: '_MasterFixedAsset'
key MasterFixedAsset,
@ObjectModel.foreignKey.association: '_FixedAsset'
key FixedAsset,
@ObjectModel.foreignKey.association: '_Ledger'
key Ledger,
@ObjectModel.foreignKey.association: '_FiscalYear'
key FiscalYear,
key FiscalPeriod,
@ObjectModel.foreignKey.association: '_SubledgerAccLineItemType'
key SubLedgerAcctLineItemType,
key AssetAcctTransClassfctn,
key AssetAccountingKeyFigure,
key AssetAccountingKeyFigureSet,
@ObjectModel.foreignKey.association: '_JournalEntry'
key AccountingDocument,
key LedgerGLLineItem,
key TransactionSubitem,
key DebitCreditCode,
key CurrencyRole,
substring (I_AssetBalanceCube.AssetDeactivationDate,1,6) as IL_DeactivationIndexYearMonth, // Note 3295621//n3329830
substring (I_AssetBalanceCube.AcquisitionValueDate,1,6) as IL_AcquisitionIndexYearMonth, // Note 3295621//n3329830
concat($parameters.P_FiscalYear,substring ($parameters.P_FiscalPeriod,2,2)) as IL_CurrentPeriodIndexYearMonth, // Note 3295621
@ObjectModel.foreignKey.association: '_AssetClass'
AssetClass,
_FixedAsset.FixedAssetDescription as FixedAssetDescription,
I_AssetBalanceCube.AcquisitionValueDate as AcquisitionValueDate, //n3329830
I_AssetBalanceCube.AssetDeactivationDate,//n3329830
I_AssetBalanceCube.AssetCapitalizationDate,//n3329830
DepreciationStartDate,
PlannedUsefulLifeInYears,
PlannedUsefulLifeInPeriods,
AssetTransactionType,
AssetValueDate,
//feild for ALV REPORT//
CostCenter,
AssetCostCenter,
Group1AssetEvaluationKey,
Group2AssetEvaluationKey,
Group3AssetEvaluationKey,
Group4AssetEvaluationKey,
Group5AssetEvaluationKey,
InvestmentSupportMeasure,
AssetBusinessArea,
BusinessArea,
_FixedAsset.InvestmentReason as InvestmentReason,
_FixedAsset.AssetAccountDetermination as AssetAccountDetermination,
_FixedAsset.FixedAssetGroup as FixedAssetGroup, //Asset Super Number
_FixedAsset.Inventory as Inventory,
_FixedAsset.AssetManufacturerName as AssetManufacturerName,
_FixedAsset.AssetAdditionalDescription as AssetAdditionalDescription,
_FixedAsset.LastRetirementValueDate as LastRetirementValueDate, //Note 3295621 Tax Gain
_FixedAsset.OriginalAcquisitionFiscalYear as OriginalAcquisitionFiscalYear,//Note 3295621 Tax Gain
DisplayCurrency,
@DefaultAggregation:#SUM
@Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
case when AssetAccountingKeyFigure = '0000700501' then AmountInDisplayCurrency
else cast( 0 as abap.curr(23,2) )
end as AccumulatedOrdinaryDeprAmount, //knafa
@DefaultAggregation:#SUM
@Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
case when ( AssetAccountingKeyFigure = '0000700601' )
then AmountInDisplayCurrency
else cast( 0 as abap.curr(23,2) )
end as AccumulatedSpecialDeprAmount, //ksafa
@DefaultAggregation:#SUM
@Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
case when ( AssetAccountingKeyFigure = '0000700701' )
then AmountInDisplayCurrency
else cast( 0 as abap.curr(23,2) )
end as AccumulatedUnplannedDeprAmount, //kaafa
@DefaultAggregation:#SUM
@Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
case when ( AssetAccountingKeyFigure = '0007700501' )
then AmountInDisplayCurrency
else cast( 0 as abap.curr(23,2) )
end as PlannedOrdinaryDeprAmount, //nafag for tax
@DefaultAggregation:#SUM
@Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
case when ( AssetAccountingKeyFigure = '0007701600' ) //0007700600
then AmountInDisplayCurrency
else cast( 0 as abap.curr(23,2) )
end as SpecialDepreciationAmount, //safag
@DefaultAggregation:#SUM
@Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
case when ( AssetAccountingKeyFigure = '0007701700' ) // '0007700700'
then AmountInDisplayCurrency
else cast( 0 as abap.curr(23,2) )
end as UnplannedDepreciationAmount, //aafag
@DefaultAggregation:#SUM
@Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
case when ( AssetAccountingKeyFigure = '0009791070' )
then AmountInDisplayCurrency
else cast( 0 as abap.curr(23,2) )
end as UnplndDeprValAdjustmentAmount, //aafal
@DefaultAggregation:#SUM
@Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
case when ( AssetAccountingKeyFigure = '0007700701' )
then AmountInDisplayCurrency
else cast( 0 as abap.curr(23,2) )
end as PlannedUnplannedDeprAmount, //aafap
@DefaultAggregation:#SUM
@Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
case when ( AssetAccountingKeyFigure = '0007700601' )
then AmountInDisplayCurrency
else cast( 0 as abap.curr(23,2) )
end as PlannedSpecialDeprAmount, //safap
@DefaultAggregation:#SUM
@Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
case when ( AssetAccountingKeyFigure = '0007700401' )
then AmountInDisplayCurrency
else cast( 0 as abap.curr(23,2) )
end as AccmltdRevalOrdinaryDeprAmount, //kaufn
@DefaultAggregation:#SUM
@Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
case when ( AssetAccountingKeyFigure = '0001700000' or AssetAccountingKeyFigure = '0009790100' or AssetAccountingKeyFigure ='0005700000')
then AmountInDisplayCurrency
else cast( 0 as abap.curr(23,2) )
end as AcquisitionProductionAmount, //answl
@DefaultAggregation:#SUM
@Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
case when ( AssetAccountingKeyFigure = '0003700000' or AssetAccountingKeyFigure = '0003710200'
or AssetAccountingKeyFigure = '0003720200' )
then AmountInDisplayCurrency
else cast( 0 as abap.curr(23,2) )
end as TransferAmtInDspCrcy,
@DefaultAggregation:#SUM
@Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
case when ( AssetAccountingKeyFigure = '0002700000' ) //or AssetAccountingKeyFigure = '0009791070' )
then AmountInDisplayCurrency
else cast( 0 as abap.curr(23,2) )
end as RetirementCostsAmtInDspCrcy,
@DefaultAggregation:#SUM
@Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
case when ( AssetAccountingKeyFigure = '0000700110' )
then AmountInDisplayCurrency
else cast( 0 as abap.curr(23,2) )
end as AccmltdAcqnProductionAmount,//kansw
@DefaultAggregation:#SUM
@Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
case when ( AssetAccountingKeyFigure = '0000700301' )
then AmountInDisplayCurrency
else cast( 0 as abap.curr(23,2) )
end as AccumulatedRevaluationAmount, //kaufw
@DefaultAggregation:#SUM
@Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
case when ( AssetAccountingKeyFigure = '0007700302' )
then AmountInDisplayCurrency
else cast( 0 as abap.curr(23,2) )
end as RevaluationAmount, //aufwp
@DefaultAggregation:#SUM
@Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
case when ( AssetAccountingKeyFigure = '0007700402' )
then AmountInDisplayCurrency
else cast( 0 as abap.curr(23,2) )
end as PlannedRevalOrdinaryDeprAmount, //aufnp
@DefaultAggregation:#SUM
@Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
case when ( AssetAccountingKeyFigure = '0007700802' )
then AmountInDisplayCurrency
else cast( 0 as abap.curr(23,2) )
end as PlannedTransferOfReservesAmt, //mafap
@DefaultAggregation:#SUM
@Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
case when ( AssetAccountingKeyFigure = '0008700500' )
then AmountInDisplayCurrency
else cast( 0 as abap.curr(23,2) )
end as OrdinaryDeprWriteUpAmount, //zusna
@DefaultAggregation:#SUM
@Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
case when ( AssetAccountingKeyFigure = '0008700600' )
then AmountInDisplayCurrency
else cast( 0 as abap.curr(23,2) )
end as SpclDepreciationWriteUpAmount, //zussa
@DefaultAggregation:#SUM
@Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
case when ( AssetAccountingKeyFigure = '0008700700' )
then AmountInDisplayCurrency
else cast( 0 as abap.curr(23,2) )
end as UnplannedDeprWriteUpAmount, //zusaa
@DefaultAggregation:#SUM
@Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
case when ( AssetAccountingKeyFigure = '0008700800' )
then AmountInDisplayCurrency
else cast( 0 as abap.curr(23,2) )
end as TrnsfdRsrvWriteUpAmtInDspCrcy, //zusma
@DefaultAggregation:#SUM
@Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
case when ( AssetAccountingKeyFigure = '0009790050' or AssetAccountingKeyFigure = '0009790800' or AssetAccountingKeyFigure = '0009792050') //Note 3295621
then AmountInDisplayCurrency
else cast( 0 as abap.curr(23,2) )
end as AccmltdOrdnryDeprValAdjmtAmt, //nafav
@DefaultAggregation:#SUM
@Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
case when ( AssetAccountingKeyFigure = '0009790060' )
then AmountInDisplayCurrency
else cast( 0 as abap.curr(23,2) )
end as AccmltdSpclDeprValAdjmtAmount, //safav
@DefaultAggregation:#SUM
@Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
case when ( AssetAccountingKeyFigure = '0009790070' )
then AmountInDisplayCurrency
else cast( 0 as abap.curr(23,2) )
end as AccmltdUnplndDeprValAdjmtAmt, //aafav
@DefaultAggregation:#SUM
@Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
case when ( AssetAccountingKeyFigure = '0009791080' )
then AmountInDisplayCurrency
else cast( 0 as abap.curr(23,2) )
end as ProportionalTransfOfReserveAmt, //mafal
@DefaultAggregation:#SUM
@Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
case when ( AssetAccountingKeyFigure = '0009792080' )
then AmountInDisplayCurrency
else cast( 0 as abap.curr(23,2) )
end as AccmltdProportionTransfRsrvAmt, //mafav
@DefaultAggregation:#SUM
@Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
case when ( AssetAccountingKeyFigure = '0000700801' )
then AmountInDisplayCurrency
else cast( 0 as abap.curr(23,2) )
end as CumulativeReservesTransferAmt, //kmafa
@DefaultAggregation:#SUM
@Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
case when ( AssetAccountingKeyFigure = '0007701800' )
then AmountInDisplayCurrency
else cast( 0 as abap.curr(23,2) )
end as ManualTransferOfReservesAmt, //mafam
@DefaultAggregation:#SUM
@Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
case when ( AssetAccountingKeyFigure = '0009791050' )
then AmountInDisplayCurrency
else cast( 0 as abap.curr(23,2) )
end as OrdnryDeprValAdjustmentAmount, //nafal
//////////// Amounts for Tax Gain report Note 3295621 ////////////
@DefaultAggregation:#SUM
@Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
case when ( AssetAccountingKeyFigure = '0002700900' )
then AmountInDisplayCurrency
else cast( 0 as abap.curr(23,2) )
end as RetirementRevenue, //ERLBT
@DefaultAggregation:#SUM
@Semantics: { amount : {currencyCode: 'DisplayCurrency'} }
case when ( AssetAccountingKeyFigure = '0002700901' or AssetAccountingKeyFigure = '0009791070') // test for CCQ n3295621)
then AmountInDisplayCurrency
else cast( 0 as abap.curr(23,2) )
end as RetirementCost, //VERKO
/*Associations */
_CompanyCode,
_MasterFixedAsset,
_FixedAsset,
_Ledger,
_FiscalYear,
_JournalEntry,
_SubLedgerAccLineItemType,
_AssetKeyFigureSet,
_AssetClass
}
where
(AssetDepreciationArea = $parameters.P_CurrentDepreciationArea
and CurrencyRole = '10'
and Ledger = $parameters.P_Ledger)
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ASSETBALANCECUBE",
"I_FIXEDASSET"
],
"ASSOCIATED":
[
"I_ASSETCLASS",
"I_ASSETKEYFIGURESET",
"I_COMPANYCODE",
"I_FISCALYEARFORCOMPANYCODE",
"I_FIXEDASSET",
"I_JOURNALENTRY",
"I_LEDGER",
"I_MASTERFIXEDASSET",
"I_SUBLEDGERACCLINEITEMTYPE"
],
"BASE":
[
"I_ASSETBALANCECUBE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/