I_IHBAccountStatusText

DDL: I_IHBACCOUNTSTATUSTEXT Type: view_entity BASIC

IHB Account Status - Text

I_IHBAccountStatusText is a Basic CDS View that provides data about "IHB Account Status - Text" in SAP S/4HANA. It reads from 1 data source (dd07t) and exposes 6 fields with key fields Language, IHBAccountStatus. It has 2 associations to related views.

1 data source(s) 6 fields

Data Sources (1)

SourceAliasJoin Type
dd07t dd07t from

Associations (2)

CardinalityTargetAliasCondition
[1..1] I_IHBAccountStatus _IHBAccountStatus $projection.IHBAccountStatus = _IHBAccountStatus.IHBAccountStatus
[0..1] I_Language _Language $projection.Language = _Language.Language

Annotations (9)

NameValueLevelField
EndUserText.label IHB Account Status - Text view
AccessControl.authorizationCheck #NOT_REQUIRED view
ObjectModel.dataCategory #TEXT view
ObjectModel.representativeKey IHBAccountStatus view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.dataClass #META view
ObjectModel.usageType.sizeCategory #S view
Search.searchable true view
VDM.viewType #BASIC view

Fields (6)

KeyFieldSource TableSource FieldDescription
KEY Language
KEY IHBAccountStatus Status
DomainValue dd07t domvalue_l
IHBAccountStatusText Status Text
_IHBAccountStatus _IHBAccountStatus
_Language _Language 
@EndUserText.label: 'IHB Account Status - Text'
@AccessControl.authorizationCheck: #NOT_REQUIRED

@ObjectModel : {
  dataCategory: #TEXT,
//  modelingPattern: #LANGUAGE_DEPENDENT_TEXT,

  representativeKey: 'IHBAccountStatus',
  usageType : {
    serviceQuality: #A,
    dataClass: #META,
    sizeCategory: #S
  }
}

@Search.searchable: true
@VDM: {
  viewType: #BASIC
}
define view entity I_IHBAccountStatusText
  as select from dd07t
  /*+[hideWarning] { "IDS" :  [ "CALCULATED_FIELD_CHECK" ] } */
  association [1..1] to I_IHBAccountStatus as _IHBAccountStatus on $projection.IHBAccountStatus = _IHBAccountStatus.IHBAccountStatus
  association [0..1] to I_Language         as _Language         on $projection.Language = _Language.Language

{
      @Semantics.language: true
      @ObjectModel.foreignKey.association: '_Language'
  key cast( dd07t.ddlanguage as spras preserving type )   as Language,
      @EndUserText.label: 'Status'
      @ObjectModel.foreignKey.association: '_IHBAccountStatus'
      @ObjectModel.text.element: ['IHBAccountStatusText']
  key cast ( dd07t.domvalue_l as /pf1/dte_ihb_acct_stat ) as IHBAccountStatus,

      @Analytics.hidden: true
      @Consumption.hidden: true
      dd07t.domvalue_l                                    as DomainValue,

      @EndUserText.label: 'Status Text'
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @Semantics.text: true
      @Consumption.filter.hidden: true
      cast( dd07t.ddtext as text60 preserving type )      as IHBAccountStatusText,

      _IHBAccountStatus,
      _Language

}
where
      dd07t.domname  = '/PF1/DOM_IHB_ACCT_STAT'
  and dd07t.as4local = 'A'
  and dd07t.as4vers  = '0000'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_IHBACCOUNTSTATUS",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More