I_GoodsMvtTypeBySpclStkIndT

@AbapCatalog.sqlViewName: 'IGDSMVTBYSPSTINT'
@AbapCatalog.preserveKey: true
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.buffering : { status : #ACTIVE, type: #GENERIC, numberOfKeyFields: 2 }
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.sizeCategory: #S       // see https://wiki.wdf.sap.corp/wiki/display/SuiteCDS/CDS+View+Performance#CDSViewPerformance-ObjectModel.usageType.sizeCategory

@ObjectModel.usageType.serviceQuality: #A     // see https://wiki.wdf.sap.corp/wiki/display/SuiteCDS/CDS+View+Performance#CDSViewPerformance-ObjectModel.usageType.serviceQuality

@ObjectModel.usageType.dataClass:#CUSTOMIZING // see https://wiki.wdf.sap.corp/wiki/display/SuiteCDS/CDS+View+Performance#CDSViewPerformance-ObjectModel.usageType.dataClass

@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Goods Movement Type by Special Stock Indicator Text'

@VDM.viewType: #BASIC
@ObjectModel.representativeKey: 'GoodsMovementType'
@ObjectModel.dataCategory: #TEXT
@Metadata: {
             ignorePropagatedAnnotations: true
           }

define view I_GoodsMvtTypeBySpclStkIndT
  as select from t156t

  association [0..1] to I_GoodsMovementType           as _GoodsMovementType         on $projection.GoodsMovementType = _GoodsMovementType.GoodsMovementType
  association [0..1] to I_InventorySpecialStockType   as _InventorySpecialStockType on $projection.InventorySpecialStockType = _InventorySpecialStockType.InventorySpecialStockType
  association [0..1] to I_GoodsMovementRefDocType     as _GoodsMovementRefDocType   on $projection.GoodsMovementRefDocType = _GoodsMovementRefDocType.GoodsMovementRefDocType
  association [0..1] to I_GoodsReceiptType            as _GoodsReceiptType          on $projection.GoodsReceiptType = _GoodsReceiptType.GoodsReceiptType
  association [0..1] to I_ConsumptionPostingIndicator as _ConsumptionPosting        on $projection.ConsumptionPosting = _ConsumptionPosting.ConsumptionPosting
  association [0..1] to I_Language                    as _Language                  on $projection.Language = _Language.Language
{
      @ObjectModel.foreignKey.association: '_GoodsMovementType'
  key bwart as GoodsMovementType,
      @ObjectModel.foreignKey.association: '_InventorySpecialStockType'
  key sobkz as InventorySpecialStockType,
      @ObjectModel.foreignKey.association: '_GoodsMovementRefDocType'
  key kzbew as GoodsMovementRefDocType,
      @ObjectModel.foreignKey.association: '_GoodsReceiptType'
  key kzzug as GoodsReceiptType,
      @ObjectModel.foreignKey.association: '_ConsumptionPosting'
  key kzvbr as ConsumptionPosting,
      @Semantics.language: true
  key spras as Language,

      @Semantics.text: true
      btext as GoodsMovementTypeName,

      _GoodsMovementType,
      _InventorySpecialStockType,
      _GoodsMovementRefDocType,
      _ConsumptionPosting,
      _GoodsReceiptType,
      _Language
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"T156T"
],
"ASSOCIATED":
[
"I_CONSUMPTIONPOSTINGINDICATOR",
"I_GOODSMOVEMENTREFDOCTYPE",
"I_GOODSMOVEMENTTYPE",
"I_GOODSRECEIPTTYPE",
"I_INVENTORYSPECIALSTOCKTYPE",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/