I_GoodsMovementRefDocTypeText

@AbapCatalog: { sqlViewName: 'IGDSMVTREFDOCTXT',
                compiler.compareFilter: true,
                preserveKey: true }

@Analytics.dataExtraction.enabled:true

@EndUserText.label: 'Goods Mvt Reference Document Type - Text'

@Metadata.ignorePropagatedAnnotations: true

@AccessControl.authorizationCheck: #NOT_REQUIRED

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel: { dataCategory: #TEXT,
                modelingPattern: #LANGUAGE_DEPENDENT_TEXT,
                representativeKey: 'GoodsMovementRefDocType',
                supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET,
                                        #CDS_MODELING_DATA_SOURCE,
                                        #EXTRACTION_DATA_SOURCE,
                                        #LANGUAGE_DEPENDENT_TEXT,
                                        #SEARCHABLE_ENTITY,
                                        #SQL_DATA_SOURCE],
                usageType: { serviceQuality: #A, 
                             dataClass: #META, 
                             sizeCategory: #S } }

@Search.searchable: true

@VDM: { lifecycle.contract.type: #PUBLIC_LOCAL_API,
        viewType: #BASIC }
define view I_GoodsMovementRefDocTypeText 
  as select from dd07t
  
  association [0..1] to I_GoodsMovementRefDocType  as _GoodsMovementRefDocType on $projection.GoodsMovementRefDocType = _GoodsMovementRefDocType.GoodsMovementRefDocType
  association [0..1] to I_Language                 as _Language                on $projection.Language = _Language.Language  

{
      @ObjectModel.foreignKey.association: '_GoodsMovementRefDocType'
  key cast ( cast ( substring( domvalue_l, 1, 2 ) as abap.char( 2 ) ) as kzbew ) as GoodsMovementRefDocType,  
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key cast(ddlanguage as spras preserving type)        as Language,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @Semantics.text: true
      cast(ddtext as vdm_lkngseq_text preserving type) as GoodsMovementRefDocTypeName,
      @Analytics.hidden: true
      @Consumption.hidden: true
      dd07t.domvalue_l as DomainValue,

      //Associations

      _GoodsMovementRefDocType,
      _Language  
}
where domname  = 'KZBEW'
  and as4local = 'A';

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_GOODSMOVEMENTREFDOCTYPE",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/