I_GoodsMovementDocumentDEX

@AbapCatalog: {
                sqlViewName: 'IGOODSMVMTDOCDEX',
                compiler.compareFilter: true,
                preserveKey: true
              }
@EndUserText.label: 'Material document data extraction'
@AccessControl: {
                   authorizationCheck: #CHECK,
                   personalData.blocking: #NOT_REQUIRED
                }
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel: {
                usageType: {
                             sizeCategory: #XXL,
                             serviceQuality: #C,
                             dataClass:#TRANSACTIONAL
                           },
                sapObjectNodeType.name : 'MaterialStock',                           
                semanticKey: ['MaterialDocumentYear', 'MaterialDocument', 'MaterialDocumentItem'],
                supportedCapabilities: [#EXTRACTION_DATA_SOURCE]
} 
@VDM: {
        viewType: #COMPOSITE,
        lifecycle.contract.type: #PUBLIC_LOCAL_API
      }
@Analytics: {
              dataCategory: #FACT,
              internalName: #LOCAL,
              dataExtraction: {
                                enabled: true,
                                delta.changeDataCapture: {
                                                           mapping: [
                                                                      {
                                                                        table: 'MATDOC',
                                                                        role: #MAIN,
                                                                        viewElement: ['MaterialDocumentKey1', 'MaterialDocumentKey2', 'MaterialDocumentKey3', 'MaterialDocumentKey4', 'MaterialDocumentKey5', 'MaterialDocumentKey6'],
                                                                        tableElement: ['key1', 'key2', 'key3', 'key4', 'key5', 'key6']
                                                                      }
                                                                    ]
                                                         }
                              }
            }
@Metadata: {
             ignorePropagatedAnnotations: true
           }

define view I_GoodsMovementDocumentDEX
  as select from I_MaterialDocumentRecord 
{
// Technical key fields

  @Consumption.hidden: true
      key MaterialDocumentKey1,
  @Consumption.hidden: true
      key MaterialDocumentKey2,
  @Consumption.hidden: true
      key MaterialDocumentKey3,
  @Consumption.hidden: true
      key MaterialDocumentKey4,
  @Consumption.hidden: true
      key MaterialDocumentKey5,
  @Consumption.hidden: true
      key MaterialDocumentKey6,
      
// Semantic key fields      

  @Semantics.calendar.year: true
      MaterialDocumentYear,
      MaterialDocument,
      MaterialDocumentItem,
    
// Warehouse stock identifier

      StockIdentifyingMaterial,
      Plant,
      StockIdfgStorageLocation,
      StockIdentifyingBatch,
      SpecialStockIdfgSupplier,
      SpecialStockIdfgSalesOrder,
      SpecialStockIdfgSalesOrderItem,
-- CAST to get rid of conversion exit
      cast(SpecialStockIdfgWBSElement as nsdm_wbselement_internal_id preserving type) as SpecialStockIdfgWBSElement,  
      SpecialStockIdfgCustomer,
      InventorySpecialStockType,
      InventoryStockType,
      SpecialStockIdfgStockOwner,
      cast(ResourceID as nsdm_resourcename preserving type ) as ResourceID,
      
// Warehouse stock grouping fields     

       CostEstimate,     
   
// Fields of material document     

      StorageLocation,
      Material,
      Batch,     
      StockOwner,      
      CompanyCode,
      InventorySpecialStockValnType,
      @Semantics.currencyCode: true
      CompanyCodeCurrency,  
    
      @Semantics.unitOfMeasure: true
      MaterialBaseUnit,
      @Semantics.unitOfMeasure: true
      EntryUnit,
      @Semantics.unitOfMeasure: true
      OrderQuantityUnit,
      IsReversalMovementType,
      InventoryTransactionType,
      ConsumptionPosting,
      GoodsReceiptType,
      
      // Stock Transfers

      IssuingOrReceivingPlant,
      IssuingOrReceivingStorageLoc,
      IssgOrRcvgMaterial,
      IssgOrRcvgBatch,
      IssgOrRcvgSpclStockInd,
      IssuingOrReceivingStockType,
      IssuingOrReceivingValType,      
      
      cast(IssgOrRcvgResourceID as nsdm_transfer_resourcename preserving type ) as IssgOrRcvgResourceID,
      
      // Cancellation information

      GoodsMovementIsCancelled,
      ReversedMaterialDocument,
      ReversedMaterialDocumentItem,
      ReversedMaterialDocumentYear,
      
      // Periods & Times

      @Semantics.businessDate.at: true
      DocumentDate,
      AccountingDocumentType,
      CreationDate,
      CreationTime,
      
      PostingDate,
      @Semantics.fiscal.yearVariant: true
      FiscalYearVariant,
      FiscalYear,
      @Semantics.fiscal.yearPeriod: true
      FiscalYearPeriod,
      YearDay,
      @Semantics.calendar.yearWeek: true
      YearWeek,
      @Semantics.calendar.yearMonth: true
      YearMonth,
      @Semantics.calendar.yearQuarter: true
      YearQuarter,
      @Semantics.calendar.quarter: true
      CalendarQuarter,
      @Semantics.calendar.month: true
      CalendarMonth,
      @Semantics.calendar.week: true
      CalendarWeek,
      @Semantics.calendar.dayOfYear: true
      CalendarDay,
      WeekDay,      
      
      // Reference Documents

      SalesOrder,
      SalesOrderItem,
      SalesOrderScheduleLine,
      PurchaseOrder,
      cast(PurchaseOrderItem as nsdm_ebelp preserving type) as PurchaseOrderItem,
      ProjectNetwork,
      DeliveryDocument,
      cast(DeliveryDocumentItem as nsdm_posnr_vl preserving type) as DeliveryDocumentItem,
-- CAST to get rid of conversion exit
      cast(WBSElementInternalID as nsdm_wbselement preserving type) as WBSElementInternalID,
      ManufacturingOrder,
      ManufacturingOrderItem,     

      ReferenceDocument,
      GoodsIssueOrReceiptSlipNumber,
      
      ReferenceDocumentFiscalYear,
      InvtryMgmtRefDocumentItem,
      InvtryMgmtReferenceDocument, 
      
      // Other

      GoodsMovementType,
      InventoryValuationType,
      CreatedByUser,
      Supplier,
      Customer,
      IsMaterialDocumentHeader,
      MaterialDocumentHeaderText,
      MaterialDocumentItemText,
      IsCompletelyDelivered,
      GoodsRecipientName,
      UnloadingPointName,
      GoodsMovementRefDocType,
      GoodsMovementReasonCode,
      ShelfLifeExpirationDate,
      ManufactureDate,
      SerialNumbersAreCreatedAutomly,
      VersionForPrintingSlip,
      @Semantics.booleanIndicator: true
      ManualPrintIsTriggered,
    
      // Accounting information

      AccountAssignmentCategory,
      CostCenter,
      ControllingArea, // required to fulfill requirement to expose the full key (for cost center association)

      CostObject,
      GLAccount,
      FunctionalArea,
      @API.element.releaseState: #DECOMMISSIONED
      @API.element.successor: 'ProfitabilitySegment_2'
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'ProfitabilitySegment_2'
      ProfitabilitySegment,
      ProfitabilitySegment_2,      
      ProfitCenter,      
      MasterFixedAsset,
      FixedAsset,
      FundsCenter,
      Fund,   
      CommitmentItemShortID,
      GrantID,
      
      // Reservation

      Reservation,
      ReservationItem,
      ReservationIsFinallyIssued,
      
      DebitCreditCode,
      
      // Amounts

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      @DefaultAggregation: #NONE
      TotalGoodsMvtAmtInCCCrcy,      
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      @DefaultAggregation: #NONE
      GoodsMovementStkAmtInCCCrcy,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      @DefaultAggregation: #NONE
      GoodsMvtCnsmpnAmtInCCCrcy,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      @DefaultAggregation: #NONE
      GdsMvtExtAmtInCoCodeCrcy,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      @DefaultAggregation: #NONE
      SlsPrcAmtInclVATInCoCodeCrcy,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      @DefaultAggregation: #NONE
      EnteredSlsAmtInCoCodeCrcy,
      
      // Quantities

      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      @DefaultAggregation: #NONE
      MatlStkChangeQtyInBaseUnit,
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      @DefaultAggregation: #NONE
      MatlCnsmpnQtyInMatlBaseUnit,
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      @DefaultAggregation: #NONE
      QuantityInBaseUnit,
      @Semantics.quantity.unitOfMeasure: 'EntryUnit'
      @DefaultAggregation: #NONE
      QuantityInEntryUnit,
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      @DefaultAggregation: #NONE 
      GoodsReceiptQtyInOrderUnit,
      
      @Consumption.hidden: true
      TransactionCode,      
      @Consumption.hidden: true
      @Semantics.booleanIndicator: true
      IsAutomaticallyCreated,
      @Consumption.hidden: true
      MaterialDocumentLine,
      @Consumption.hidden: true
      MaterialDocumentParentLine,
      @Consumption.hidden: true
      HierarchyNodeLevel,
      
      _Supplier,
      _BPStockOwner,
      _Customer,
      _SupplierCompanyByPlant,
      _CustomerCompanyByPlant,
      _StorageLocation,
      _IssuingOrReceivingStorageLoc
            
}
where MaterialDocumentRecordType = 'MDOC' or MaterialDocumentRecordType = 'MDOC_CP' 
   or MaterialDocumentRecordType = 'MDOC340' or MaterialDocumentRecordType = 'CORR' 

  

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_MATERIALDOCUMENTRECORD"
],
"ASSOCIATED":
[
"I_CUSTOMER",
"I_CUSTOMERCOMPANYBYPLANT",
"I_STORAGELOCATION",
"I_SUPPLIER",
"I_SUPPLIERCOMPANYBYPLANT"
],
"BASE":
[
"I_MATERIALDOCUMENTRECORD"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/