I_GLAccountToleranceGroup

@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #BASIC
@EndUserText.label: 'Tolerance Group for G/L Account'
@Analytics.dataCategory: #DIMENSION
@AccessControl.authorizationCheck: #CHECK
@AbapCatalog.sqlViewName: 'IFIGLTOLEGRP'
@ObjectModel.representativeKey: 'APARToleranceGroup'
@Metadata.allowExtensions:true
@ObjectModel.usageType: {
  serviceQuality: #A,
  sizeCategory: #S,
  dataClass: #MASTER
}

define view I_GLAccountToleranceGroup
  as select from t043s
  association [0..1] to I_CompanyCode                 as _CompanyCode on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..*] to I_GLAccountToleranceGroupText as _Text        on  $projection.CompanyCode        = _Text.CompanyCode
                                                                      and $projection.APARToleranceGroup = _Text.APARToleranceGroup
  association [0..1] to I_Currency                    as _Currency    on  $projection.currency = _Currency.Currency
{
      //--[ GENERATED:012:29JlHNUf7jY4ip0dSlCN8W

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_CompanyCodeStdVH',
                     element: 'CompanyCode' }
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_CompanyCode'
  key bukrs as CompanyCode,
      @ObjectModel.text.association: '_Text'
  key togru as APARToleranceGroup,

      @DefaultAggregation: #NONE
      @Semantics.amount.currencyCode: 'Currency'
      betrs as MaxRevnClrgDiffAmtInCoCodeCrcy,
      @DefaultAggregation: #NONE
      @Semantics.amount.currencyCode: 'Currency'
      betrh as MaxExpnClrgDiffAmtInCoCodeCrcy,

      prozs as MaxRevnClrgDifferencePercent,
      prozh as MaxExpnClrgDifferencePercent,

      @ObjectModel.foreignKey.association: '_Currency'
      @Semantics.currencyCode: true
      _CompanyCode.Currency,

      _CompanyCode,
      _Currency,
      _Text
}    
 
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"T043S"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_CURRENCY",
"I_GLACCOUNTTOLERANCEGROUPTEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/