I_FundsMgmtFunctionalAreaTP

@AbapCatalog.sqlViewName: 'IFMFUNCAREATP'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Manage Functional Area'

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@ObjectModel: {
     modelCategory: #BUSINESS_OBJECT,
     createEnabled: true,
     draftEnabled: true,
     representativeKey: 'FunctionalArea',
     semanticKey:  [ 'FunctionalArea' ],
     compositionRoot: true,
     transactionalProcessingEnabled: true,
     updateEnabled: true,
     deleteEnabled: true,
     writeDraftPersistence: 'FMFUNCAREA_DRAFT',
     entityChangeStateId: 'EXTERNAL_CALCULATION',  //'LastChangeDate',

     lifecycle.draft.expiryBehavior: #RELATIVE_TO_PROCESSING_START, 
     lifecycle.draft.expiryInterval: 'P5D',
     sapObjectNodeType.name: 'FunctionalArea',
     usageType: {
        dataClass: #MASTER,
        serviceQuality: #C,
        sizeCategory: #L
     }
}

define view I_FundsMgmtFunctionalAreaTP
       as select from I_FundsMgmtFunctionalArea as iFmFunctionalArea
       
  association [1..1] to E_FndsMgmtFunctionalArea as _Extension  //do not expose this association in the projection list of the view 

       on  $projection.FunctionalArea                       = _Extension.FunctionalArea
              
{
      @ObjectModel.readOnly: true
  key iFmFunctionalArea.FunctionalArea,
      @ObjectModel.enabled:   'EXTERNAL_CALCULATION'
      @ObjectModel.readOnly:  'EXTERNAL_CALCULATION'
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      iFmFunctionalArea.FunctionalArea as FunctionalAreaForEdit,
      @ObjectModel.enabled:   'EXTERNAL_CALCULATION'
      @ObjectModel.readOnly:  'EXTERNAL_CALCULATION'
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      iFmFunctionalArea.FunctionalAreaAuthznGrp,
      @ObjectModel.enabled:   'EXTERNAL_CALCULATION'
      @ObjectModel.readOnly:  'EXTERNAL_CALCULATION'
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      iFmFunctionalArea.ValidityStartDate,
      @ObjectModel.enabled:   'EXTERNAL_CALCULATION'
      @ObjectModel.readOnly:  'EXTERNAL_CALCULATION'
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      iFmFunctionalArea.ValidityEndDate,
      @ObjectModel.enabled:   'EXTERNAL_CALCULATION'
      @ObjectModel.readOnly:  'EXTERNAL_CALCULATION'
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      iFmFunctionalArea.ExpirationDate,
      @ObjectModel.readOnly: true
      iFmFunctionalArea.CreatedByUser,
      @Semantics.businessDate.createdAt: true
      @ObjectModel.readOnly: true
      iFmFunctionalArea.CreationDate,
      @Semantics.businessDate.createdAt: true
      @ObjectModel.readOnly: true
      iFmFunctionalArea.CreationTime,    
      
      @ObjectModel.readOnly: true
      cast(dats_tims_to_tstmp(iFmFunctionalArea.CreationDate, iFmFunctionalArea.CreationTime, 
      abap_system_timezone($session.client, 'NULL'), $session.client, 'NULL') as fmmd_creation_timestamp preserving type ) as CreationDateTime,
            
      @ObjectModel.readOnly: true
      iFmFunctionalArea.LastChangedByUser,
      @Semantics.businessDate.lastChangedAt: true
      @ObjectModel.readOnly: true
      iFmFunctionalArea.LastChangeDate,
      @Semantics.businessDate.lastChangedAt: true
      @ObjectModel.readOnly: true
      iFmFunctionalArea.LastChangeTime,
           
      @ObjectModel.readOnly: true
      cast(dats_tims_to_tstmp(iFmFunctionalArea.LastChangeDate, iFmFunctionalArea.LastChangeTime, 
      abap_system_timezone($session.client, 'NULL'), $session.client, 'NULL') as fmmd_change_timestamp preserving type ) as LastChangeDateTime,

      // Subdivision fields

      @ObjectModel.enabled:   'EXTERNAL_CALCULATION'
      @ObjectModel.readOnly:  'EXTERNAL_CALCULATION'
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      iFmFunctionalArea.FunctionalAreaSubdivisionID,      
      @ObjectModel.enabled:   'EXTERNAL_CALCULATION'
      @ObjectModel.readOnly:  'EXTERNAL_CALCULATION'
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      iFmFunctionalArea.FunctionalArea1Subdivision,      
      @ObjectModel.enabled:   'EXTERNAL_CALCULATION'
      @ObjectModel.readOnly:  'EXTERNAL_CALCULATION'
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      iFmFunctionalArea.FunctionalArea2Subdivision,      
      @ObjectModel.enabled:   'EXTERNAL_CALCULATION'
      @ObjectModel.readOnly:  'EXTERNAL_CALCULATION'
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      iFmFunctionalArea.FunctionalArea3Subdivision,      

      //Text

      @ObjectModel.enabled:   'EXTERNAL_CALCULATION'
      @ObjectModel.readOnly:  'EXTERNAL_CALCULATION'
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      iFmFunctionalArea._Text[1:Language=$session.system_language].FunctionalAreaName as FunctionalAreaName,

      //This associations

      iFmFunctionalArea._FunctionalAreaSubdivisionID,
      iFmFunctionalArea._FuncArea1Subdivision,
      iFmFunctionalArea._FuncArea2Subdivision,
      iFmFunctionalArea._FuncArea3Subdivision,
      iFmFunctionalArea._FunctionalArea
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_FUNCTIONALAREATEXT",
"I_FUNDSMGMTFUNCTIONALAREA"
],
"ASSOCIATED":
[
"E_FNDSMGMTFUNCTIONALAREA",
"I_FUNCAREA1SUBDIVISION",
"I_FUNCAREA2SUBDIVISION",
"I_FUNCAREA3SUBDIVISION",
"I_FUNCAREASUBDIVISIONBASIC",
"I_FUNCTIONALAREA"
],
"BASE":
[
"I_FUNDSMGMTFUNCTIONALAREA"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/