I_FundedProgramHierarchy

@ObjectModel.representativeKey: 'FundedProgramHierarchy'
@EndUserText.label: 'Funded Program Hierarchy'
@Analytics: { dataCategory: #DIMENSION, internalName:#LOCAL }
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'IFUNDEDPH'
@AccessControl.authorizationCheck: #CHECK
@AbapCatalog.preserveKey:true
@AbapCatalog.compiler.compareFilter:true
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {
  dataClass: #MASTER,
  serviceQuality: #A,
  sizeCategory: #XL
}

@Metadata.allowExtensions: true

@Analytics.dataExtraction.enabled: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #ANALYTICAL_DIMENSION, #EXTRACTION_DATA_SOURCE ]

@AccessControl.privilegedAssociations: ['_FinancialManagementAreaText']

define view I_FundedProgramHierarchy
  as select from hrrp_directory

  association [1..*] to I_FinancialManagementAreaText as _FinancialManagementAreaText on  $projection.FinancialManagementArea = _FinancialManagementAreaText.FinancialManagementArea

  association [1..*] to I_FundedProgramHierarchyText  as _Text                        on  $projection.FundedProgramHierarchy  = _Text.FundedProgramHierarchy
                                                                                      and $projection.FinancialManagementArea = _Text.FinancialManagementArea

  association [1..1] to I_FinancialManagementArea     as _FinMgmtArea                 on  $projection.FinancialManagementArea = _FinMgmtArea.FinancialManagementArea

{

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_FinMgmtAreaStdVH',
                     element: 'FinancialManagementArea' }
        }]
      @ObjectModel.foreignKey.association: '_FinMgmtArea'
  key cast(hrrp_directory.hrycls as fikrs )                                         as FinancialManagementArea,
      @ObjectModel.text.association: '_Text'
  key cast(hrrp_directory.hryid as fmis_hryid_fundedprogram )                       as FundedProgramHierarchy,
      @Semantics.businessDate.to: true
  key cast(hrrp_directory.hryvalto as fmis_fp_validityenddate preserving type )     as ValidityEndDate,
      @Semantics.businessDate.from: true
      cast(hrrp_directory.hryvalfrom as fmis_fp_validitystartdate preserving type ) as ValidityStartDate,
      @Semantics.user.lastChangedBy: true
      hrrp_directory.upduser                                                        as LastChangedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      hrrp_directory.updtime                                                        as LastChangeDateTime,
      hrrp_directory.hrysid                                                         as HierarchyShortID,
      _FinMgmtArea,
      @Consumption.hidden: true
      _FinancialManagementAreaText,
      _Text

}
where
  hrrp_directory.hrytyp = '0315';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"HRRP_DIRECTORY"
],
"ASSOCIATED":
[
"I_FINANCIALMANAGEMENTAREA",
"I_FINANCIALMANAGEMENTAREATEXT",
"I_FUNDEDPROGRAMHIERARCHYTEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/