I_FundAcctgLineItemCube

@AbapCatalog: { sqlViewName: 'IFALINEITEMC',
                preserveKey: true,
                buffering.status: #NOT_ALLOWED,
                compiler.compareFilter: true }
@AccessControl: { authorizationCheck: #MANDATORY,
                  personalData.blocking: #REQUIRED }
@Analytics: { dataCategory: #CUBE }
@Analytics.internalName:#LOCAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Fund Accounting Line Item - Cube'
@ObjectModel: { usageType: { sizeCategory: #XXL,
                             dataClass:  #MIXED,
                             serviceQuality: #D },
                supportedCapabilities: [#ANALYTICAL_PROVIDER, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE],
                modelingPattern: #ANALYTICAL_CUBE }
@Metadata: { ignorePropagatedAnnotations: true,
             allowExtensions: true }
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #COMPOSITE

define view I_FundAcctgLineItemCube
  as select from I_GLAccountLineItem as I_GLAccountLineItem
  association [0..1] to I_FundType               as _FundType                 on  $projection.FinancialManagementArea = _FundType.FinancialManagementArea
                                                                              and $projection.fundtype                = _FundType.FundType
  association [0..1] to I_Grant                  as _Grant                    on  $projection.GrantID = _Grant.GrantID
  association [0..1] to I_GrantType              as _GrantType                on  $projection.granttype = _GrantType.GrantType
{
      @ObjectModel.foreignKey.association: '_Ledger'
  key Ledger,
      @ObjectModel.foreignKey.association: '_SourceLedger'
  key SourceLedger,
      @ObjectModel.foreignKey.association: '_CompanyCode'
  key CompanyCode,
      @ObjectModel.foreignKey.association: '_FiscalYear'
  key cast( FiscalYear as fis_gjahr_no_conv preserving type )                 as FiscalYear,
      @ObjectModel.foreignKey.association: '_JournalEntry'
  key AccountingDocument,
  key LedgerGLLineItem,
      @ObjectModel.foreignKey.association: '_LedgerFiscalYearForVariant'
      @Semantics.fiscal.year: true
      LedgerFiscalYear,
      @ObjectModel.foreignKey.association: '_ControllingArea'
      ControllingArea,
      @ObjectModel.foreignKey.association: '_ChartOfAccounts'
      ChartOfAccounts,
      @ObjectModel.foreignKey.association: '_GLAccountInChartOfAccounts'
      GLAccount,
      @ObjectModel.foreignKey.association: '_CostCenter'
      CostCenter,
      @ObjectModel.foreignKey.association: '_ProfitCenter'
      ProfitCenter,
      @ObjectModel.foreignKey.association: '_FunctionalArea'
      FunctionalArea,
      @ObjectModel.foreignKey.association: '_FiscalPeriodForVariant'
      @Semantics.fiscal.period: true
      FiscalPeriod,
      @ObjectModel.foreignKey.association: '_FiscalYearVariant'
      @Semantics.fiscal.yearVariant: true
      FiscalYearVariant,
      PostingDate,
      @ObjectModel.foreignKey.association: '_AccountingDocumentType'
      AccountingDocumentType,
      @ObjectModel.foreignKey.association: '_AlternativeGLAccount'
      AlternativeGLAccount,
      @ObjectModel.foreignKey.association: '_CountryChartOfAccounts'
      CountryChartOfAccounts,
      InvoiceReference,
      @Semantics.fiscal.year: true
      InvoiceReferenceFiscalYear,
      InvoiceItemReference,
      @ObjectModel.foreignKey.association: '_SalesDocument'
      SalesDocument,
      @ObjectModel.foreignKey.association: '_Product'
      Product,
      @ObjectModel.foreignKey.association: '_Plant'
      Plant,
      @ObjectModel.foreignKey.association: '_Supplier'
      Supplier,
      @ObjectModel.foreignKey.association: '_Customer'
      Customer,
      @ObjectModel.foreignKey.association: '_FinancialAccountType'
      FinancialAccountType,
      @Semantics.booleanIndicator
      IsOpenItemManaged,
      ClearingDate,
      @Semantics.fiscal.year: true
      ClearingDocFiscalYear,
      @ObjectModel.foreignKey.association: '_Segment'
      Segment,
      @ObjectModel.foreignKey.association: '_BusinessArea'
      BusinessArea,
      CostObject,
      @ObjectModel.foreignKey.association: '_FinancialTransactionType'
      FinancialTransactionType,
      @ObjectModel.foreignKey.association: '_Fund'
      Fund,
      @Analytics.internalName: #LOCAL
      @ObjectModel.foreignKey.association: '_FundType'
      _Fund.FundType,
      @ObjectModel.foreignKey.association: '_FinancialManagementArea'
      FinancialManagementArea,
      @ObjectModel.foreignKey.association: '_GLAccountType'
      GLAccountType,
      @Analytics.internalName: #LOCAL
      @ObjectModel.foreignKey.association: '_Grant'
      GrantID,
      @Analytics.internalName: #LOCAL
      @ObjectModel.foreignKey.association: '_GrantType'
      _Grant.GrantType,
      AssetClass,
      DistributionChannel,
      OrganizationDivision,
      SalesOrganization,
      ServiceDocumentType,
      ValuationArea,
      OrderID,
      ServiceDocument,
      @Semantics.currencyCode: true
      @ObjectModel.foreignKey.association: '_CompanyCodeCurrency'
      CompanyCodeCurrency,
      @Aggregation.default: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      AmountInCompanyCodeCurrency,
      _Grant.GrantIsNotRelevantGrant,
      _Grant.GrantLifecycleStatus,
      _Grant.GrantAuthznGrp,
      _Grant.GranteeMgmtSponsor,

      _FinancialManagementArea,
      _Grant,
      _Grant._Sponsor,
      _GrantType,
      _FundType,
      _JournalEntry,
      _CompanyCode,
      _FiscalYear,
      _FiscalPeriodForVariant,
      _LedgerFiscalYearForVariant,
      _FiscalYearVariant,
      _Fund,
      _ControllingArea,
      _GLAccountType,
      _Product,
      _CompanyCodeCurrency,
      _Segment,
      _ProfitCenter,
      _CostCenter,
      _SalesDocument,
      _BusinessArea,
      _FunctionalArea,
      _GLAccountInChartOfAccounts,
      _GLAccountInCompanyCode,
      _ChartOfAccounts,
      _AccountingDocumentType,
      _FinancialAccountType,
      _Plant,
      _Ledger,
      _SourceLedger,
      _Customer,
      _Supplier,
      _FinancialTransactionType,
      _AlternativeGLAccount,
      _CountryChartOfAccounts,
      _CurrentCostCenter,
      _CurrentProfitCenter,
      _Order,
      _ServiceDocument
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_FUND",
"I_GLACCOUNTLINEITEM",
"I_GRANT"
],
"ASSOCIATED":
[
"I_ACCOUNTINGDOCUMENTTYPE",
"I_BUSINESSAREA",
"I_BUSINESSPARTNER",
"I_CHARTOFACCOUNTS",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_COSTCENTER",
"I_CURRENCY",
"I_CUSTOMER",
"I_FINANCIALACCOUNTTYPE",
"I_FINANCIALMANAGEMENTAREA",
"I_FINANCIALTRANSACTIONTYPE",
"I_FISCALPERIODFORVARIANT",
"I_FISCALYEARFORCOMPANYCODE",
"I_FISCALYEARFORVARIANT",
"I_FISCALYEARVARIANT",
"I_FUNCTIONALAREA",
"I_FUND",
"I_FUNDTYPE",
"I_GLACCOUNTINCHARTOFACCOUNTS",
"I_GLACCOUNTINCOMPANYCODE",
"I_GLACCOUNTTYPE",
"I_GRANT",
"I_GRANTTYPE",
"I_JOURNALENTRY",
"I_LEDGER",
"I_ORDER",
"I_PLANT",
"I_PRODUCT",
"I_PROFITCENTER",
"I_SALESDOCUMENT",
"I_SEGMENT",
"I_SRVCDOCBYDOCUMENTTYPE",
"I_SUPPLIER"
],
"BASE":
[
"I_GLACCOUNTLINEITEM",
"I_GRANT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/