I_FulfillmentStatusText

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.dataCategory: #TEXT
@ObjectModel.representativeKey: 'FulfillmentStatus'
@ObjectModel.usageType.dataClass: #META
@ObjectModel.usageType.serviceQuality: #A 
@ObjectModel.usageType.sizeCategory: #S
@EndUserText.label: 'Fulfillment Status Text'
@VDM.viewType: #BASIC
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AbapCatalog.sqlViewName: 'ISOFLFLMTSTATT'
@AbapCatalog.buffering.status: #ACTIVE
@AbapCatalog.buffering.type: #FULL 
@Search.searchable: true

define view I_FulfillmentStatusText
as select from dd07t

association[0..1] to I_FulfillmentStatus as _FulfillmentStatus on $projection.FulfillmentStatus = _FulfillmentStatus.FulfillmentStatus 
association[0..1] to I_Language as _Language on $projection.Language = _Language.Language
{
    @ObjectModel.foreignKey.association: '_FulfillmentStatus' 
    @ObjectModel.text.element: ['FulfillmentStatusDescription']
    key SUBSTRING(dd07t.domvalue_l, 1, 1) as FulfillmentStatus,
    
    @Semantics.language
    @ObjectModel.foreignKey.association: '_Language' 
    key ddlanguage as Language,
    
    @Semantics.text: true
    @Search.defaultSearchElement: true
    @Search.fuzzinessThreshold: 0.8
    @Search.ranking: #LOW
    ddtext as FulfillmentStatusDescription,
    
    //Associations

    _FulfillmentStatus,
    _Language
} 

where domname = 'SLSORDERFLFLLMNTCATEGORYSTATUS' and as4local = 'A';   
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_FULFILLMENTSTATUS",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/