I_FreightContractVH

@AbapCatalog.sqlViewName: 'IFRCNTRCTVH'
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #BASIC
@Search.searchable: true
@ObjectModel:{
    usageType.serviceQuality: #D,
    usageType.sizeCategory: #L,
    usageType.dataClass: #TRANSACTIONAL
    }
@AbapCatalog.preserveKey:true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData: {blocking: #REQUIRED}
@EndUserText.label: 'Value Help for Freight Contract'
@ClientHandling.algorithm: #SESSION_VARIABLE
define view I_FreightContractVH
  as select from    ekko                    as a
    left outer join I_FreightContractItemVH as b on a.ebeln = b.FreightContract
    left outer join lfa1                    as c on a.lifnr = c.lifnr
    left outer join eket                    as d on  b.FreightContract        = d.ebeln
                                                 and b.PurchasingDocumentItem = d.ebelp
    left outer join t161                    as e on  a.bstyp = e.bstyp
                                                 and a.bsart = e.bsart
    left outer join oij_el_layt_inf         as f on a.ebeln = f.vbeln
  // added for dpp by aishwarya

    left outer join oij_el_cp_layt          as g on  b.FreightContract     = g.vbeln
                                                 and b.FreightContractItem = g.posnr

  association [0..1] to I_NominationVehicleIdVH as _VehicleId on $projection.VehicleId = _VehicleId.VehicleId
  association [0..1] to I_Supplier              as _Supplier  on $projection.Supplier = _Supplier.Supplier
{
      @Search.defaultSearchElement: true
      @EndUserText.label: 'Freight Contract'
  key a.ebeln                         as FreightContract,
      @EndUserText.label: 'Freight Contract Item'
  key b.FreightContractItem           as FreightContractItem,
      @UI.hidden: true
  key f.seqnr                         as SequenceNumber,
      @UI.hidden: true
      d.etenr                         as ScheduleLine,
      b.Material                      as Material,
      b.Plant                         as Plant,
      @UI.hidden: true
      b.StorageLocation               as StorageLocation,
      @UI.hidden: true
      a.lifnr                         as Supplier,
      @UI.hidden: true
      c.name1                         as OrganizationBPName1,
      @UI.hidden: true
      a.ekorg                         as PurchasingOrganization,
   //   @UI.selectionField: [{exclude: true}]

      a.bsart                         as PurchasingDocumentType,
      @UI.hidden: true
      b.OrderQuantity                 as OrderQuantity,
      @UI.hidden: true
      b.OrderQuantityUnit             as OrderQuantityUnit,
      @UI.hidden: true
      b.ValuationType                 as ValuationType,
      @UI.hidden: true
      d.charg                         as Batch,
      @UI.hidden: true
      b.NetPriceAmount                as NetPriceAmount,
      @UI.hidden: true
      b.DocumentCurrency              as DocumentCurrency,
      @UI.hidden: true
      b.ExchangeAgreement             as ExchangeAgreement,
      @UI.hidden: true
      b.ExchangeAgreementType         as ExchangeAgreementType,
      @UI.hidden: true
      b.ModeOfTransport               as ModeOfTransport,
      @EndUserText.label: 'Location'
      @UI.hidden: true
      f.locid                         as LocationId,
      // added for dpp by aishwarya

      @UI.hidden: true
      g.vehicle                       as VehicleId,
      @UI.hidden: true
      a.bukrs                         as CompanyCode,
      _VehicleId,
      @Consumption.valueHelp: '_Supplier'
      _Supplier
}
where
      a.bstyp = 'K'
  and a.bsart = 'FC'
  and a.loekz = ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_FREIGHTCONTRACTITEMVH",
"EKET",
"EKKO",
"LFA1",
"OIJ_EL_CP_LAYT",
"OIJ_EL_LAYT_INF",
"T161"
],
"ASSOCIATED":
[
"I_NOMINATIONVEHICLEIDVH",
"I_SUPPLIER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/