I_FndsMgmtFunctionalAreaCoreTP

@AbapCatalog.sqlViewName: 'IFMFUNCNLACORETP'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations:  ['_UserCreated', '_UserChanged']
@EndUserText.label: 'Manage Functional Area'

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

@ObjectModel.sapObjectNodeType.name: 'FunctionalArea'

@ObjectModel: {
     modelCategory: #BUSINESS_OBJECT,
     compositionRoot: true,
     transactionalProcessingEnabled: true,
     createEnabled: true,
     updateEnabled: true,
     deleteEnabled: true,
     representativeKey: 'FunctionalArea',
     semanticKey:  [ 'FunctionalArea' ],

     draftEnabled: true,
     writeDraftPersistence: 'FMC_D_FUNCAR_DFT',
     entityChangeStateId: 'EXTERNAL_CALCULATION',
     lifecycle.draft.expiryBehavior: #RELATIVE_TO_PROCESSING_START,
     lifecycle.draft.expiryInterval: 'P5D',
     usageType: {
        dataClass: #MASTER,
        serviceQuality: #C,
        sizeCategory: #L
     }
}

// Comment added to check BO sync errors - remove later


define view I_FndsMgmtFunctionalAreaCoreTP
  as select from I_FundsMgmtFunctionalArea as funcnlarea
  association [0..1] to E_FndsMgmtFunctionalArea as _Extension    on $projection.FunctionalArea = _Extension.FunctionalArea
  association [0..1] to I_User                   as _UserCreated on $projection.CreatedByUser = _UserCreated.UserID
  association [0..1] to I_User                   as _UserChanged on $projection.LastChangedByUser = _UserChanged.UserID
{
      //funcnlarea

      @ObjectModel.readOnly: true
  key funcnlarea.FunctionalArea,
      @ObjectModel.enabled:   'EXTERNAL_CALCULATION'
      @ObjectModel.readOnly:  'EXTERNAL_CALCULATION'
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      funcnlarea.FunctionalArea                                                                                                     as FunctionalAreaForEdit,
      @ObjectModel.enabled:   'EXTERNAL_CALCULATION'
      @ObjectModel.readOnly:  'EXTERNAL_CALCULATION'
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      funcnlarea.FunctionalAreaAuthznGrp,
      @ObjectModel.enabled:   'EXTERNAL_CALCULATION'
      @ObjectModel.readOnly:  'EXTERNAL_CALCULATION'
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      funcnlarea.ValidityStartDate,
      @ObjectModel.enabled:   'EXTERNAL_CALCULATION'
      @ObjectModel.readOnly:  'EXTERNAL_CALCULATION'
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      funcnlarea.ValidityEndDate,
      @ObjectModel.enabled:   'EXTERNAL_CALCULATION'
      @ObjectModel.readOnly:  'EXTERNAL_CALCULATION'
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      funcnlarea.ExpirationDate,
      @Semantics.user.createdBy: true
      @ObjectModel.readOnly: true
      funcnlarea.CreatedByUser,
      @ObjectModel.readOnly: true
      case
      when _UserCreated.UserDescription  is initial then funcnlarea.CreatedByUser
      else _UserChanged.UserDescription  end                                                                                       as CreatedByUserName,
      //@Semantics.systemDate.createdAt: true

      @Semantics.businessDate.createdAt: true
      //  @Semantics.systemDate.createdAt: true

      @ObjectModel.readOnly: true
      funcnlarea.CreationDate,
      //@Semantics.systemTime.createdAt: true

      @ObjectModel.readOnly: true
      funcnlarea.CreationTime,
      @Semantics.user.lastChangedBy: true
      @ObjectModel.readOnly: true
      funcnlarea.LastChangedByUser,
      @ObjectModel.readOnly: true
      case
      when  _UserCreated.UserDescription is initial  then  funcnlarea.LastChangedByUser
      else _UserChanged.UserDescription     end                                                                                    as LastChangeByUserName,
      @Semantics.systemDate.lastChangedAt: true
      @ObjectModel.readOnly: true
      funcnlarea.LastChangeDate,
      //@Semantics.systemTime.lastChangedAt: true

      @ObjectModel.readOnly: true
      funcnlarea.LastChangeTime,

      //Text

      @ObjectModel.enabled:   'EXTERNAL_CALCULATION'
      @ObjectModel.readOnly:  'EXTERNAL_CALCULATION'
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      cast( funcnlarea._Text[1:Language=$session.system_language].FunctionalAreaName as fis_fkbtx preserving type )                 as FunctionalAreaName,
      /* Associations */
      //funcnlarea

      funcnlarea._FunctionalArea,
      
      @Consumption.filter.hidden: true
      @UI.hidden: true
      _UserCreated,
      
      @Consumption.filter.hidden: true
      @UI.hidden: true
      _UserChanged
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_FUNCTIONALAREATEXT",
"I_FUNDSMGMTFUNCTIONALAREA",
"I_USER"
],
"ASSOCIATED":
[
"E_FNDSMGMTFUNCTIONALAREA",
"I_FUNCTIONALAREA",
"I_USER"
],
"BASE":
[
"I_FUNDSMGMTFUNCTIONALAREA"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/