I_FlxMtPlObjVariant

@AbapCatalog.sqlViewName: 'IFMPOVARIANT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'List of Variants linked to a FMPO Header'
@VDM.viewType: #BASIC
@ObjectModel.representativeKey: 'FlxblMatlPlngObjVariantUUID'
@ObjectModel.usageType.serviceQuality:#A
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.sizeCategory: #L
@ClientHandling.algorithm: #SESSION_VARIABLE
@Search.searchable: true
@Metadata.ignorePropagatedAnnotations: true

@Analytics:{

    dataCategory: #DIMENSION,
    dataExtraction.enabled: true,
    dataExtraction.delta.changeDataCapture.automatic: true
    }

@ObjectModel.supportedCapabilities: [ #SQL_DATA_SOURCE,
                                      #CDS_MODELING_DATA_SOURCE,
                                      #ANALYTICAL_DIMENSION,
                                      #EXTRACTION_DATA_SOURCE,
                                      #CDS_MODELING_ASSOCIATION_TARGET,
                                      #SEARCHABLE_ENTITY ]
                                      
@Metadata.allowExtensions:true

define view I_FlxMtPlObjVariant
  as select from dfs_fmpo_varnt
  association [1..1] to I_FlxMtPlObj           as _FlxMtPlObj       on $projection.FlxblMatlPlngObjectUUID = _FlxMtPlObj.FlxblMatlPlngObjectUUID
  association [1..1] to I_ExtProdGrp           as _ExtProdGrp       on $projection.FlxMtPlObjVarExternalProdGroup = _ExtProdGrp.ExternalProductGroup
  association [0..1] to I_DFS_StatusAttributes as _StatusAttributes on $projection.FlxMtPlObjVarStatusCode = _StatusAttributes.SystemStatus
  association [0..1] to I_StatusObject         as _StatusObject     on $projection.DfsAssgmtStatusObject = _StatusObject.StatusObject
  association [1..1] to I_ProductGroup_2       as _ProductGroup     on $projection.MaterialGroup = _ProductGroup.ProductGroup
  
  association [1..1] to I_FlxMtPlObjVarDescription as _VarDescrip   on $projection.FlxblMatlPlngObjVariantUUID = _VarDescrip.FlxblMatlPlngObjVariantUUID
                                                                        and _VarDescrip.Language           = $session.system_language

  association [0..1] to E_FlxMtPlObjVariant    as _Extension        on $projection.FlxblMatlPlngObjVariantUUID = _Extension.FlxblMatlPlngObjVariantUUID
  //  Added for Structural Authorization

  association [1..1] to I_FlxMtPlObjWithAuthorization as _Authorization  on  _Authorization.FlxblMatlPlngObjectUUID = $projection.FlxblMatlPlngObjectUUID 
                                                                        and _Authorization.DfsIsStrucAuthznEnabled = 'X'
  //  Added for Structural Authorization

{

  key flxblmatlplngobjvariantuuid                                                        as FlxblMatlPlngObjVariantUUID,
      flxblmatlplngobjectuuid                                                            as FlxblMatlPlngObjectUUID,

      @Search.defaultSearchElement: true
      //      @Search.fuzzinessThreshold: 0.8

      flxblmatlplngobjvariantid                                                          as FlxblMatlPlngObjVariantID,
      //_FlxMtPlObj.FlxblMatlPlngObjectID                                                  as FlxblMatlPlngObjectID,

      dfsassgmtstatusobject                                                              as DfsAssgmtStatusObject,
      flxmtplobjvarstatuscode                                                            as FlxMtPlObjVarStatusCode,

      cast(materialgroup as productgroup preserving type )                               as MaterialGroup,

      cast(flxmtplobjvarexternalprodgroup as externalproductgroup preserving type )      as FlxMtPlObjVarExternalProdGroup,

      flxmtplobjvarproduct                                                               as FlxMtPlObjVarProduct,
      flxmtplobjvarisrelocrlvt                                                           as FlxMtPlObjVarIsRelocRlvt,
      flxmtplobjvarisserialnmbrrlvt                                                      as FlxMtPlObjVarIsSerialNmbrRlvt,
//      flxblmatlplngobjvariantdesc                                                        as FlxblMatlPlngObjVariantDesc,

      @Search.defaultSearchElement: true
      @Analytics.hidden: true
      _VarDescrip.FlxblMatlPlngObjVariantDesc                                            as FlxblMatlPlngObjVariantDesc,
      flxmtplobjvarrespplnrobjtype                                                       as FlxMtPlObjVarRespPlnrObjType,
      flxmtplobjvarrespplnrobjectid                                                      as FlxMtPlObjVarRespPlnrObjectID,
      flxmtplobjvarownerobjecttype                                                       as FlxMtPlObjVarOwnerObjectType,
      flxmtplobjvarownerobjectid                                                         as FlxMtPlObjVarOwnerObjectID,
      @Semantics.systemDateTime.createdAt: true
      flxmtplobjvarcreationdatetime                                                      as FlxMtPlObjVarCreationDateTime,
      @Semantics.user.createdBy:true
      flxmtplobjvariantcreatedbyuser                                                     as FlxMtPlObjVariantCreatedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      flxmtplobjvarlastchangeddtetme                                                     as FlxMtPlObjVarLastChangedDteTme,
      @Semantics.user.lastChangedBy: true
      flxmtplobjvariantlastchangedby                                                     as FlxMtPlObjVariantLastChangedBy,
      cast (packinginstructionsystemuuid as pl_packnr preserving type )                  as PackingInstructionSystemUUID,                
      
       //Added for Structural Authorization

       @Semantics.booleanIndicator:true       
       _Authorization.DfsIsStrucAuthznEnabled as DfsIsStrucAuthznEnabled,
       _Authorization,
      _FlxMtPlObj,
      _StatusAttributes,
      _StatusObject,
      _ProductGroup,
      _ExtProdGrp
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_FLXMTPLOBJVARDESCRIPTION",
"I_FLXMTPLOBJWITHAUTHORIZATION",
"DFS_FMPO_VARNT"
],
"ASSOCIATED":
[
"E_FLXMTPLOBJVARIANT",
"I_DFS_STATUSATTRIBUTES",
"I_EXTPRODGRP",
"I_FLXMTPLOBJ",
"I_FLXMTPLOBJVARDESCRIPTION",
"I_FLXMTPLOBJWITHAUTHORIZATION",
"I_PRODUCTGROUP_2",
"I_STATUSOBJECT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/