I_FldLogsMatlDocumentRecord

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Field Logistics Material Document Record'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #A,
  sizeCategory: #XXL,
  dataClass: #TRANSACTIONAL
}
@VDM: {
        private: false,
        viewType: #BASIC,
        lifecycle.contract.type: #SAP_INTERNAL_API
        }
define view entity I_FldLogsMatlDocumentRecord
  as select from matdoc
{
  key mblnr                                     as MaterialDocument,
  key mjahr                                     as MaterialDocumentYear,
  key zeile                                     as MaterialDocumentItem,
      //      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'   //v2813353

      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit' --Inc# 2380137735
      @DefaultAggregation: #NONE
      bstmg                                     as GoodsReceiptQtyInOrderUnit,
      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      @DefaultAggregation: #NONE
      menge                                     as QuantityInBaseUnit,
      meins                                     as MaterialBaseUnit,
      ebeln                                     as PurchaseOrder,
      ebelp                                     as PurchaseOrderItem,
      bwart                                     as GoodsMovementType,
      cast(sjahr as nsdm_sjahr preserving type) as ReversedMaterialDocumentYear,
      cast(smbln as nsdm_smbln preserving type) as ReversedMaterialDocument,
      cast(smblp as nsdm_smblp preserving type) as ReversedMaterialDocumentItem,
      matnr                                     as Material,
      @Consumption.hidden: true
      record_type                               as MaterialDocumentRecordType,
      @Consumption.hidden: true
      header_counter                            as IsMaterialDocumentHeader,
      werks                                     as Plant,
      cast(umwrk as nsdm_plant preserving type) as IssuingOrReceivingPlant,

      vbeln_im                                  as DeliveryDocument,
      vbelp_im                                  as DeliveryDocumentItem,
      cancelled                                 as GoodsMovementIsCancelled,
      reversal_movement                         as IsReversalMovementType,

      @Semantics.booleanIndicator: true
      xauto                                     as IsAutomaticallyCreated,
      matbf                                     as StockIdentifyingMaterial,
      lbbsa_sid                                 as InventoryStockType,
      lgort_sid                                 as StockIdfgStorageLocation,
      cast(mat_pspnr  as ps_s4_pspnr )          as SpecialStockIdfgWBSElement, //Cast required for conversion exit

      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      stock_qty                                 as MatlStkChangeQtyInBaseUnit,
      charg_sid                                 as Batch,
      bwtar                                     as ValuationType,

      @Semantics.businessDate.at: true
      budat                                     as PostingDate, // #Add Date fields to each milestone

      bstme                                     as OrderQuantityUnit --Inc# 2380137735
}

where
  record_type = 'MDOC'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"MATDOC"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/