I_FldLogsDeliveryDocItem

@AbapCatalog.sqlViewName: 'IFLDLVITM'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl:
{
 authorizationCheck: #CHECK,
  personalData.blocking: #BLOCKED_DATA_EXCLUDED
}
@VDM.viewType: #BASIC
@ObjectModel.usageType: {serviceQuality: #C,
                         dataClass: #TRANSACTIONAL,
                         sizeCategory: #L}
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Delivery Items for FL'
define view I_FldLogsDeliveryDocItem
  as select from lips as _DeliveryDocItem
    inner join   likp as _DeliveryDoc on _DeliveryDocItem.vbeln = _DeliveryDoc.vbeln
  association [0..1] to I_Customer as _SoldToParty on $projection.SoldToParty = _SoldToParty.Customer
  association [0..1] to I_Customer as _ShipToParty on $projection.ShipToParty = _ShipToParty.Customer
  association [0..1] to I_Supplier as _Supplier    on $projection.Supplier = _Supplier.Supplier
{
  key _DeliveryDocItem.vbeln                                            as DeliveryDocument,
  key _DeliveryDocItem.posnr                                            as DeliveryDocumentItem,
      _DeliveryDocItem.vgbel                                            as ReferenceSDDocument,
      _DeliveryDocItem.vgpos                                            as ReferenceSDDocumentItem,
      cast(substring(_DeliveryDocItem.vgpos, 2, 5) as ebelp)            as PurchasingDocumentItem,
      _DeliveryDocItem.lgort                                            as StorageLocation,
      @Semantics.quantity.unitOfMeasure: 'DeliveryQuantityUnit'
      _DeliveryDocItem.lfimg                                            as ActualDeliveryQuantity,
      @Semantics.unitOfMeasure: true
      _DeliveryDocItem.vrkme                                            as DeliveryQuantityUnit,
      _DeliveryDocItem.wbsta                                            as GoodsMovementStatus,
      _DeliveryDocItem.bwart                                            as GoodsMovementType,
      _DeliveryDocItem.bwtar                                            as InventoryValuationType,
      _DeliveryDocItem.flpkz                                            as FldLogsStatus,
      _DeliveryDocItem.charg                                            as Batch,
      _DeliveryDocItem.handle                                           as DeliveryDocumentUUID,
      _DeliveryDoc.lfdat                                                as DeliveryDate,
      _DeliveryDoc.vbtyp                                                as SDDocumentCategory,
      _DeliveryDoc.vlstk                                                as DistrStatusByDecentralizedWrhs,
      _DeliveryDoc.lifex                                                as DeliveryDocumentBySupplier,
      _DeliveryDoc.lifsk                                                as DeliveryBlockReason,

      _DeliveryDoc.lstel                                                as LoadingPoint,
      _DeliveryDoc.ablad                                                as UnloadingPointName,
      _DeliveryDocItem.kosta                                            as PickingStatus,
      _DeliveryDoc.lfart                                                as DeliveryDocumentType,


      cast(_DeliveryDoc.lifnr as lifnr preserving type )                as Supplier,

      _DeliveryDoc.kunag                                                as SoldToParty,

      _DeliveryDoc.kunnr                                                as ShipToParty,
      _ShipToParty,
      _SoldToParty,
      _Supplier,

      //EWM Reference Document Number Item

      cast(lpad(_DeliveryDocItem.posnr, 10, '0') as /scdl/dl_refitemno) as EWMRefDeliveryDocumentItem
}
where
  _DeliveryDocItem.lfimg is not initial
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"LIKP",
"LIPS"
],
"ASSOCIATED":
[
"I_CUSTOMER",
"I_SUPPLIER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/