I_FinancialTransactionStdVH

//GENERATED:001:E6ExH29r7jUzzJ}fF{7DBm

@AbapCatalog.sqlViewName: 'IFTRFT__VH'
@AbapCatalog.compiler.compareFilter: true

@VDM.viewType: #COMPOSITE

@ObjectModel.dataCategory: #VALUE_HELP
@ObjectModel.representativeKey: 'FinancialTransaction'

@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L

@AccessControl.authorizationCheck: #CHECK

@ClientHandling.algorithm: #SESSION_VARIABLE

@Metadata.ignorePropagatedAnnotations: true

@EndUserText.label: 'FinancialTransaction'
@Consumption.ranked: true
@Search.searchable: true
@AccessControl.privilegedAssociations: [ '_CreatedBy','_LastChangedBy' ]
@AccessControl.personalData.blocking: #NOT_REQUIRED
define view I_FinancialTransactionStdVH
  as select from I_FinancialTransaction
  association [0..1] to I_UserContactCard     as _CreatedBy     on $projection.CreatedByUser = _CreatedBy.ContactCardID
  association [0..1] to I_UserContactCard     as _LastChangedBy on $projection.LastChangedByUser = _LastChangedBy.ContactCardID
{


      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
      @Search.fuzzinessThreshold: 0.8
      @UI.lineItem.importance: #HIGH
  key FinancialTransaction,

      @Consumption.valueHelpDefinition: [{entity:{
                                                    name:    'I_CompanyCodeStdVH',
                                                    element: 'CompanyCode'
                                                 }
      }]
      @ObjectModel.foreignKey.association: '_CompanyCode'
      @Search.ranking: #LOW
      @Search.fuzzinessThreshold: 0.8
      @UI.lineItem.importance: #HIGH
  key CompanyCode,

      @Search.ranking: #LOW
      @Search.fuzzinessThreshold: 0.8
      @Consumption.valueHelpDefinition: [{entity:{
                                                    name:    'I_FinancialInstrTransType',
                                                    element: 'FinancialInstrTransactionType'
                                                 }
      }]
      @UI.lineItem.importance: #HIGH
      FinancialInstrTransactionType,

      @Search.ranking: #LOW
      @Search.fuzzinessThreshold: 0.8
      @Consumption.valueHelpDefinition: [{entity :{
                                                      name:     'I_FinancialinstrProductType',
                                                      element:  'FinancialInstrumentProductType'
                                                  }
      }]
      @UI.lineItem.importance: #HIGH
      FinancialInstrumentProductType,

      @Search.ranking: #LOW
      @Search.fuzzinessThreshold: 0.8
      @Consumption.valueHelpDefinition: [{entity :{
                                                      name:     'I_FinTransacCounterPartyStdVH',
                                                      element:  'BusinessPartner'
                                                  }
      }]
      Counterparty,

      @Consumption.hidden: true
      CreatedByUser,
      @Search.ranking: #LOW
      @Search.fuzzinessThreshold: 0.8
      @EndUserText.label: 'Created By'
      @Semantics.text: true
      _CreatedBy.FullName                                                                               as CreatedByUserDescription,
      @Consumption.filter: {selectionType: #INTERVAL}
      FinTransCreationDate,
      @Consumption.hidden: true
      LastChangedByUser,
      @Search.ranking: #LOW
      @Search.fuzzinessThreshold: 0.8
      @EndUserText.label: 'Last Changed By'
      @Semantics.text: true
      _LastChangedBy.FullName                                                                           as LastChangedByUserDescription,
      @Consumption.filter: {selectionType: #INTERVAL}
      LastChangeDate,
      @Consumption.valueHelpDefinition: [{entity :{
                                                      name:     'I_FinInstrumentStatus',
                                                      element:  'FinancialInstrumentStatus'
                                                  }
      }]
      FinancialInstrumentStatus,
      @Consumption.valueHelpDefinition: [{entity :{
                                                  name:     'I_TreasuryPortfolio',
                                                  element:  'Portfolio'
                                              }
      }]
      Portfolio,
      @Consumption.hidden: true
      SecurityAccount,

      @Consumption.hidden: true
      _CreatedBy,
      @Consumption.hidden: true
      _LastChangedBy,
      @Consumption.hidden: true
      _CompanyCode
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_FINANCIALTRANSACTION",
"I_USERCONTACTCARD"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_USERCONTACTCARD"
],
"BASE":
[
"I_FINANCIALTRANSACTION"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/