I_FinancialStatementHierNodeT

@AbapCatalog.sqlViewName: 'IFISTMTHERNDT'
@ObjectModel.dataCategory: #TEXT
@AccessControl.authorizationCheck: #CHECK
@AbapCatalog.buffering.status: #NOT_ALLOWED
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass:  #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Financial Statement Hierarchy Node - Text'
@ObjectModel.representativeKey: 'HierarchyNode'
@ObjectModel.supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #LANGUAGE_DEPENDENT_TEXT, #EXTRACTION_DATA_SOURCE]
@AbapCatalog.compiler.compareFilter:true
@AbapCatalog.preserveKey:true
@Analytics: { dataExtraction.enabled: true}
@VDM.viewType: #BASIC
define view I_FinancialStatementHierNodeT
  as select from hrrp_nodet_n
  association [0..1] to I_Language                   as _Language  on  $projection.Language = _Language.Language

  association [0..*] to I_GLAccountHierarchy         as _Hierarchy on  $projection.FinancialStatementHierarchy = _Hierarchy.GLAccountHierarchy

  association [0..1] to I_FinancialStatementHierNode as _node      on  $projection.FinancialStatementHierarchy = _node.FinancialStatementHierarchy
                                                                   and $projection.HierarchyNode               = _node.HierarchyNode
                                                                   and $projection.ValidityEndDate             = _node.ValidityEndDate
{
      @ObjectModel.foreignKey.association: '_Hierarchy'
  key hrrp_nodet_n.hryid_42                  as FinancialStatementHierarchy,
      @ObjectModel.text.element: 'HierarchyNodeText'
  key hrrp_nodet_n.hrynode                   as HierarchyNode,
      @Semantics.businessDate.to: true
  key hrrp_nodet_n.hryvalto                  as ValidityEndDate,
      @Semantics.language: true
  key hrrp_nodet_n.spras                     as Language,
      @Semantics.text: true
      hrrp_nodet_n.nodetxt                   as HierarchyNodeText,
      @Semantics.text: true
      substring(hrrp_nodet_n.nodetxt, 1, 20) as HierarchyNodeShortText,

      @Semantics.businessDate.from: true
      hrrp_nodet_n.hryvalfrom                as ValidityStartDate,

      _node.FinStmntNodeFormattedID,

      _Language,
      _Hierarchy
}
where
      hrrp_nodet_n.hrytyp    =    'FSVN'
  and not hrrp_nodet_n.hryid like '0109/%'
  and not hrrp_nodet_n.hryid like '0102/%'
  and not hrrp_nodet_n.hryid like 'H109/%'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_FINANCIALSTATEMENTHIERNODE",
"HRRP_NODET_N"
],
"ASSOCIATED":
[
"I_FINANCIALSTATEMENTHIERNODE",
"I_GLACCOUNTHIERARCHY",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/