I_FinTransSecurity

@AbapCatalog.sqlViewName: 'IFINTRANSSCRTY'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AbapCatalog.buffering.status: #NOT_ALLOWED
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Fin Trans Securities Information'
@ObjectModel.representativeKey: 'FinancialTransaction'
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #L
@Metadata.allowExtensions:false
@Metadata.ignorePropagatedAnnotations: true // For C1-Release

@VDM.viewType: #COMPOSITE
@ObjectModel.supportedCapabilities: [ #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE ]

//view shall provide securities data based on main flow

define view I_FinTransSecurity
  as select from vtbfha as Deal  
  // only the main flow of current activity

  // Both of securities quantity flow and securities payment flow contain payment information.

  // So to improve the performance, we can get all data from quantity flow directly.

    inner join   R_FinTransSecurityQuantityFlow as Flow on  Deal.bukrs          = Flow.CompanyCode
                                                        and Deal.rfha           = Flow.FinancialTransaction
                                                        and Deal.rfhazul        = Flow.FinancialInstrumentActivity
  // dimensions, containing for example text fields

  association [0..1] to I_CompanyCode          as _CompanyCode       on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_FinancialTransaction as _FinTrans          on  $projection.CompanyCode          = _FinTrans.CompanyCode
                                                                     and $projection.FinancialTransaction = _FinTrans.FinancialTransaction
  association [0..1] to I_Currency             as _NominalCurrency   on  $projection.FinTransFlowNomAmtCrcy = _NominalCurrency.Currency
  association [0..1] to I_Currency             as _QuotationCurrency on  $projection.QuotationCurrency = _QuotationCurrency.Currency
  association [0..1] to I_Currency             as _PaymentCurrency   on  $projection.PaymentCurrency = _PaymentCurrency.Currency
  association [0..1] to I_Currency             as _PositionCurrency  on  $projection.PositionCurrency = _PositionCurrency.Currency
  association [0..1] to I_Currency             as _LocalCurrency     on  $projection.LocalCurrency = _LocalCurrency.Currency
  association [0..1] to I_SecurityExchange     as _SecurityExchange  on  $projection.SecurityExchange = _SecurityExchange.SecurityExchange
  association [0..1] to I_SecurityClass        as _SecurityClass     on  $projection.SecurityClass = _SecurityClass.SecurityClass
  association [0..1] to I_SecurityAccount      as _SecurityAccount   on  $projection.SecurityAccount = _SecurityAccount.SecurityAccount
                                                                     and $projection.CompanyCode     = _SecurityAccount.CompanyCode

{
      //exposed fields

      @ObjectModel.foreignKey.association: '_CompanyCode'
  key Flow.CompanyCode                                                       as CompanyCode,
      @ObjectModel.foreignKey.association: '_FinTrans'
  key Flow.FinancialTransaction                                              as FinancialTransaction,

      @Semantics.amount.currencyCode: 'FinTransFlowNomAmtCrcy'
      Flow.FinTransTradedNomAmt                                              as FinTransTradedNomAmt,
      @ObjectModel.foreignKey.association: '_NominalCurrency'
      @EndUserText.label: 'Nominal Currency'
      @EndUserText.quickInfo: 'Nominal Currency'
      Flow.FinTransFlowNomAmtCrcy                                            as FinTransFlowNomAmtCrcy,
      @Semantics.amount.currencyCode: 'FinTransFlowNomAmtCrcy'
      Flow.FinTransTradedOriglNomAmt                                         as FinTransTradedOriglNomAmt,
      Flow.FinTransTradedNumberOfUnits                                       as FinTransTradedNumberOfUnits,
      Flow.FinTransTradedPricePercent                                        as FinTransTradedPricePercent,
      Flow.FinTransTrdPriceCrcyUnitRate                                      as FinTransTrdPriceCrcyUnitRate,
      Flow.FinTransTradedPriceCrcyUnit                                       as FinTransTradedPriceCrcyUnit,
      @Semantics.amount.currencyCode: 'QuotationCurrency'
      Flow.MarketValueInQtanCurrency                                         as MarketValueInQtanCurrency,
      @ObjectModel.foreignKey.association: '_QuotationCurrency'
      Flow.QuotationCurrency                                                 as QuotationCurrency,
      @Semantics.amount.currencyCode: 'PaymentCurrency'
      Flow.MarketValInPaytCurrency                                           as MarketValInPaytCurrency,
      @ObjectModel.foreignKey.association: '_PaymentCurrency'
      Flow.PaymentCurrency                                                   as PaymentCurrency,
      Flow.FinTransPaymentCrcyCnvrsnRate                                     as FinTransPaymentCrcyCnvrsnRate,
      @Semantics.amount.currencyCode: 'PositionCurrency'
      Flow.MarketValueInPositionCurrency                                     as MarketValueInPositionCurrency,
      @ObjectModel.foreignKey.association: '_PositionCurrency'
      Flow.PositionCurrency                                                  as PositionCurrency,
      Flow.FinTransPositionCrcyCnvrsnRate                                    as FinTransPositionCrcyCnvrsnRate,
      @Semantics.amount.currencyCode: 'LocalCurrency'
      Flow.MarketValueInLocalCurrency                                        as MarketValueInLocalCurrency,
      @ObjectModel.foreignKey.association: '_LocalCurrency'
      Flow.LocalCurrency                                                     as LocalCurrency,
      Flow.FinTransLoclCrcyCnvrsnRate                                        as FinTransLoclCrcyCnvrsnRate,
      @EndUserText.label: 'Spot Price in Percent'
      @EndUserText.quickInfo: 'Spot Price in Percent'
      Flow.FinTransSpotPricePercent                                          as FinTransSpotPricePercent,
      @EndUserText.label: 'Spot Price in Currency Unit'
      @EndUserText.quickInfo: 'Spot Price in Currency Unit'
      Flow.FinTransSpotPriceCrcyUnitRate                                     as FinTransSpotPriceCrcyUnitRate,
      @EndUserText.label: 'Maturity Spot Price in Percent'
      @EndUserText.quickInfo: 'Maturity Spot Price in Percent'
      Flow.FinTransMaturitySpotPricePct                                      as FinTransMaturitySpotPricePct,
      @EndUserText.label: 'Maturity Spot Price in Currency Unit'
      @EndUserText.quickInfo: 'Maturity Spot Price in Currency Unit'
      Flow.FinTransMatSpotPrcCrcyUnitRate                                    as FinTransMatSpotPrcCrcyUnitRate,
      Flow.FinTransForwardPriceCostRate                                      as FinTransForwardPriceCostRate,
      Flow.FinTransFwdPrcIntrstCompRate                                      as FinTransFwdPrcIntrstCompRate,
      Flow.FinTransFwdPrcDividendPercent                                     as FinTransFwdPrcDividendPercent,
      @ObjectModel.foreignKey.association: '_SecurityExchange'
      Flow.SecurityExchange                                                  as SecurityExchange,
      @ObjectModel.foreignKey.association: '_SecurityClass'
      cast(Flow.SecurityClass as ftr_gen_security_class preserving type)     as SecurityClass,
      @ObjectModel.foreignKey.association: '_SecurityAccount'
      cast(Flow.SecurityAccount as ftr_gen_security_account preserving type) as SecurityAccount,
      Flow.FinTransPositionValueDate,
      Flow.FinTransFlowPaymentDate,
      Flow.CalculationDate,

      //exposed dimensions, containing for example text fields

      _CompanyCode,
      _FinTrans,
      _NominalCurrency,
      _QuotationCurrency,
      _PaymentCurrency,
      _PositionCurrency,
      _LocalCurrency,
      _SecurityExchange,
      _SecurityClass,
      _SecurityAccount
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"R_FINTRANSSECURITYQUANTITYFLOW",
"VTBFHA"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_CURRENCY",
"I_FINANCIALTRANSACTION",
"I_SECURITYACCOUNT",
"I_SECURITYCLASS",
"I_SECURITYEXCHANGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/