I_FinInstrActivityCategory

@AbapCatalog.buffering.status: #NOT_ALLOWED
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AbapCatalog.sqlViewName: 'IFININSTRACTCAT'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Analytics.dataCategory: #DIMENSION
@Analytics.dataExtraction.enabled: true
@ObjectModel.supportedCapabilities: [ #ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #EXTRACTION_DATA_SOURCE ]
@ObjectModel.modelingPattern: [ #ANALYTICAL_DIMENSION ]
@Analytics.internalName: #LOCAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Financial Instrument Activity Category'
@ObjectModel.representativeKey: 'FinancialInstrActivityCategory'
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #S
@Metadata.allowExtensions:true
@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #BASIC 
@Search.searchable: true
@Consumption.ranked: true

define view I_FinInstrActivityCategory
  as select from at02
  association [0..1] to I_FinancialInstrProdCat        as _ProductCategory      on  $projection.FinancialInstrProductCategory = _ProductCategory.FinancialInstrProductCategory
  association [0..1] to I_FinInstrTransCat             as _TransactionCategory  on  $projection.FinancialInstrProductCategory = _TransactionCategory.FinancialInstrProductCategory
                                                                                and $projection.FinInstrTransactionCategory   = _TransactionCategory.FinInstrTransactionCategory
  association [0..*] to I_FinInstrActivityCategoryText as _ActivityCategoryText on  $projection.FinancialInstrProductCategory  = _ActivityCategoryText.FinancialInstrProductCategory
                                                                                and $projection.FinInstrTransactionCategory    = _ActivityCategoryText.FinInstrTransactionCategory
                                                                                and $projection.FinancialInstrActivityCategory = _ActivityCategoryText.FinancialInstrActivityCategory

{
      @ObjectModel.foreignKey.association: '_ProductCategory'  
      @Search.defaultSearchElement: true
      @Search.ranking: #LOW
      @UI.lineItem:[{ position : 2 }]  
  key sanlfor                                   as FinancialInstrProductCategory,
      @ObjectModel.foreignKey.association: '_TransactionCategory' 
      @Search.defaultSearchElement: true
      @Search.ranking: #LOW
      @UI.lineItem:[{ position : 3 }]  
  key sfgtyp                                    as FinInstrTransactionCategory,
      @ObjectModel.text.association: '_ActivityCategoryText' 
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
      @Search.fuzzinessThreshold: 0.8
      @UI.lineItem:[{ position : 1 }]  
  key sfgzustt                                  as FinancialInstrActivityCategory,

      @Search.defaultSearchElement: true
      @Search.ranking: #LOW
      @UI.lineItem:[{ position : 4 }]  
      cast(svgtyp as ftr_gen_activity_category) as FinTransGenActivityCategory,

      @Consumption.filter.hidden: true  
      _ProductCategory,
      @Consumption.filter.hidden: true
      _TransactionCategory,
      @Consumption.filter.hidden: true
      _ActivityCategoryText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"AT02"
],
"ASSOCIATED":
[
"I_FINANCIALINSTRPRODCAT",
"I_FININSTRACTIVITYCATEGORYTEXT",
"I_FININSTRTRANSCAT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/