I_FavoriteEHSLocationExpanded

@AbapCatalog:{
    sqlViewName: 'IFAVLOCEXPANDED',
    compiler.compareFilter: true
}
@EndUserText.label: 'Favorite EHS Location and Sublocations'
@Analytics: { dataCategory:#DIMENSION , dataExtraction.enabled:true }
@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #NOT_REQUIRED
// Client handling by session

@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.allowExtensions:true
@ObjectModel:{
    representativeKey: 'EHSLocationUUID',
// used for BOBF Master Data Object

    usageType:{ serviceQuality: #C,        // < 15 msec

                         sizeCategory:  #L,         // < 10.000.000

                         dataClass: #MASTER }
}
                         
// This returns the current users "Favorite Location" and its sublocations

define view I_FavoriteEHSLocationExpanded
  as select from I_FavoriteEHSLocation as EHSFavLocation

  // get the current revision of the location hierarchy

    inner join   I_EHSLocationHierarchyRevision on I_EHSLocationHierarchyRevision.RevisionStartDate <= $session.system_date and
                                                   I_EHSLocationHierarchyRevision.RevisionEndDate   >= $session.system_date

  // get all sub location of favorite location and favorite location in addition

    inner join   I_EHSLocHierarchyPath          on I_EHSLocHierarchyPath.EHSLocHierarchyRevisionUUID = I_EHSLocationHierarchyRevision.EHSLocHierarchyRevisionUUID and
                                                   (
                                                     I_EHSLocHierarchyPath.EHSParentLocationUUID     = EHSFavLocation.EHSLocationUUID                             or
                                                     I_EHSLocHierarchyPath.EHSLocationUUID           = EHSFavLocation.EHSLocationUUID                             and
                                                     I_EHSLocHierarchyPath.EHSParentLocationUUID     = hextobin( '00000000000000000000000000000000' )
                                                   )
                                                   
  association [1..1] to I_EHSLocationRevision as _EHSLocationRevision on  $projection.EHSLocationUUID = _EHSLocationRevision.EHSLocationUUID and
                                                                          _EHSLocationRevision.RevisionStartDate <= $session.system_date and
                                                                          _EHSLocationRevision.RevisionEndDate   >= $session.system_date

                                                     
                                                   
{
   key cast (I_EHSLocHierarchyPath.EHSLocationUUID as ehfnd_location_uuid_ref ) as EHSLocationUUID,
   
//     add an additional field to be able to filter on one given favorite location later on    

       cast (EHSFavLocation.EHSLocationUUID as ehfnd_location_uuid_ref )        as FavoriteEHSLocationUUID,
       _EHSLocationRevision
}
where EHSFavLocation.EHSLocationUUID <> hextobin( '00000000000000000000000000000000' )                                    
  
  
  
  
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_EHSLOCATIONHIERARCHYREVISION",
"I_EHSLOCHIERARCHYPATH",
"I_FAVORITEEHSLOCATION"
],
"ASSOCIATED":
[
"I_EHSLOCATIONREVISION"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/