I_EquipMaterialSerialNumberVH

@AbapCatalog.sqlViewName: 'IEQMATSERNRVH'
@AbapCatalog.compiler.compareFilter: true

@VDM.viewType: #COMPOSITE

@ObjectModel.dataCategory: #VALUE_HELP
@Consumption.ranked: true    // Optimize Type ahead for value helps - 2302

@Search: {
  searchable: true
}                           // Optimize Type ahead for value helps - 2302

@ObjectModel.representativeKey: 'Equipment'
@AbapCatalog.preserveKey: true

@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L

@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations: ['_EquipmentText']
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')

@ClientHandling.algorithm: #SESSION_VARIABLE

@Metadata.ignorePropagatedAnnotations: true

@EndUserText.label: 'Equipment'
define view I_EquipMaterialSerialNumberVH
  as select from I_Equipment
  association [0..*] to I_BusinessPartnerCustomer          as _SoldToParty        on  $projection.Customer = _SoldToParty.Customer                                            

{
    @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}  // Optimize Type ahead for value helps - 2302

    @Consumption.valueHelpDefault.binding.usage:#FILTER // Optimize Type ahead for value helps - 2302

  key Equipment,
      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8}  // Optimize Type ahead for value helps - 2302

      @EndUserText.label: 'Description'
      @EndUserText.quickInfo: 'Description' 
      _EquipmentText[ 1: Language = $session.system_language ].EquipmentName,
      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8}  // Optimize Type ahead for value helps - 2302

      @EndUserText.label: 'Business Partner ID'
      @EndUserText.quickInfo: 'Business Partner ID'
      _SoldToParty.BusinessPartner,
      @EndUserText.label: 'Business Partner Name'
      @EndUserText.quickInfo: 'Business Partner Name'   
      @Consumption.filter.hidden: true
      //@Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8} Disabled for this field as it causes a shop dump for type ahead

      _SoldToParty._CustomerToBusinessPartner._BusinessPartner.BusinessPartnerName,
      
    
      @Consumption.valueHelpDefinition: [{entity: { name:    'I_MaterialVH',
                                                    element: 'Material'  }}] 
      @ObjectModel.text.element: ['']
    //  @Consumption.valueHelpDefault.binding.usage:#FILTER     

      @EndUserText.label: 'Material ID'
      @EndUserText.quickInfo: 'Material ID' 
      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8}  // Optimize Type ahead for value helps - 2302

      Material,
      
      @EndUserText.label: 'Material Description'
      @EndUserText.quickInfo: 'Material Description' 
      @Consumption.filter.hidden: true
      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8}  // Optimize Type ahead for value helps - 2302

      _Material._Text[ 1: Language = $session.system_language ].MaterialName,
      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8}  // Optimize Type ahead for value helps - 2302

     // @Consumption.valueHelpDefault.binding.usage:#FILTER    

      cast ( SerialNumber  as crm_gernr ) as SerialNumber,             
        
      @Consumption.hidden: true
      AuthorizationGroup,

      @UI.hidden: true            
      Customer,

      @UI.hidden: true       
      Supplier, 
      
      @Consumption.hidden: true
      HasEquipmentData,
      
      @Consumption.hidden: true
      _Customer,
      @Consumption.hidden: true
      _Supplier,      

      @Consumption.filter.hidden: true
      @UI.hidden: true
      _EquipmentText,
                  
     _Material,       
                      
     _SoldToParty              
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSPARTNER",
"I_BUSINESSPARTNERCUSTOMER",
"I_CUSTOMER_TO_BUSINESSPARTNER",
"I_EQUIPMENT",
"I_EQUIPMENTTEXT",
"I_MATERIAL",
"I_MATERIALTEXT"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNERCUSTOMER",
"I_CUSTOMER",
"I_EQUIPMENTTEXT",
"I_MATERIAL",
"I_SUPPLIER"
],
"BASE":
[
"I_EQUIPMENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/