I_EnterpriseProjectTP

@AbapCatalog: {

    sqlViewName: 'IENTERPRISEPROTP',
    compiler.compareFilter: true
}

@ClientHandling.algorithm: #SESSION_VARIABLE

@Metadata.ignorePropagatedAnnotations: true

@AccessControl: {
    authorizationCheck:     #CHECK,
    personalData.blocking:  #BLOCKED_DATA_EXCLUDED
}

@ObjectModel: {
    sapObjectNodeType:{
      name: 'EnterpriseProject'},
    usageType: {
      dataClass:       #MIXED,
      serviceQuality:  #C,
      sizeCategory:    #L
    }
}

@VDM: {
    viewType: #TRANSACTIONAL,
    lifecycle.contract.type: #SAP_INTERNAL_API
}

@EndUserText.label: 'Appl. Interface for Enterprise Project'
@AbapCatalog.preserveKey: true
define root view I_EnterpriseProjectTP
  as select from I_PPM_Project as _Project
  composition [0..1] of I_EnterpriseProjectJVATP     as _EnterpriseProjectJVA
  composition [0..1] of I_EntProjectPublicSectorTP   as _EntProjectPublicSector
  composition [0..*] of I_EnterpriseProjectElementTP as _EnterpriseProjectElement
  composition [0..1] of R_EntProjectBlockFunctionTP  as _EntProjBlkFunc

  // Association for extensibility

  association [1..1] to E_PPM_Project                as _ProjectHeaderExtension on $projection.ProjectUUID = _ProjectHeaderExtension.ProjectUUID


{
  key ProjectUUID                 as ProjectUUID,
      ProjectSummaryTaskUUID      as ProjectSummaryTaskUUID,
      ProjectInternalID           as ProjectInternalID,
      Project                     as Project,
      cast(_ProjectName.ObjectNameMasterLanguage as text40 )  as ProjectDescription,
      EnterpriseProjectType       as EnterpriseProjectType,
      PriorityCode                as PriorityCode,
      ProjectStartDate            as ProjectStartDate,
      ProjectEndDate              as ProjectEndDate,
      EntProjIsMultiSlsOrdItmsEnbld as EntProjIsMultiSlsOrdItmsEnbld,
      //      @ObjectModel.readOnly: true  -> now set in BDEF

      ProcessingStatus            as ProcessingStatus,
      ResponsibleCostCenter       as ResponsibleCostCenter,
      ProfitCenter                as ProfitCenter,
      ProjectManagerUUID,
      ProjectProfileCode          as ProjectProfileCode,
      FunctionalArea              as FunctionalArea,
      CompanyCode                 as CompanyCode,
      ControllingArea             as ControllingArea,
      Plant                       as Plant,
      Location                    as Location,
      TaxJurisdiction             as TaxJurisdiction,
      ProjectCurrency             as ProjectCurrency,
      AvailabilityControlProfile  as AvailabilityControlProfile,
      AvailabilityControlIsActive as AvailabilityControlIsActive,

      LastChangeDateTime          as LastChangeDateTime,

      _Project.InvestmentProfile  as InvestmentProfile,

      //2005 functioanl location enhancement

      FunctionalLocation          as FunctionalLocation,

      //CE2005 Flexible Billing Element

      IsBillingRelevant           as IsBillingRelevant,



      _EnterpriseProjectJVA,
      //    @feature: 'BF:PSM_BUDGET_ACCOUNTING_CONTROL, EPPM_PUBLIC_SECTOR'

      _EntProjectPublicSector,
      _EnterpriseProjectElement,
      _ControllingArea,
      _CompanyCode,
      _ResponsibleCostCenter,
      _ProjectProfileCode,
      _FunctionalArea,
      _ProfitCenter,
      _EnterpriseProjectType,
      _EntProjBlkFunc,

      _AuthUser,
      _AuthSubst,
      _AuthRole,
      _AuthGroup,

      _I_Project

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PPM_PROJECT",
"I_PPM_TASKTEXT"
],
"ASSOCIATED":
[
"E_PPM_PROJECT",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_COSTCENTER",
"I_ENTERPRISEPROJECTELEMENTTP",
"I_ENTERPRISEPROJECTJVATP",
"I_ENTPROJECTPUBLICSECTORTP",
"I_FUNCTIONALAREA",
"I_PPM_AUTHZNBYSUBSTITH",
"I_PPM_AUTHZNBYUSERROLEH",
"I_PPM_AUTHZNBYUSRGRPH",
"I_PPM_AUTHZNBYUSRH",
"I_PROFITCENTER",
"I_PROJECTBASICDATA",
"I_PROJECTPROFILECODE",
"I_PROJECTTYPE",
"R_ENTPROJECTBLOCKFUNCTIONTP"
],
"BASE":
[
"I_PPM_PROJECT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/