I_EngmntProjSrchModel

@AbapCatalog.sqlViewName: 'IENGPRJSRCH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Engagement Project Search Model'
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #BASIC
@ObjectModel.representativeKey: 'EngagementProject'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.dataClass: #MIXED
@AccessControl.personalData.blocking: #REQUIRED
define view I_EngmntProjSrchModel
  as select from P_EngagementProject as EngagementProject
  association [0..*] to I_EngagementProjFinancialPlan as _EngagementProjectFinPlan    on $projection.EngagementProjectUUID = _EngagementProjectFinPlan.EngagementProjectUUID
  association [0..1] to I_EngagementProjectStage      as _EngagementProjectStage      on $projection.EngagementProjectStage = _EngagementProjectStage.EngagementProjectStage
  association [0..1] to I_EngagementProjectSrvcOrg    as _EngagementProjectServiceOrg on $projection.EngagementProjectServiceOrg = _EngagementProjectServiceOrg.EngagementProjectServiceOrg
  association [0..1] to I_Customer                    as _Customer                    on $projection.Customer = _Customer.Customer
  association [0..1] to I_PersonWorkAgreement_1       as _PersonWorkAgreement_1       on $projection.ProjectManagerWorkAgreement = _PersonWorkAgreement_1.PersonWorkAgreement
  association [0..1] to I_PersonWorkAgreement_2       as _PersonWorkAgreement_2       on $projection.ProjectManagerWorkAgreement = _PersonWorkAgreement_2.PersonWorkAgreement
  association [1..1] to E_CustomerProject             as _CustomerProjectExt          on $projection.EngagementProject = _CustomerProjectExt.CustomerProject
{
       @ObjectModel.text.element: 'EngagementProjectName'
  key  cast(EngagementProject.mp_id  as /cpd/eng_mp_id preserving type )           as EngagementProject,
       EngagementProject.db_key                                                    as EngagementProjectUUID,
       @Semantics.text: true
       EngagementProject.text                                                      as EngagementProjectName,
       cast(EngagementProject.mp_type as /cpd/eng_mp_type  preserving type )       as EngagementProjectType,
       @ObjectModel.foreignKey.association: '_EngagementProjectStage'
       EngagementProject.mp_stage                                                  as EngagementProjectStage,
       @ObjectModel.foreignKey.association: '_EngagementProjectServiceOrg'
       EngagementProject.org_id                                                    as EngagementProjectServiceOrg,
       cast(EngagementProject.project_type as /cpd/eng_proj_type preserving type ) as EngagementProjectCategory,
       EngagementProject.start_date                                                as ProjectStartDate,
       EngagementProject.end_date                                                  as ProjectEndDate,
       EngagementProject.confidential                                              as ProjectVisibility,

       @VDM.lifecycle.status: #DEPRECATED
       @VDM.lifecycle.successor: 'ProjectManagerWorkAgreement'
       EngagementProject.proj_manager_id                                           as ProjectManager,
       EngagementProject.proj_manager_id                                           as ProjectManagerWorkAgreement,
       @ObjectModel.foreignKey.association: '_Customer'
       EngagementProject.customer                                                  as Customer,
       EngagementProject.CompanyCode                                               as CompanyCode,
       cast( EngagementProject.cost_center as /cpd/pws_ws_org_unit_key preserving type ) as CostCenter,
       EngagementProject.profit_center                                             as ProfitCenter,
       EngagementProject.ProjectProfileCode                                        as ProjectProfileCode,

       /* Associations */
       _EngagementProjectFinPlan,
       _EngagementProjectStage,
       _EngagementProjectServiceOrg,
       _Customer,
       _PersonWorkAgreement_1,
       _PersonWorkAgreement_2
}
where
  EngagementProject.confidential = 'N'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_ENGAGEMENTPROJECT"
],
"ASSOCIATED":
[
"E_CUSTOMERPROJECT",
"I_CUSTOMER",
"I_ENGAGEMENTPROJECTSRVCORG",
"I_ENGAGEMENTPROJECTSTAGE",
"I_ENGAGEMENTPROJFINANCIALPLAN",
"I_PERSONWORKAGREEMENT_1",
"I_PERSONWORKAGREEMENT_2"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/