I_EngSnpshtHdrTP

@AbapCatalog.sqlViewName: 'IENGSNPHDRTP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Engineering Snapshot Header for transactional'

@VDM.viewType: #TRANSACTIONAL
@ObjectModel: {
-- Annotations for transactional processing
  modelCategory: #BUSINESS_OBJECT,
  compositionRoot: true,
  transactionalProcessingEnabled: true,
  createEnabled: true,
  updateEnabled: true,
  deleteEnabled: true,
  writeActivePersistence: 'MPE_SNP_HDR_V'
  //semanticKey: ,

}

@ObjectModel.usageType: {serviceQuality: #C,
                         dataClass: #MIXED,
                         sizeCategory: #L}

define view I_EngSnpshtHdrTP
  as select from mpe_snp_hdr as Header
  association [1..*] to I_EngSnpshtObjRefTP as _EngSnpshtObjRef on $projection.EngSnapshotUUID = _EngSnpshtObjRef.EngSnapshotUUID
  association [0..1] to E_EngSnpshtHdr      as _HeaderExtension on $projection.EngSnapshotUUID = _HeaderExtension.EngSnapshotUUID
{
  key  Header.uuid                  as EngSnapshotUUID,
       Header.snapshot_id           as EngSnapshotID,
       Header.snapshot_name         as EngSnapshotName,
       Header.snapshot_type         as EngSnapshotType,
       Header.matnr                 as Material,
       Header.werks                 as Plant,
       Header.stlan                 as BillOfMaterialVariantUsage,
       Header.stlal                 as BillOfMaterialVariant,
       Header.dokar                 as DocumentInfoRecordDocType,
       Header.doknr                 as DocumentInfoRecordDocNumber,
       Header.doktl                 as DocumentInfoRecordDocPart,
       Header.plan_scope_documentid as PlanningScopeInternalID,
       Header.plan_scope_alt        as PlanningScopeAlternative,
       Header.revn_nmbr             as EngSnpshtRevisionNumber,
       Header.aux_prep_sts          as EngSnpshtAuxiliaryPrepSts,
       Header.chg_prep_sts          as EngSnpshtChangePrepSts,
       Header.prpsd_effective_date  as EngSnpshtProposedEffectiveDate,
       @Semantics.user.createdBy: true
       Header.created_by            as CreatedByUser,
       @Semantics.systemDateTime.createdAt: true
       Header.created_at            as CreationDateTime,
       @Semantics.user.lastChangedBy: true
       Header.changed_by            as LastChangedByUser,
       @Semantics.systemDateTime.lastChangedAt: true
       Header.changed_at            as LastChangeDateTime,

       @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
       _EngSnpshtObjRef
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"MPE_SNP_HDR"
],
"ASSOCIATED":
[
"E_ENGSNPSHTHDR",
"I_ENGSNPSHTOBJREFTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/