I_EWM_WhseDocumentStatusText

@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Warehouse Document Status - Text'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.dataCategory: #TEXT
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.representativeKey: 'EWMWarehouseDocumentStatus'
@ObjectModel.supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET, 
                                     #CDS_MODELING_DATA_SOURCE,
                                     #LANGUAGE_DEPENDENT_TEXT,
                                     #SQL_DATA_SOURCE]
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.dataClass: #META
@ObjectModel.usageType.sizeCategory: #S
@Search.searchable: true
@VDM.viewType: #BASIC
define view entity I_EWM_WhseDocumentStatusText as select from dd07t 
  association to parent I_EWM_WhseDocumentStatusVH as _EWMWarehouseDocumentStatus
    on $projection.EWMWarehouseDocumentStatus = _EWMWarehouseDocumentStatus.EWMWarehouseDocumentStatus
  association [0..1] to I_Language as _Language      
    on $projection.Language = _Language.Language
{
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key cast( dd07t.ddlanguage as spras preserving type ) as Language, 
      @ObjectModel.foreignKey.association: '_EWMWarehouseDocumentStatus'
      @ObjectModel.text.element: ['EWMWarehouseDocumentStatusName']
  key cast( dd07t.domvalue_l as ewm_de_whsedocstatus ) as EWMWarehouseDocumentStatus,
      @Analytics.hidden: true
      @Consumption.hidden: true
      dd07t.domvalue_l as DomainValue,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @Semantics.text: true
      cast( dd07t.ddtext as ddtext ) as EWMWarehouseDocumentStatusName,
      _EWMWarehouseDocumentStatus,
      _Language
} 
where dd07t.domname  = 'EWM_DO_WHSEDOCSTATUS'
  and dd07t.as4local = 'A'
  and dd07t.as4vers  = '0000'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_EWM_WHSEDOCUMENTSTATUSVH",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/