I_EWM_LocationTypeText

@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Location Type - Text'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.dataCategory: #TEXT
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.representativeKey: 'EWMLocationType'
@ObjectModel.supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET,
                                     #CDS_MODELING_DATA_SOURCE,
                                     #LANGUAGE_DEPENDENT_TEXT,
                                     #SQL_DATA_SOURCE]
@ObjectModel.usageType:{
  serviceQuality: #A,
  sizeCategory: #S,
  dataClass: #META
}
@Search.searchable: true
@VDM.viewType: #BASIC
define view entity I_EWM_LocationTypeText
  as select from dd07t
  association        to parent I_EWM_LocationType as _EWMLocationType on $projection.EWMLocationType = _EWMLocationType.EWMLocationType
  association [0..1] to I_Language                    as _Language            on $projection.Language = _Language.Language
{
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key cast( dd07t.ddlanguage as spras preserving type )              as Language,
      @ObjectModel.foreignKey.association: '_EWMLocationType'
      @ObjectModel.text.element: ['EWMLocationTypeName']
  key cast( dd07t.domvalue_l as /scwm/de_loc_type )                  as EWMLocationType,
      @Consumption.hidden: true
      @Analytics.hidden: true
      dd07t.domvalue_l                                               as DomainValue,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @Semantics.text: true
      cast( dd07t.ddtext as ewm_de_locationtypename preserving type ) as EWMLocationTypeName,
      _EWMLocationType,
      _Language
}
where
      dd07t.domname  = '/SCWM/DO_LOC_TYPE'
  and dd07t.as4local = 'A'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_EWM_LOCATIONTYPE",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/