I_EWM_InbDeliveryItemBasic

@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Inbound Delivery Item Basic'
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.sizeCategory: #XL

@AccessControl.personalData.blocking :#REQUIRED

@VDM.viewType:#COMPOSITE
define view entity I_EWM_InbDeliveryItemBasic
  as select from I_EWM_WarehouseRequestInbItem as IbdDeliveryItemBasic

  association [0..*] to I_EWM_DeliveryStatus      as _ItemStatus           on  $projection.InboundDeliveryUUID         = _ItemStatus.DeliveryUUID
                                                                           and $projection.InboundDeliveryItemUUID     = _ItemStatus.DeliveryItemUUID
                                                                           and _ItemStatus.EWMDeliveryDocumentCategory = 'PDI'

  association [0..*] to I_EWM_DeliveryQuantity_2  as _Quantity             on  $projection.InboundDeliveryUUID       = _Quantity.DeliveryUUID
                                                                           and $projection.InboundDeliveryItemUUID   = _Quantity.DeliveryItemUUID
                                                                           and _Quantity.EWMDeliveryDocumentCategory = 'PDI'

  association [0..*] to I_EWM_DeliveryDateAndTime as _DeliveryItemDateTime on  $projection.InboundDeliveryUUID                = _DeliveryItemDateTime.DeliveryOrderUUID
                                                                           and $projection.InboundDeliveryItemUUID            = _DeliveryItemDateTime.DeliveryOrderItemUUID
                                                                           and _DeliveryItemDateTime.DeliveryDocumentCategory = 'PDI'

  association [0..*] to I_EWM_WhseReqItmExtProdBatch  as _ExtProdBatch  on $projection.InboundDeliveryUUID       = _ExtProdBatch.EWMWarehouseRequestUUID
                                                                           and $projection.InboundDeliveryItemUUID   = _ExtProdBatch.EWMWarehouseRequestItemUUID
                                                                           and $projection.DeliveryDocumentCategory = 'PDI'
{
  key EWMWarehouseRequestUUID                                        as InboundDeliveryUUID,
  key EWMWarehouseRequestItemUUID                                    as InboundDeliveryItemUUID,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor:  'EWMWarehouse'
      EWMWarehouse                                                   as Warehouse,
      EWMWarehouse                                                   as EWMWarehouse,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor:  'EWMInboundDelivery'
      EWMWarehouseRequest                                            as InboundDelivery,
      EWMWarehouseRequest                                            as EWMInboundDelivery,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor:  'EWMInboundDeliveryItem'
      EWMWarehouseRequestItem                                        as InboundDeliveryItem,
      EWMWarehouseRequestItem                                        as EWMInboundDeliveryItem,
      EWMWhseRequestDocumentCategory                                 as DeliveryDocumentCategory,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor:  'EWMInboundDeliveryItemCategory'
      EWMWhseRequestItemCategory                                     as DeliveryItemCategory,
      EWMWhseRequestItemCategory                                     as EWMInboundDeliveryItemCategory,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor:  'EWMInboundDeliveryItemType'
      EWMWarehouseRequestItemType                                    as InboundDeliveryItemType,
      EWMWarehouseRequestItemType                                    as EWMInboundDeliveryItemType,
      WarehouseProcessType,
      WarehouseDoor,
      StagingAreaGroup,
      StagingArea,
      StagingBay,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor:  'EWMProductionSupplyArea'
      EWMProductionSupplyArea                                        as ProductionSupplyArea,
      EWMProductionSupplyArea,
      GoodsMovementBin,
      Product,
      ProductExternalID,
      cast(ProductBatch as charg_d)                                  as Batch,
      RequirementSegment,
      StockSegment,
      CountryOfOrigin,
      EntitledToDisposeParty,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor:  'EWMStockOwner'
      EWMStockOwner                                                  as StockOwner,
      EWMStockOwner,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor:  'EWMStockType'
      EWMStockType                                                   as StockType,
      EWMStockType,
      StockUsage,
      StockDocumentCategory,
      StockDocumentNumber,
      StockItemNumber,

      /* Special Stock - Sales Order */
      case StockDocumentCategory
        when 'SOS' then cast(substring(StockDocumentNumber,26,10) as vbeln preserving type)
        else cast( '          ' as vbeln preserving type ) end       as SpecialStockIdfgSalesOrder, // SOS -> Valuated Sales Order


      /* Special Stock - Sales Order Item */
      case StockDocumentCategory
        when 'SOS'  then cast(substring(StockItemNumber, 5,6) as abap.numc( 6 ))
        else cast( '000000' as numc06 preserving type ) end          as SpecialStockIdfgSalesOrderItem,

      EWMWhseReqItmStockTypeDetnCode                                 as DeliveryItemStockTypeDetnCode,
      ProductQuantity,
      CompletionStatus,
      GoodsReceiptStatus,
      FldLogsStatus, // Introduced with 2202 CE for Field Logistic colleagues


      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor:  'EWMDelivLastChangeUTCDateTime'
      EWMWhseReqLastChangeUTCDteTme                                  as LastChangeTime,
      EWMWhseReqLastChangeUTCDteTme                                  as EWMDelivLastChangeUTCDateTime,

      QuantityUnit,
      EWMWhseReqCreationUTCDateTime                                  as InbDelivItemCrtnUTCDateTime,
      PlndGREndWhseTmznDateTime,
      UnloadingEndWhseTmznDateTime,
      PutawayEndWhseTmznDateTime,
      ActualGREndWhseTmznDateTime,
      EWMItmCmpltWhseTmznDteTme                                      as InbDelivItmCmpltWhseTmznDteTme,

      /* Reference Documents */
      PurchasingDocument,
      PurchasingDocumentItem,

      _ItemStatus,
      _Quantity,
      _DeliveryItemDateTime,
      _ExtProdBatch
}
where
  EWMWhseRequestDocumentCategory = 'PDI'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_EWM_WAREHOUSEREQUESTINBITEM"
],
"ASSOCIATED":
[
"I_EWM_DELIVERYDATEANDTIME",
"I_EWM_DELIVERYQUANTITY_2",
"I_EWM_DELIVERYSTATUS",
"I_EWM_WHSEREQITMEXTPRODBATCH"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/