@AbapCatalog.sqlViewName: 'IEWMHUHDRC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@EndUserText.label: 'Handling Unit Header - Cube'
@Analytics.internalName: #LOCAL
@Analytics.dataCategory: #CUBE
@VDM.viewType: #COMPOSITE
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@Metadata.allowExtensions: true
@VDM.lifecycle.status: #DEPRECATED
// P_EWM_HandlingUnitHeader05 --> Distinguished Active HU from Snap HU
// P_EWM_HandlingUnitHeaderLog04 --> Returns the latest Snapshot of an HU with all required info
// P_EWM_HandlingUnitHeader02 --> Returns an active HU with all required info
define view I_EWM_HandlingUnitHeaderC
as select from P_EWM_HandlingUnitHeader05 as _HandlingUnitUnion
association [0..1] to P_EWM_HandlingUnitHeaderLog04 as _SnapshotHandlingUnit on _HandlingUnitUnion.HandlingUnitExternalID = _SnapshotHandlingUnit.HandlingUnitExternalID
and _HandlingUnitUnion.Warehouse = _SnapshotHandlingUnit.Warehouse
{
key _SnapshotHandlingUnit.HandlingUnitExternalID,
key _SnapshotHandlingUnit.Warehouse,
_SnapshotHandlingUnit.PackagingMaterial,
_SnapshotHandlingUnit.PackagingMaterialType,
_SnapshotHandlingUnit.StorageType,
_SnapshotHandlingUnit.HandlingUnitStatus, //Not Used By A-View for 1911
_SnapshotHandlingUnit.StorageSection, // Not Used By A-View for 1911
_SnapshotHandlingUnit.StorageBin, // No Used By A-View for 1911
_SnapshotHandlingUnit.HandlingUnitType,
/* Weight */
@Semantics.quantity.unitOfMeasure: 'WeightUnit'
_SnapshotHandlingUnit.GrossWeight,
@Semantics.quantity.unitOfMeasure: 'WeightUnit'
_SnapshotHandlingUnit.NetWeight,
@Semantics.quantity.unitOfMeasure: 'WeightUnit'
_SnapshotHandlingUnit.HandlingUnitMaxWeight,
@Semantics.unitOfMeasure: true
_SnapshotHandlingUnit.WeightUnit,
@Semantics.quantity.unitOfMeasure: 'HandlingUnitTareWeightUnit'
_SnapshotHandlingUnit.HandlingUnitTareWeight,
@Semantics.unitOfMeasure: true
_SnapshotHandlingUnit.HandlingUnitTareWeightUnit,
/* Volume */
@Semantics.quantity.unitOfMeasure: 'VolumeUnit'
_SnapshotHandlingUnit.GrossVolume,
@Semantics.quantity.unitOfMeasure: 'VolumeUnit'
_SnapshotHandlingUnit.HandlingUnitNetVolume,
@Semantics.quantity.unitOfMeasure: 'VolumeUnit'
_SnapshotHandlingUnit.HandlingUnitMaxVolume,
@Semantics.unitOfMeasure: true
_SnapshotHandlingUnit.VolumeUnit,
@Semantics.quantity.unitOfMeasure: 'HandlingUnitTareVolumeUnit'
_SnapshotHandlingUnit.HandlingUnitTareVolume,
@Semantics.quantity.unitOfMeasure: 'HandlingUnitTareVolumeUnit'
_SnapshotHandlingUnit.HandlingUnitVolumeTolerance,
@Semantics.unitOfMeasure: true
_SnapshotHandlingUnit.HandlingUnitTareVolumeUnit,
/* Dimensions */
@Semantics.quantity.unitOfMeasure: 'UnitOfMeasureDimension'
_SnapshotHandlingUnit.HandlingUnitLength,
@Semantics.quantity.unitOfMeasure: 'UnitOfMeasureDimension'
_SnapshotHandlingUnit.HandlingUnitWidth,
@Semantics.quantity.unitOfMeasure: 'UnitOfMeasureDimension'
_SnapshotHandlingUnit.HandlingUnitHeight,
@Semantics.unitOfMeasure: true
_SnapshotHandlingUnit.UnitOfMeasureDimension,
/* Max Dimensions */
@Semantics.quantity.unitOfMeasure: 'HandlingUnitMaxDimensionUnit'
_SnapshotHandlingUnit.HandlingUnitMaxLength,
@Semantics.quantity.unitOfMeasure: 'HandlingUnitMaxDimensionUnit'
_SnapshotHandlingUnit.HandlingUnitMaxWidth,
@Semantics.quantity.unitOfMeasure: 'HandlingUnitMaxDimensionUnit'
_SnapshotHandlingUnit.HandlingUnitMaxHeight,
@Semantics.unitOfMeasure: true
_SnapshotHandlingUnit.HandlingUnitMaxDimensionUnit,
_SnapshotHandlingUnit.ReferenceDocumentNumber,
/* Admin DateTime and User */
_SnapshotHandlingUnit.CreatedByUser,
_SnapshotHandlingUnit.CreationUTCDateTime,
_SnapshotHandlingUnit.LastChangedByUser,
cast( _SnapshotHandlingUnit.LastChangeUTCDateTime as tzntstmps preserving type ) as LastChangeUTCDateTime,
_SnapshotHandlingUnit.ParentHandlingUnitNumber,
_SnapshotHandlingUnit.HandlingUnitUUID
}
where
ActiveEntries = 0 // Filter ony Snapshots
union all select from P_EWM_HandlingUnitHeader02
{
//Active HUs
key HandlingUnitExternalID,
key Warehouse,
PackagingMaterial,
PackagingMaterialType,
StorageType,
HandlingUnitStatus,
//Not Used By A-View for 1911
StorageSection, // Not Used By A-View for 1911
StorageBin, // No Used By A-View for 1911
HandlingUnitType,
/* Weight */
@Semantics.quantity.unitOfMeasure: 'WeightUnit'
GrossWeight,
@Semantics.quantity.unitOfMeasure: 'WeightUnit'
NetWeight,
@Semantics.quantity.unitOfMeasure: 'WeightUnit'
HandlingUnitMaxWeight,
@Semantics.unitOfMeasure: true
WeightUnit,
@Semantics.quantity.unitOfMeasure: 'HandlingUnitTareWeightUnit'
HandlingUnitTareWeight,
@Semantics.unitOfMeasure: true
HandlingUnitTareWeightUnit,
/* Volume */
@Semantics.quantity.unitOfMeasure: 'VolumeUnit'
GrossVolume,
@Semantics.quantity.unitOfMeasure: 'VolumeUnit'
HandlingUnitNetVolume,
@Semantics.quantity.unitOfMeasure: 'VolumeUnit'
HandlingUnitMaxVolume,
@Semantics.unitOfMeasure: true
VolumeUnit,
@Semantics.quantity.unitOfMeasure: 'HandlingUnitTareVolumeUnit'
HandlingUnitTareVolume,
@Semantics.quantity.unitOfMeasure: 'HandlingUnitTareVolumeUnit'
HandlingUnitVolumeTolerance,
@Semantics.unitOfMeasure: true
HandlingUnitTareVolumeUnit,
/* Dimensions */
@Semantics.quantity.unitOfMeasure: 'UnitOfMeasureDimension'
HandlingUnitLength,
@Semantics.quantity.unitOfMeasure: 'UnitOfMeasureDimension'
HandlingUnitWidth,
@Semantics.quantity.unitOfMeasure: 'UnitOfMeasureDimension'
HandlingUnitHeight,
@Semantics.unitOfMeasure: true
UnitOfMeasureDimension,
/* Max Dimensions */
@Semantics.quantity.unitOfMeasure: 'HandlingUnitMaxDimensionUnit'
HandlingUnitMaxLength,
@Semantics.quantity.unitOfMeasure: 'HandlingUnitMaxDimensionUnit'
HandlingUnitMaxWidth,
@Semantics.quantity.unitOfMeasure: 'HandlingUnitMaxDimensionUnit'
HandlingUnitMaxHeight,
@Semantics.unitOfMeasure: true
HandlingUnitMaxDimensionUnit,
ReferenceDocumentNumber,
/* Admin DateTime and User */
CreatedByUser,
CreationUTCDateTime,
LastChangedByUser,
cast( LastChangeUTCDateTime as tzntstmps preserving type ) as LastChangeUTCDateTime,
ParentHandlingUnitNumber,
HandlingUnitUUID
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_EWM_HANDLINGUNITHEADER02",
"P_EWM_HANDLINGUNITHEADER05",
"P_EWM_HANDLINGUNITHEADERLOG04"
],
"ASSOCIATED":
[
"P_EWM_HANDLINGUNITHEADERLOG04"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/