I_EWM_HandlingUnitHdr_2

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Handling Unit Header'
@VDM.viewType:#BASIC

@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.sizeCategory: #L
@Analytics.internalName:#LOCAL
@Metadata.ignorePropagatedAnnotations:true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]

define view entity I_EWM_HandlingUnitHdr_2
  as select from /scwm/huhdr as huhdr
{
  key cast(huident as ewm_de_hu_no_conv preserving type ) as HandlingUnitNumber,
  key lgnum                                               as EWMWarehouse,
  key vhi                                                 as HandlingUnitIndicator,
      guid_hu                                             as HandlingUnitUUID,
      cast(pmat_guid as matid_no_conv preserving type )   as PackagingMaterialUUID,
      created_by                                          as CreatedByUser,
      created_at                                          as CreationDateTime,
      //orig_system,

      changed_by                                          as LastChangedByUser,
      changed_at                                          as LastChangeDateTime,
      @Semantics.quantity.unitOfMeasure: 'WEIGHTUNIT'
      g_weight                                            as GrossWeight,
      @Semantics.quantity.unitOfMeasure: 'WEIGHTUNIT'
      n_weight                                            as NetWeight,
      unit_gw                                             as WeightUnit,
      @Semantics.quantity.unitOfMeasure: 'HANDLINGUNITTAREWEIGHTUNIT'
      t_weight                                            as HandlingUnitTareWeight,
      unit_tw                                             as HandlingUnitTareWeightUnit,
      @Semantics.quantity.unitOfMeasure: 'VOLUMEUNIT'
      g_volume                                            as GrossVolume,
      @Semantics.quantity.unitOfMeasure: 'VOLUMEUNIT'
      n_volume                                            as HandlingUnitNetVolume,
      unit_gv                                             as VolumeUnit,
      @Semantics.quantity.unitOfMeasure: 'HANDLINGUNITTAREVOLUMEUNIT'
      t_volume                                            as HandlingUnitTareVolume,
      unit_tv                                             as HandlingUnitTareVolumeUnit,
      @Semantics.quantity.unitOfMeasure: 'EWMDIMENSIONUNIT'
      g_capa                                              as HandlingUnitGrossCapacity,
      @Semantics.quantity.unitOfMeasure: 'EWMDIMENSIONUNIT'
      n_capa                                              as HandlingUnitNetCapacity,
      @Semantics.quantity.unitOfMeasure: 'EWMDIMENSIONUNIT'
      t_capa                                              as HandlingUnitTareCapacity,
      @Semantics.quantity.unitOfMeasure: 'EWMDIMENSIONUNIT'
      length                                              as HandlingUnitLength,
      @Semantics.quantity.unitOfMeasure: 'EWMDIMENSIONUNIT'
      width                                               as HandlingUnitWidth,
      @Semantics.quantity.unitOfMeasure: 'EWMDIMENSIONUNIT'
      height                                              as HandlingUnitHeight,
      unit_lwh                                            as EWMDimensionUnit,
      @Semantics.quantity.unitOfMeasure: 'WEIGHTUNIT'
      max_weight                                          as HandlingUnitMaxWeight,
      @Semantics.quantity.unitOfMeasure: 'WEIGHTUNIT'
      tolw                                                as HandlingUnitWeightTolerance,
      tare_var                                            as HasVariableTareWeight,
      @Semantics.quantity.unitOfMeasure: 'VOLUMEUNIT'
      max_volume                                          as HandlingUnitMaxVolume,
      @Semantics.quantity.unitOfMeasure: 'VOLUMEUNIT'
      tolv                                                as HandlingUnitVolumeTolerance,
      closed_package                                      as HandlingUnitIsClosed,
      max_capa                                            as MaximumCapacity,
      @Semantics.quantity.unitOfMeasure: 'EWMDIMENSIONUNIT'
      tolc                                                as HandlingUnitCapacityTolerance,
      @Semantics.quantity.unitOfMeasure: 'HANDLINGUNITMAXDIMENSIONUNIT'
      max_length                                          as HandlingUnitMaxLength,
      @Semantics.quantity.unitOfMeasure: 'HANDLINGUNITMAXDIMENSIONUNIT'
      max_width                                           as HandlingUnitMaxWidth,
      @Semantics.quantity.unitOfMeasure: 'HANDLINGUNITMAXDIMENSIONUNIT'
      max_height                                          as HandlingUnitMaxHeight,
      unit_max_lwh                                        as HandlingUnitMaxDimensionUnit,
      letyp                                               as HandlingUnitType,
      flgavq                                              as HandlingUnitHasAvailQty,
      flgmove                                             as HandlingUnitOpenTaskInd,
      procs                                               as ExternalStorageProcessStep,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'EWMHUProcessStepIsCompleted'
      copst                                               as ProcessStepCompletedInd,
      copst                                               as EWMHUProcessStepIsCompleted,
      prces                                               as StorageProcess,
      dstgrp                                              as EWMConsolidationGroup,
      wklid                                               as WorkloadIdentification,
      entitled                                            as EntitledToDisposeParty,
      wstyp                                               as EWMStorageType,
      wssec                                               as EWMStorageSection,
      wsbin                                               as EWMStorageBin,
      wcr                                                 as WarehouseOrderCreationRule,
      mfserror                                            as HandlingUnitDefectCode,
      ukcon                                               as HandlingUnitContentInd,
      pmtyp                                               as PackagingMaterialType,
      packgr                                              as HandlingUnitPackingGroup,
      //saprl,

      phystat                                             as HandlingUnitStatus,
      @Semantics.booleanIndicator: true
      top                                                 as HandlingUnitTopLevelInd,
      @Semantics.booleanIndicator: true
      bottom                                              as HandlingUnitBottomInd,
      stsma                                               as StatusProfile,
      cast( ps_guid as raw16 preserving type )            as PackagingSpecificationUUID,
      ps_level_seq                                        as PackagingSpecificationLevel,
      @Semantics.booleanIndicator: true
      objref                                              as HandlingUnitObjRefInd,
      hzmt                                                as HazardousSubstanceIndicator,
      logpos                                              as HandlingUnitLogicalPosition,
      logpos_ext                                          as DistrEquipmentLogicalPos,
      auto_crea_pick                                      as HandlingUnitAutoCreationLevel,
      hu_guid_ext                                         as EWMHandlingUnitExternalUUID, 
      //!!! ATTENTION !!! 

      //This field requires that silent data migration /SCWM/CL_SDM_HUHDR_GUID_HU_TOP that was introduced in CE 2208 / OP 2022 has finished after upgrade

      //This field will not return any data otherwise. Note that SDM runs after upgrade and business users can already work in the system.

      //If you want to use this field you must check that silent data migration has finished in your code (error message).

      //Special attention must be paid if you use this view within an existing application. 

      //You must ensure that your application is working with the old logic without this view until SDM has finished.

      guid_hu_top                                         as EWMHghstLvlHandlingUnitUUID,
      pickhuind                                           as EWMHndlgUnitPickingCriteria,
      cast( pi_guid as raw16 preserving type )            as EWMPackingInstructionUUID,
      pb_engine                                           as UnifiedPackageBuildingEngine
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"/SCWM/HUHDR"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/