I_EHSTskInstcePersnContactCard

@AbapCatalog.sqlViewName: 'IEHSTICC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@EndUserText.label: 'EHS Task Instance Person Contact Card'

@VDM.viewType: #COMPOSITE
@ObjectModel.updateEnabled: false
@ObjectModel.createEnabled: false

@ObjectModel.semanticKey: ['ContactCardID'] // this will make the title column bold in smart templates


@UI: {
  headerInfo: {
    typeName: 'Responsible Contact Card',
    typeNamePlural: 'Responsible Contact Cards',
    title: {
      value: 'FullName'
    }
  }
}

// Client handling by session

@ClientHandling.algorithm: #SESSION_VARIABLE

// used for BOBF Master Data Object

@ObjectModel.usageType:{ serviceQuality: #D,        // < 100 msec

                         sizeCategory:  #L,         // < 10.000.000

                         dataClass: #MIXED }

define view I_EHSTskInstcePersnContactCard
  as select from I_UserContactCard  as ContactCard
    inner join I_BusinessUserBasic  as BusinessUserBasic on  ContactCard.ContactCardID       = BusinessUserBasic.UserID
                                                         and ContactCard.BusinessPartnerUUID = BusinessUserBasic.BusinessPartnerUUID
{
  key ContactCard.ContactCardID,
      ContactCard.Person,
      ContactCard.BusinessPartnerUUID,
      @Semantics.name.givenName: true
      coalesce( BusinessUserBasic.FirstName, ContactCard.FirstName )     as FirstName,
      @Semantics.name.familyName: true
      coalesce( BusinessUserBasic.LastName, ContactCard.LastName )       as LastName,
      @Semantics.name.fullName: true
      coalesce( BusinessUserBasic.PersonFullName, ContactCard.FullName ) as FullName,
      ContactCard.AddressID,
      ContactCard.PhoneNumber,
      ContactCard.MobilePhoneNumber,
      ContactCard.FaxNumber,
      ContactCard.EmailAddress,
      ContactCard.Department,
      ContactCard.FunctionalTitleName,
      ContactCard.ContactCardRole,
      ContactCard.ContactCardType,
      ContactCard.ContactCardNavLinkSemanticObj,
      ContactCard.ContactCardNavLinkQueryPart,
      BusinessUserBasic.BusinessPartner
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSUSERBASIC",
"I_USERCONTACTCARD"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/