I_EHSTaskDefWithDraftUnion

@AbapCatalog.sqlViewName: 'IEHSTSKDEFWDRFTU'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'EHSTask Definition Union'

@ObjectModel.compositionRoot: true
@ObjectModel.modelCategory: #BUSINESS_OBJECT
@ObjectModel.representativeKey: 'EHSTaskDefinitionUUID'
// used for BOBF Master Data Object

@ObjectModel.usageType:{ serviceQuality: #C,        // < 15 msec

                         sizeCategory:  #M,         // < 100.000

                         dataClass: #MASTER }

@AbapCatalog.preserveKey: true
@Search.searchable: false
@VDM.viewType: #COMPOSITE
define view I_EHSTaskDefWithDraftUnion
  as select from           I_EHSTaskDefinition
    left outer to one join I_EHSTaskDefinitionDraft as _EHSTaskDefinitionDraft on I_EHSTaskDefinition.EHSTaskDefinitionUUID = _EHSTaskDefinitionDraft.EHSTaskDefinitionActiveUUID
{
  key I_EHSTaskDefinition.EHSTaskDefinitionUUID,
      cast('' as boolean)                      as IsDraftEntity,
      ''                                       as HasActiveEntity,
      _EHSTaskDefinitionDraft.EHSTaskDefinitionActiveUUID,

      I_EHSTaskDefinition.EHSTaskHostObjectInstanceUUID,
      I_EHSTaskDefinition.EHSTaskHostObjectInstance,
      I_EHSTaskDefinition.EHSTaskHostObjectAdapterClass,
      I_EHSTaskDefinition.EHSTaskWorkflowEvent as EHSTaskDefinitionType,
      I_EHSTaskDefinition.EHSTaskPriority,
      I_EHSTaskDefinition.EHSTaskAssignedUser,
      I_EHSTaskDefinition.EHSTaskOwnerUser,
      I_EHSTaskDefinition.EHSTaskApprovingUser,
      I_EHSTaskDefinition.EHSTaskDefinitionStatus,
      I_EHSTaskDefinition.EHSTaskTitle,
      I_EHSTaskDefinition.EHSTaskDescription,

      // Scheduling

      I_EHSTaskDefinition.EHSTaskStartDate,
      I_EHSTaskDefinition.EHSTaskDueInValue,
      I_EHSTaskDefinition.EHSTaskDueInUnit,
      I_EHSTaskDefinition.EHSTaskDueDate,
      I_EHSTaskDefinition.EHSTaskRecurrenceType,
      I_EHSTaskDefinition.EHSTaskIsDueOnSameDay,
      I_EHSTaskDefinition.EHSTaskStartBeforeValue,
      I_EHSTaskDefinition.EHSTaskStartBeforeUnit,
      I_EHSTaskDefinition.EHSTaskRecurrenceIsByDueDate,
      I_EHSTaskDefinition.EHSTaskRecurrenceOffset,
      I_EHSTaskDefinition.EHSTaskIsRecurringOnMonday,
      I_EHSTaskDefinition.EHSTaskIsRecurringOnTuesday,
      I_EHSTaskDefinition.EHSTaskIsRecurringOnWednesday,
      I_EHSTaskDefinition.EHSTaskIsRecurringOnThursday,
      I_EHSTaskDefinition.EHSTaskIsRecurringOnFriday,
      I_EHSTaskDefinition.EHSTaskIsRecurringOnSaturday,
      I_EHSTaskDefinition.EHSTaskIsRecurringOnSunday,
      I_EHSTaskDefinition.EHSTaskRecurrenceWeekDay,
      I_EHSTaskDefinition.EHSTaskRecurrenceInterval,
      I_EHSTaskDefinition.EHSTaskRecurrenceEndType,
      I_EHSTaskDefinition.EHSTaskRecurrenceEndDate,
      I_EHSTaskDefinition.EHSTaskRecurrenceFirstDueDate,
      I_EHSTaskDefinition.EHSTaskRecurrenceDay,
      I_EHSTaskDefinition.EHSTaskRecurrenceMonth,

      // Persons

      I_EHSTaskDefinition.EHSTaskOwnerUser     as EHSTaskOwnerBP,
      I_EHSTaskDefinition.EHSTaskApprovingUser as EHSTaskApprovingBP,
      I_EHSTaskDefinition.EHSTaskAssignedUser  as EHSTaskAssignedBP,
      
      I_EHSTaskDefinition.EHSTaskAssignedLocRole,
      I_EHSTaskDefinition.EHSTaskApproverLocRole,

      I_EHSTaskDefinition.EHSTaskDefinitionIsPaused,
      I_EHSTaskDefinition.EHSLocationUUID,
      I_EHSTaskDefinition.EHSTaskID,
      I_EHSTaskDefinition.EHSTaskMigrationSource,
      I_EHSTaskDefinition.EHSTaskAssignedType,

      /* Associations */
      I_EHSTaskDefinition._CmplncRqmtAuthznFields,
      I_EHSTaskDefinition._EHSCmplncScenAuthznFields,
      I_EHSTaskDefinition._EHSCtrlImplmtnAuthznFields,
      I_EHSTaskDefinition._EHSRskAssessmentAuthznFields,
      I_EHSTaskDefinition._EHSTaskAdapterClass,
      I_EHSTaskDefinition._EHSTaskApprovingUser,
      I_EHSTaskDefinition._EHSTaskAssignedUser,
      I_EHSTaskDefinition._EHSTaskDefinitionExecution,
      I_EHSTaskDefinition._EHSTaskDefinitionMaintenance,
      I_EHSTaskDefinition._EHSTaskDefinitionMoC,
      I_EHSTaskDefinition._EHSTaskDefinitionReference,
      I_EHSTaskDefinition._EHSTaskDefinitionType,
      I_EHSTaskDefinition._EHSTaskDueInUnit,
      I_EHSTaskDefinition._EHSTaskOwnerUser,
      I_EHSTaskDefinition._EHSTaskPlannedInstance,
      I_EHSTaskDefinition._EHSTaskPriority,
      I_EHSTaskDefinition._EHSTaskStartBeforeUnit,
      I_EHSTaskDefinition._IncidentAuthorizationFields,
      I_EHSTaskDefinition._IncidentTaskRefAccRestricted,
      I_EHSTaskDefinition._EHSTaskRecurrenceType,
      I_EHSTaskDefinition._EHSTaskRecurrenceOffset,
      I_EHSTaskDefinition._EHSTaskRecurrenceWeekDay,
      I_EHSTaskDefinition._EHSTaskRecurrenceMonth,
      I_EHSTaskDefinition._EHSTaskRecurrenceEndType
}
where // Filter out definitions which are saved, but now have active draft created by the current user -> we will show the draft record on the UI

     _EHSTaskDefinitionDraft.EHSTaskDefinitionActiveUUID is null
  or _EHSTaskDefinitionDraft.CreatedByUser <> $session.user

union all

select from I_EHSTaskDefinitionDraft
association [0..1] to I_EHSTaskDefinition as _TaskDefinition on I_EHSTaskDefinitionDraft.EHSTaskDefinitionActiveUUID = _TaskDefinition.EHSTaskDefinitionUUID // take the status from task definition

{

  key EHSTaskDefinitionUUID,

      cast('X' as boolean)                                                                                as IsDraftEntity,

      HasActiveEntity,
      EHSTaskDefinitionActiveUUID,

      EHSTaskHostObjectInstanceUUID,
      EHSTaskHostObjectInstance,
      EHSTaskHostObjectAdapterClass,
      EHSTaskWorkflowEvent                                                                                as EHSTaskDefinitionType,
      EHSTaskPriority,
      EHSTaskAssignedUser,
      EHSTaskOwnerUser,
      EHSTaskApprovingUser,
      coalesce(_TaskDefinition.EHSTaskDefinitionStatus, I_EHSTaskDefinitionDraft.EHSTaskDefinitionStatus) as EHSTaskDefinitionStatus,
      EHSTaskTitle,
      EHSTaskDescription,

      // Scheduling

      EHSTaskStartDate,
      EHSTaskDueInValue,
      EHSTaskDueInUnit,
      EHSTaskDueDate,
      EHSTaskRecurrenceType,
      EHSTaskIsDueOnSameDay,
      EHSTaskStartBeforeValue,
      EHSTaskStartBeforeUnit,
      EHSTaskRecurrenceIsByDueDate,
      EHSTaskRecurrenceOffset,
      EHSTaskIsRecurringOnMonday,
      EHSTaskIsRecurringOnTuesday,
      EHSTaskIsRecurringOnWednesday,
      EHSTaskIsRecurringOnThursday,
      EHSTaskIsRecurringOnFriday,
      EHSTaskIsRecurringOnSaturday,
      EHSTaskIsRecurringOnSunday,
      EHSTaskRecurrenceWeekDay,
      EHSTaskRecurrenceInterval,
      EHSTaskRecurrenceEndType,
      EHSTaskRecurrenceEndDate,
      EHSTaskRecurrenceFirstDueDate,
      EHSTaskRecurrenceDay,
      EHSTaskRecurrenceMonth,

      // Persons

      EHSTaskOwnerUser                                                                                    as EHSTaskOwnerBP,
      EHSTaskApprovingUser                                                                                as EHSTaskApprovingBP,
      EHSTaskAssignedUser                                                                                 as EHSTaskAssignedBP,
      
      EHSTaskAssignedLocRole,
      EHSTaskApproverLocRole,

      EHSTaskDefinitionIsPaused,
      EHSLocationUUID,
      EHSTaskID,
      EHSTaskMigrationSource,
      EHSTaskAssignedType,

      /* Associations */
      _CmplncRqmtAuthznFields,
      _EHSCmplncScenAuthznFields,
      _EHSCtrlImplmtnAuthznFields,
      _EHSRskAssessmentAuthznFields,
      _EHSTaskAdapterClass,
      _EHSTaskApprovingUser,
      _EHSTaskAssignedUser,
      _EHSTaskDefinitionExecution,
      _EHSTaskDefinitionMaintenance,
      _EHSTaskDefinitionMoC,
      _EHSTaskDefinitionReference,
      _EHSTaskDefinitionType,
      _EHSTaskDueInUnit,
      _EHSTaskOwnerUser,
      _EHSTaskPlannedInstance,
      _EHSTaskPriority,
      _EHSTaskStartBeforeUnit,
      _IncidentAuthorizationFields,
      _IncidentTaskRefAccRestricted,
      _EHSTaskRecurrenceType,
      _EHSTaskRecurrenceOffset,
      _EHSTaskRecurrenceWeekDay,
      _EHSTaskRecurrenceMonth,
      _EHSTaskRecurrenceEndType
}
where
     I_EHSTaskDefinitionDraft.CreatedByUser = $session.user
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_EHSTASKDEFINITION",
"I_EHSTASKDEFINITIONDRAFT"
],
"ASSOCIATED":
[
"I_BUSINESSUSERBASIC",
"I_CMPLNCRQMTAUTHZNFIELDS",
"I_EHSCMPLNCSCENAUTHZNFIELDS",
"I_EHSCTRLIMPLMTNAUTHZNFIELDS",
"I_EHSRSKASSESSMENTAUTHZNFIELDS",
"I_EHSTASKADAPTERCLASS",
"I_EHSTASKDEFEXECUTION",
"I_EHSTASKDEFINITIONTYPE",
"I_EHSTASKDEFMAINTENANCENOTIF",
"I_EHSTASKDEFMGMTOFCHANGE",
"I_EHSTASKDEFREFERENCE",
"I_EHSTASKDUEINUNIT",
"I_EHSTASKPLANNEDINSTANCE",
"I_EHSTASKPRIORITY",
"I_EHSTASKRECURRENCEENDTYPE",
"I_EHSTASKRECURRENCEMONTH",
"I_EHSTASKRECURRENCEOFFSET",
"I_EHSTASKRECURRENCETYPE",
"I_EHSTASKRECURRENCEWEEKDAY",
"I_EHSTASKSTARTBEFOREUNIT",
"I_INCIDENTCOMBAUTHFIELDS",
"I_INCIDENTTASKREFACCRESTRICTED"
],
"BASE":
[
"I_EHSTASKDEFINITION"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/