I_EHSLocationGeoPoint

DDL: I_EHSLOCATIONGEOPOINT Type: view_entity COMPOSITE

Location map position

I_EHSLocationGeoPoint is a Composite CDS View (Dimension) that provides data about "Location map position" in SAP S/4HANA. It reads from 2 data sources (I_EHSLocationRevision, I_EHSLocationRoot) and exposes 8 fields with key fields EHSLocationID, RevisionEndDate. It has 1 association to related views.

2 data source(s) 8 fields

Data Sources (2)

SourceAliasJoin Type
I_EHSLocationRevision EHSLocationRevision from
I_EHSLocationRoot EHSLocationRoot inner

Associations (1)

CardinalityTargetAliasCondition
[0..*] I_EHSLocNameByIdentifierText _Text EHSLocationRoot.EHSLocationID = _Text.EHSLocationID and EHSLocationRevision.EHSLocationRevisionUUID = _Text.EHSLocationRevisionUUID

Annotations (13)

NameValueLevelField
AccessControl.authorizationCheck #PRIVILEGED_ONLY view
Analytics.dataCategory #DIMENSION view
Analytics.internalName #LOCAL view
Analytics.dataExtraction.enabled false view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.modelingPattern #ANALYTICAL_DIMENSION view
ObjectModel.representativeKey EHSLocationID view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #M view
ObjectModel.usageType.dataClass #MASTER view
EndUserText.label Location map position view
VDM.viewType #COMPOSITE view
Metadata.allowExtensions true view

Fields (8)

KeyFieldSource TableSource FieldDescription
KEY EHSLocationID I_EHSLocationRoot EHSLocationID
KEY RevisionEndDate I_EHSLocationRevision RevisionEndDate
EHSLocationRevisionUUID I_EHSLocationRevision EHSLocationRevisionUUID
RevisionStartDate I_EHSLocationRevision RevisionStartDate
EHSLocationUUID I_EHSLocationRevision EHSLocationUUID
EHSLocationGeoPoint LocGeoPosition EHSLocationGeoPoint
EHSLocationName _Text EHSLocationName
_Text _Text 
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@Analytics: {
dataCategory: #DIMENSION,
              internalName: #LOCAL,
              dataExtraction.enabled: false
}


@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET]
@ObjectModel.representativeKey: 'EHSLocationID'

@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #M,
  dataClass: #MASTER
}



@EndUserText.label: 'Location map position'
@VDM.viewType: #COMPOSITE
@Metadata.allowExtensions:true

define view entity I_EHSLocationGeoPoint


  as select from            I_EHSLocationRevision                         as EHSLocationRevision
    inner join              I_EHSLocationRoot                             as EHSLocationRoot on EHSLocationRoot.EHSLocationUUID = EHSLocationRevision.EHSLocationUUID
    left outer to many join P_EHSLocGeoPosition(P_Mandt: $session.client) as LocGeoPosition  on LocGeoPosition.EHSLocationRevisionUUID = EHSLocationRevision.EHSLocationRevisionUUID
  association [0..*] to I_EHSLocNameByIdentifierText as _Text on  EHSLocationRoot.EHSLocationID               = _Text.EHSLocationID
                                                              and EHSLocationRevision.EHSLocationRevisionUUID = _Text.EHSLocationRevisionUUID
{


         @ObjectModel.text.element: ['EHSLocationName']
  key    EHSLocationRoot.EHSLocationID,
         @Semantics.businessDate.to
  key    EHSLocationRevision.RevisionEndDate,
         EHSLocationRevision.EHSLocationRevisionUUID,
         @Semantics.businessDate.from
         EHSLocationRevision.RevisionStartDate,
         EHSLocationRevision.EHSLocationUUID,

         @Semantics.spatialData.srid.value: '3857'
         @Semantics.spatialData.type: [ #POINT ]
         LocGeoPosition.EHSLocationGeoPoint,
         _Text.EHSLocationName,
         _Text


}

 
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_EHSLOCATIONREVISION",
"I_EHSLOCATIONROOT",
"I_EHSLOCNAMEBYIDENTIFIERTEXT"
],
"ASSOCIATED":
[
"I_EHSLOCNAMEBYIDENTIFIERTEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More