I_EHSLocRespManagerInherited

@AbapCatalog.sqlViewName: 'ILOCRESPMNGRINH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Location Responsible Manager Inherited'

@VDM.viewType: #COMPOSITE

// Client handling by session

@ClientHandling.algorithm: #SESSION_VARIABLE

// used for BOBF Master Data Object

@ObjectModel.usageType:{ serviceQuality: #C,        // < 15 msec

                         sizeCategory:  #M,         // < 100.000

                         dataClass: #MASTER }

//This view returns only location responsible Managers by inheritence

//(excluding direct assignees)


define view I_EHSLocRespManagerInherited
  as select distinct from I_EHSLocRespManager as loc_resp
    inner join            I_EHSLocationHierarchyRevision on  I_EHSLocationHierarchyRevision.RevisionStartDate <= $session.system_date
                                                         and I_EHSLocationHierarchyRevision.RevisionEndDate   >= $session.system_date

  // get all sub location of my location and my location in addition

    inner join            I_EHSLocHierarchyPath          on I_EHSLocHierarchyPath.EHSLocHierarchyRevisionUUID = I_EHSLocationHierarchyRevision.EHSLocHierarchyRevisionUUID
                                                         and(
                                                           I_EHSLocHierarchyPath.EHSParentLocationUUID        = loc_resp.EHSLocationUUID
                                                           or I_EHSLocHierarchyPath.EHSLocationUUID           = loc_resp.EHSLocationUUID
                                                           and I_EHSLocHierarchyPath.EHSParentLocationUUID    = hextobin(
                                                             '00000000000000000000000000000000'
                                                           )
                                                         )

{
  key cast (I_EHSLocHierarchyPath.EHSLocationUUID as ehfnd_location_uuid_ref preserving type ) as EHSLocationUUID,
  key loc_resp.EHSLocationResponsibleUUID,

      loc_resp.EHSLocationPersonRespRole,
      loc_resp.EHSLocResponsibleManagerID

}
where
  loc_resp.EHSLocationUUID <> hextobin( '00000000000000000000000000000000' )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_EHSLOCATIONHIERARCHYREVISION",
"I_EHSLOCHIERARCHYPATH",
"I_EHSLOCRESPMANAGER"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/