I_DueDeferredTaxItemCube

@AbapCatalog.sqlViewName: 'IDUEDEFTXITM'
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'View to display Due Deferred Tax Items'
@AccessControl.personalData.blocking: #NOT_REQUIRED
@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE
@Analytics.dataCategory: #CUBE
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass: #MIXED
@Metadata.allowExtensions: true
@Analytics.internalName:#LOCAL
@AbapCatalog.preserveKey:true
@AbapCatalog.compiler.compareFilter:true

define view I_DueDeferredTaxItemCube
  with parameters
    P_StatryRptgEntity  : srf_reporting_entity,
    P_StatryRptCategory : srf_rep_cat_id,
    P_StatryRptRunID    : srf_report_run_id

  as select from I_StRpTaxReturnBoxCube(
                          P_TaxIsDeferredRelevant: 'Y',
                          P_TaxIsMossRelevant:     'N',
                          P_StatryRptgEntity:      $parameters.P_StatryRptgEntity,
                          P_StatryRptCategory:     $parameters.P_StatryRptCategory,
                          P_StatryRptRunID:        $parameters.P_StatryRptRunID,
                          P_ReportingCountry:      'MX',
                          P_TaxBoxConfiguration:   '1' ) as StRpTaxItemBoxCube

    inner join P_MX_DefTaxDocSupplierDetails as DefTaxTransfer on StRpTaxItemBoxCube.CompanyCode        = DefTaxTransfer.CompanyCode
                                                              and StRpTaxItemBoxCube.AccountingDocument = DefTaxTransfer.AccountingDocument
                                                              and StRpTaxItemBoxCube.FiscalYear         = DefTaxTransfer.FiscalYear

  association [1..1] to I_CompanyCode             as _CompanyCode     on  $projection.CompanyCode = _CompanyCode.CompanyCode

{
  key StRpTaxItemBoxCube.CompanyCode                  as CompanyCode,
  key StRpTaxItemBoxCube.AccountingDocument           as AccountingDocument,
  key cast( StRpTaxItemBoxCube.FiscalYear as fis_gjahr_no_conv preserving type ) as FiscalYear,
  key StRpTaxItemBoxCube.TaxCode                      as TaxCode,
  key StRpTaxItemBoxCube.TaxItem                      as TaxItem,
  key StRpTaxItemBoxCube.TaxBox                       as TaxBox,
  key StRpTaxItemBoxCube.TaxDeclnAmountType           as TaxDeclnAmountType,
      --- Based on T007K/L
  key cast ( case
        when StRpTaxItemBoxCube.TaxItemGroupingVersion is not null and StRpTaxItemBoxCube.TaxItemGroupingVersion <> ''
        then StRpTaxItemBoxCube.TaxItemGroupingVersion
        else left( StRpTaxItemBoxCube.TaxBoxStructureType, 4 )
      end as verstax preserving type )                                       as TaxItemGroupingVersion,
      --- Based on FOT*
  key StRpTaxItemBoxCube.TaxBoxStructureType          as TaxBoxStructureType,
  key StRpTaxItemBoxCube.AccountingDocumentType       as AccountingDocumentType,
  key StRpTaxItemBoxCube.TransactionTypeDetermination as TransactionTypeDetermination,
  key StRpTaxItemBoxCube.StatryRptgEntity             as StatryRptgEntity,
  key StRpTaxItemBoxCube.StatryRptCategory            as StatryRptCategory,
  key StRpTaxItemBoxCube.StatryRptRunID               as StatryRptRunID,

      StRpTaxItemBoxCube.ReportingDate                as ReportingDate,
      StRpTaxItemBoxCube.TaxBoxStrucValidityStartDate as TaxBoxStrucValidityStartDate,
      StRpTaxItemBoxCube.TaxBoxStrucValidityEndDate   as TaxBoxStrucValidityEndDate,
      StRpTaxItemBoxCube.PostingDate                  as PostingDate,
      StRpTaxItemBoxCube.DocumentDate                 as DocumentDate,  
      StRpTaxItemBoxCube.DocumentReferenceID          as DocumentReferenceID,
      StRpTaxItemBoxCube.TaxRate                      as TaxRate,

      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      StRpTaxItemBoxCube.TaxBaseAmountInCoCodeCrcy    as TaxBaseAmountInCoCodeCrcy,

      @Semantics.currencyCode:true
      StRpTaxItemBoxCube.CompanyCodeCurrency          as CompanyCodeCurrency,

      @Semantics.currencyCode:true
      StRpTaxItemBoxCube.DocumentCurrency             as DocumentCurrency,

      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      StRpTaxItemBoxCube.TaxAmountInCoCodeCrcy        as TaxAmountInCoCodeCrcy,

      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      StRpTaxItemBoxCube.TaxBaseAmountInTransCrcy     as TaxBaseAmountInTransCrcy,

      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      StRpTaxItemBoxCube.TaxAmount                    as TaxAmount,

      @Semantics.currencyCode:true
      StRpTaxItemBoxCube.ReportingCurrency            as ReportingCurrency,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      StRpTaxItemBoxCube.TaxBaseAmountInRptgCrcy      as TaxBaseAmountInRptgCrcy,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      StRpTaxItemBoxCube.TaxAmountInRptgCrcy          as TaxAmountInRptgCrcy,

      _CompanyCode.Country                            as Country,

      StRpTaxItemBoxCube.GLAccount                    as GLAccount,
      StRpTaxItemBoxCube.TargetTaxCode                as TargetTaxCode,
      
      DefTaxTransfer.InvoiceNumber                    as TaxInvoiceNumber,
      cast( DefTaxTransfer.InvoiceFiscalYear as fis_gjahr_no_conv preserving type ) as InvoiceReferenceFiscalYear,
      
      DefTaxTransfer.FollowOnDocumentType,
      DefTaxTransfer.BusinessPartnerCountry,
      DefTaxTransfer.BusinessType,
      DefTaxTransfer.TaxNumber1,
      DefTaxTransfer.SupplierRecipientType,
      DefTaxTransfer.BusinessPartnerName,
      DefTaxTransfer.Creditor,
      DefTaxTransfer.TaxNumberResponsible,

      StRpTaxItemBoxCube._AccountingDocument          as _AccountingDocument,
      StRpTaxItemBoxCube._ReceivablesPayablesItem     as _ReceivablesPayablesItem,
      StRpTaxItemBoxCube._ReportedItemsLog            as _ReportedItemsLog,
      _CompanyCode._Country                           as _Country,
      _CompanyCode
}
where
      StRpTaxItemBoxCube.DocumentReferenceID like '_______________'     -- pattern 15 characters long, for performance reasons
  and ( ( DefTaxTransfer.BusinessPartnerCountry =    'MX' and ( StRpTaxItemBoxCube.TaxItemGroupingVersion like 'N%' or StRpTaxItemBoxCube.TaxBoxStructureType like 'N%' ) )
     or ( DefTaxTransfer.BusinessPartnerCountry <>   'MX' and ( StRpTaxItemBoxCube.TaxItemGroupingVersion like 'F%' or StRpTaxItemBoxCube.TaxBoxStructureType like 'F%' ) ) )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"I_STRPTAXRETURNBOXCUBE",
"P_MX_DEFTAXDOCSUPPLIERDETAILS"
],
"ASSOCIATED":
[
"I_ACCOUNTINGDOCUMENT",
"I_COMPANYCODE",
"I_COUNTRY",
"I_OPERATIONALACCTGDOCITEM",
"I_STRPJOURNALENTRYLOG"
],
"BASE":
[
"I_COMPANYCODE",
"I_STRPTAXRETURNBOXCUBE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/