I_DspDocFlwAccountMaintenance

DDL: I_DSPDOCFLWACCOUNTMAINTENANCE SQL: IDDFACCTMAINT Type: view BASIC

Account Maintenance Document

I_DspDocFlwAccountMaintenance is a Basic CDS View that provides data about "Account Maintenance Document" in SAP S/4HANA. It reads from 1 data source (rbkp) and exposes 13 fields with key fields AccountMaintenanceDocument, FiscalYear. It has 3 associations to related views.

1 data source(s) 13 fields

Data Sources (1)

SourceAliasJoin Type
rbkp rbkp from

Associations (3)

CardinalityTargetAliasCondition
[0..1] I_CompanyCode _CompanyCode $projection.CompanyCode = _CompanyCode.CompanyCode
[0..1] I_DspDocFlwAcctMaintFiscalYear _FiscalYear $projection.FiscalYear = _FiscalYear.FiscalYear
[0..1] I_Currency _Currency $projection.DocumentCurrency = _Currency.Currency

Annotations (11)

NameValueLevelField
AbapCatalog.sqlViewName IDDFACCTMAINT view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
ClientHandling.algorithm #SESSION_VARIABLE view
AccessControl.authorizationCheck #CHECK view
AccessControl.personalData.blocking #BLOCKED_DATA_EXCLUDED view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
EndUserText.label Account Maintenance Document view
VDM.viewType #BASIC view

Fields (13)

KeyFieldSource TableSource FieldDescription
KEY AccountMaintenanceDocument rbkp belnr
KEY FiscalYear rbkp gjahr
CompanyCode rbkp bukrs
DocumentDate
PostingDate rbkp budat
CreationDate rbkp cpudt
InvoiceGrossAmount rbkp rmwwr
DocumentCurrency rbkp waers
SuplrInvcTransactionCategory rbkp vgart
IsEndOfPurposeBlocked rbkp iseopblocked
_CompanyCode _CompanyCode
_FiscalYear _FiscalYear
_Currency _Currency 
@AbapCatalog.sqlViewName: 'IDDFACCTMAINT'

@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@ClientHandling.algorithm:#SESSION_VARIABLE

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.semanticKey:['AccountMaintenanceDocument', 'FiscalYear']

@EndUserText.label: 'Account Maintenance Document'

@VDM.viewType: #BASIC

define view I_DspDocFlwAccountMaintenance
  as select from rbkp

  association [0..1] to I_CompanyCode                  as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_DspDocFlwAcctMaintFiscalYear as _FiscalYear  on $projection.FiscalYear = _FiscalYear.FiscalYear
  association [0..1] to I_Currency                     as _Currency    on $projection.DocumentCurrency = _Currency.Currency

{
  key rbkp.belnr                                  as AccountMaintenanceDocument,

      @ObjectModel.foreignKey.association: '_FiscalYear'
  key rbkp.gjahr                                  as FiscalYear,

      @ObjectModel.foreignKey.association: '_CompanyCode'
      rbkp.bukrs                                  as CompanyCode,

      @Semantics.businessDate.at: true
      cast( rbkp.bldat as invdt  preserving type) as DocumentDate,

      @Semantics.businessDate.at: true
      rbkp.budat                                  as PostingDate,
      
      @Semantics.businessDate.createdAt: true
      rbkp.cpudt                                  as CreationDate,

      @Semantics.amount.currencyCode: 'DocumentCurrency'
      @DefaultAggregation:#NONE
      rbkp.rmwwr                                  as InvoiceGrossAmount,

      @ObjectModel.foreignKey.association: '_Currency'
      @Semantics.currencyCode: true
      rbkp.waers                                  as DocumentCurrency,
      
      rbkp.vgart                                  as SuplrInvcTransactionCategory,
      rbkp.iseopblocked                           as IsEndOfPurposeBlocked,

      _CompanyCode,
      _FiscalYear,
      _Currency
}
where
  (
       vgart = 'KP' // Account maintenance

    or vgart = 'KS' // Account maintenance reversal

  )
  and  rbkp.rbstat != '2' // excluding deleted documents

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"RBKP"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_CURRENCY",
"I_DSPDOCFLWACCTMAINTFISCALYEAR"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More