I_DocumentInfoRecordDescTP

@AbapCatalog.sqlViewName: 'ICVDOCDESCTP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'DocumentInfoRecdDescriptionTransactional'
@ObjectModel.representativeKey:'DocumentInfoRecordDocType'
@ObjectModel.dataCategory: #TEXT
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

@ObjectModel.usageType: { serviceQuality: #A, sizeCategory: #L, dataClass: #TRANSACTIONAL }
@ObjectModel.writeDraftPersistence:'DRAT_DRAFT'
@ObjectModel.draftEnabled:  true
@ObjectModel.createEnabled: true
@ObjectModel.updateEnabled: true
@ObjectModel.deleteEnabled: true

@ClientHandling.algorithm: #SESSION_VARIABLE
@ClientHandling.type: #INHERITED
 
define view I_DocumentInfoRecordDescTP
  as select from I_DocumentInfoRecordDesc as Desc
 
  --Get Document Type Association
  association [1..1] to I_DocumentInfoRecordDocType    as _DocType         on  $projection.DocumentInfoRecordDocType = _DocType.DocumentInfoRecordDocType

  --Get Document Number Association
  association [0..1] to I_DocumentInfoRecordDocNumber  as _DocNumber       on  $projection.DocumentInfoRecordDocType   = _DocNumber.DocumentInfoRecordDocType
                                                                           and $projection.DocumentInfoRecordDocNumber = _DocNumber.DocumentInfoRecordDocNumber
  --Get Document Part Association
  association [0..1] to I_DocumentInfoRecordDocPrt     as _DocPart         on  $projection.DocumentInfoRecordDocType    = _DocPart.DocumentInfoRecordDocType
                                                                           and $projection.DocumentInfoRecordDocPart    = _DocPart.DocumentInfoRecordDocPart
                                                                           and $projection.DocumentInfoRecordDocNumber  = _DocPart.DocumentInfoRecordDocNumber
                                                                           and $projection.DocumentInfoRecordDocVersion = _DocPart.DocumentInfoRecordDocVersion

  --Get Document Version Association
  association [0..1] to I_DocumentInfoRecordDocVersion as _DocVersion      on  $projection.DocumentInfoRecordDocType    = _DocVersion.DocumentInfoRecordDocType
                                                                           and $projection.DocumentInfoRecordDocNumber  = _DocVersion.DocumentInfoRecordDocNumber
                                                                           and $projection.DocumentInfoRecordDocVersion = _DocVersion.DocumentInfoRecordDocVersion

  association [0..1] to I_Language                     as _Language        on  $projection.Language = _Language.Language

  association [0..1] to I_Language                     as _LanguageForEdit on  _LanguageForEdit.LanguageISOCode = $projection.LanguageForEdit
                                                                           and _LanguageForEdit.Language = $projection.Language 

  association [1..1] to I_DocumentInfoRecordTP         as _DocInfo         on  $projection.DocumentInfoRecordDocType    = _DocInfo.DocumentInfoRecordDocType
                                                                           and $projection.DocumentInfoRecordDocNumber  = _DocInfo.DocumentInfoRecordDocNumber
                                                                           and $projection.DocumentInfoRecordDocVersion = _DocInfo.DocumentInfoRecordDocVersion
                                                                           and $projection.DocumentInfoRecordDocPart    = _DocInfo.DocumentInfoRecordDocPart

{
      @ObjectModel.foreignKey.association: '_DocType'
  key Desc.DocumentInfoRecordDocType      as DocumentInfoRecordDocType,
      @ObjectModel.foreignKey.association: '_DocNumber'
  key Desc.DocumentInfoRecordDocNumber    as DocumentInfoRecordDocNumber,
      @ObjectModel.foreignKey.association: '_DocVersion'
  key Desc.DocumentInfoRecordDocVersion   as DocumentInfoRecordDocVersion,
      @ObjectModel.foreignKey.association: '_DocPart'
  key Desc.DocumentInfoRecordDocPart      as DocumentInfoRecordDocPart,
      @Semantics.language: true
      @ObjectModel.foreignKey.association: '_Language'
  key Desc.Language                       as Language,
 
    // @ObjectModel.updateEnabled: true

      @ObjectModel: {
       enabled:   'EXTERNAL_CALCULATION',
       readOnly:  'EXTERNAL_CALCULATION',
       mandatory: 'EXTERNAL_CALCULATION'
       }
      @ObjectModel.foreignKey.association: '_LanguageForEdit'
      @Semantics.language:false
      _Language.LanguageISOCode             as LanguageForEdit,

   //  @ObjectModel.updateEnabled: true

      @ObjectModel: {
       enabled:   'EXTERNAL_CALCULATION',
       readOnly:  'EXTERNAL_CALCULATION',
       mandatory: 'EXTERNAL_CALCULATION'
       }      
      @Semantics.text: true
      Desc.DocumentDescription            as DocumentDescription,
      Desc.LongTextExists                 as LongTextExists,

      _DocNumber,
      _DocPart,
      _DocType,
      _DocVersion,
      _Language,
      _LanguageForEdit,

      @ObjectModel.association.type:  [#TO_COMPOSITION_ROOT, #TO_COMPOSITION_PARENT]
      _DocInfo
      

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_DOCUMENTINFORECORDDESC",
"I_LANGUAGE"
],
"ASSOCIATED":
[
"I_DOCUMENTINFORECORDDOCNUMBER",
"I_DOCUMENTINFORECORDDOCPRT",
"I_DOCUMENTINFORECORDDOCTYPE",
"I_DOCUMENTINFORECORDDOCVERSION",
"I_DOCUMENTINFORECORDTP",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/