I_DocInfoRecdObjectLink

@AbapCatalog.sqlViewName: 'ICVDOCOBJLINK'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE
//@ObjectModel.representativeKey:'LinkedSAPObjectKey'

@Metadata.allowExtensions: true
@Analytics: { dataCategory: #DIMENSION, dataExtraction.enabled: true }
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #MIXED}
@EndUserText.label: 'Document Info Record Object Link Details'
@VDM.lifecycle: {
  contract: {
    type: #SAP_INTERNAL_API
  },
  status: #DEPRECATED,
  successor: 'I_DocumentInfoRecordObjectLink'
}
@Metadata.ignorePropagatedAnnotations:true 
define view I_DocInfoRecdObjectLink
  as select from    P_DocInfoRecdObjectLink as ObjectLinks
    left outer join drad_last_change        as LastChange on  ObjectLinks.DocumentType       = LastChange.dokar
                                                          and ObjectLinks.DocumentInfoRecord = LastChange.doknr
                                                          and ObjectLinks.DocumentVersion    = LastChange.dokvr
                                                          and ObjectLinks.DocumentPart       = LastChange.doktl
                                                          and ObjectLinks.LinkedSAPObject    = LastChange.dokob
                                                          and ObjectLinks.LinkedSAPObjectKey = LastChange.objky
  --Get Document Type Association
  association [1..1] to I_DocInfoRecdDocumentType     as _DocumentType            on  $projection.DocumentType = _DocumentType.DocumentType

  --Get Document Number Association
  association [1..1] to I_DocInfoRecdNumber           as _DocumentNumber          on  $projection.DocumentType       = _DocumentNumber.DocumentType
                                                                                  and $projection.DocumentInfoRecord = _DocumentNumber.DocumentInfoRecord

  --Get Document Version Association
  association [1..1] to I_DocInfoRecdDocumentVersion  as _DocumentVersion         on  $projection.DocumentType       = _DocumentVersion.DocumentType
                                                                                  and $projection.DocumentInfoRecord = _DocumentVersion.DocumentInfoRecord
                                                                                  and $projection.DocumentVersion    = _DocumentVersion.DocumentVersion

  --Get Document Part Association
  association [1..1] to I_DocInfoRecdDocumentPart     as _DocumentPart            on  $projection.DocumentPart       = _DocumentPart.DocumentPart
                                                                                  and $projection.DocumentType       = _DocumentPart.DocumentType
                                                                                  and $projection.DocumentInfoRecord = _DocumentPart.DocumentInfoRecord
                                                                                  and $projection.DocumentVersion    = _DocumentPart.DocumentVersion

  --Get Document type description
  association [0..*] to I_DocInfoRecdDocumentTypeText as _DocumentTypeDescription on  $projection.DocumentType = _DocumentTypeDescription.DocumentType

  --Get Linked object description
  association [0..*] to I_DocInfoRecdObjectLinkText   as _LinkedObjectDesc        on  $projection.LinkedSAPObject = _LinkedObjectDesc.LinkedSAPObject

  //  --Get DIR created user full name

  //  association [0..1] to I_User                        as _CreatedUser             on  $projection.CreatedByUser = _CreatedUser.UserID

  //

  //  --Get DIR changed user full name

  //  association [0..1] to I_User                        as _ChangedUser             on  $projection.ChangedBy = _ChangedUser.UserID


  --Get DocumentInfoRecord created user value help
  association [1..1] to I_DocumentInfoRecordUserVH    as _CreatedUser             on  $projection.DocumentType       = _CreatedUser.DocumentInfoRecordDocType
                                                                                  and $projection.DocumentPart       = _CreatedUser.DocumentInfoRecordDocPart
                                                                                  and $projection.DocumentInfoRecord = _CreatedUser.DocumentInfoRecordDocNumber
                                                                                  and $projection.DocumentVersion    = _CreatedUser.DocumentInfoRecordDocVersion
                                                                                  and $projection.CreatedByUser      = _CreatedUser.ResponsiblePersonName

  --Get DocumentInfoRecord changed user value help
  association [1..1] to I_DocumentInfoRecordUserVH    as _ChangedUser             on  $projection.DocumentType       = _ChangedUser.DocumentInfoRecordDocType
                                                                                  and $projection.DocumentPart       = _ChangedUser.DocumentInfoRecordDocPart
                                                                                  and $projection.DocumentInfoRecord = _ChangedUser.DocumentInfoRecordDocNumber
                                                                                  and $projection.DocumentVersion    = _ChangedUser.DocumentInfoRecordDocVersion
                                                                                  and $projection.ChangedBy          = _ChangedUser.LastChangedByUser

{

      @ObjectModel.text.element: 'LinkedSAPObjectKey'
  key ObjectLinks.LinkedSAPObjectKey             as LinkedSAPObjectKey,
      @ObjectModel.foreignKey.association: '_DocumentType'
  key ObjectLinks.DocumentType                   as DocumentType,
      @ObjectModel.foreignKey.association: '_DocumentNumber'
  key ObjectLinks.DocumentInfoRecord             as DocumentInfoRecord,
      @ObjectModel.foreignKey.association: '_DocumentPart'
  key ObjectLinks.DocumentPart                   as DocumentPart,
      @ObjectModel.foreignKey.association: '_DocumentVersion'
  key ObjectLinks.DocumentVersion                as DocumentVersion,

      @ObjectModel.text.association: '_LinkedObjectDesc'
      //@ObjectModel.foreignKey.association: '_LinkedObjectDesc'

  key ObjectLinks.LinkedSAPObject                as LinkedSAPObject,

      ObjectLinks.DocObjectLinkCounter           as DocObjectLinkCounter,

      /* DIR Administrative Data */
      @Semantics.businessDate.createdAt: true
      LastChange.created_at                      as CreationDateTime,

      @Consumption.valueHelpDefinition.association: '_CreatedUser'
      @Semantics.user.createdBy: true
      LastChange.created_by                      as CreatedByUser,

      @Semantics.businessDate.at: true
      @Semantics.businessDate.lastChangedAt: true
      LastChange.changed_at                      as ChangedDateTime,

      @Consumption.valueHelpDefinition.association: '_ChangedUser'
      @Semantics.user.lastChangedBy: true
      LastChange.changed_by                      as ChangedBy,

      /* Miscallenous  Data */
      ObjectLinks.DocInfoRecdLinkStatus          as DocInfoRecdLinkStatus,
      ObjectLinks.DocInfoRecdObjectLinkStatus    as DocInfoRecdObjectLinkStatus,
      ObjectLinks.ObjectTypeDatabaseTable        as ObjectTypeDatabaseTable,
      ObjectLinks.DocInfoRecdAdditionalObjectKey as DocInfoRecdAdditionalObjectKey,
      ObjectLinks.DocLinkDirectionIsActive       as DocLinkDirectionIsActive,
      ObjectLinks.IsDefaultDocument              as IsDefaultDocument,

      @EndUserText.label:'Deletion Indicator'
      ObjectLinks.DocInfoRecdIsDeleted           as DocInfoRecdIsMarkedForDeletion,
      ObjectLinks.DocInfoRecdLongTextUUID        as DocInfoRecdLongTextUUID,

      @EndUserText.label:'CAD Indicator'
      ObjectLinks.DocumentIsCreatedByCAD         as DocumentIsCreatedByCAD,
      ObjectLinks.DocInfoRecdConfignMgmtFixed    as DocInfoRecdConfignMgmtFixed,

      /* Associations */
      _DocumentTypeDescription,
      _LinkedObjectDesc,
      _CreatedUser,
      _ChangedUser,
      _DocumentNumber,
      _DocumentType,
      _DocumentVersion,
      _DocumentPart
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_DOCINFORECDOBJECTLINK",
"DRAD_LAST_CHANGE"
],
"ASSOCIATED":
[
"I_DOCINFORECDDOCUMENTPART",
"I_DOCINFORECDDOCUMENTTYPE",
"I_DOCINFORECDDOCUMENTTYPETEXT",
"I_DOCINFORECDDOCUMENTVERSION",
"I_DOCINFORECDNUMBER",
"I_DOCINFORECDOBJECTLINKTEXT",
"I_DOCUMENTINFORECORDUSERVH"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/