I_DocInfoRecdDescription

@AbapCatalog.sqlViewName:'ICVDOCINFRECDESC'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.dataCategory: #TEXT
@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey:'DocumentDescription'
@Analytics: { dataExtraction.enabled: true }
@ObjectModel.usageType: { serviceQuality: #A, sizeCategory: #L, dataClass: #TRANSACTIONAL }
@EndUserText.label: 'Document Info Record Description'
@Search.searchable: true
@VDM.lifecycle: {
  contract: {
    type: #PUBLIC_LOCAL_API
  },
  status: #DEPRECATED,
  successor: 'I_DocumentInfoRecordDesc'
}
@Metadata.ignorePropagatedAnnotations:true

define view I_DocInfoRecdDescription
  as select from drat as documentdesc

  --Get Document Type Association
  association [1..1] to I_DocInfoRecdDocumentType    as _DocumentType    on  $projection.DocumentType = _DocumentType.DocumentType

  --Get Document Number Association
  association [1..1] to I_DocInfoRecdNumber          as _DocumentNumber  on  $projection.DocumentType       = _DocumentNumber.DocumentType
                                                                         and $projection.DocumentInfoRecord = _DocumentNumber.DocumentInfoRecord
  --Get Document Part Association
  association [1..1] to I_DocInfoRecdDocumentPart    as _DocumentPart    on  $projection.DocumentType       = _DocumentPart.DocumentType
                                                                         and $projection.DocumentPart       = _DocumentPart.DocumentPart
                                                                         and $projection.DocumentInfoRecord = _DocumentPart.DocumentInfoRecord
                                                                         and $projection.DocumentVersion    = _DocumentPart.DocumentVersion

  --Get Document Version Association
  association [1..1] to I_DocInfoRecdDocumentVersion as _DocumentVersion on  $projection.DocumentType       = _DocumentVersion.DocumentType
                                                                         and $projection.DocumentInfoRecord = _DocumentVersion.DocumentInfoRecord
                                                                         and $projection.DocumentVersion    = _DocumentVersion.DocumentVersion

  association [1..1] to I_Language                   as _Language        on  $projection.Language = _Language.Language

{
            @ObjectModel.foreignKey.association: '_DocumentType'
  key       documentdesc.dokar  as DocumentType,

            @ObjectModel.foreignKey.association: '_DocumentNumber'
  key       documentdesc.doknr  as DocumentInfoRecord,

            @ObjectModel.foreignKey.association: '_DocumentVersion'
  key       documentdesc.dokvr  as DocumentVersion,

            @ObjectModel.foreignKey.association: '_DocumentPart'
  key       documentdesc.doktl  as DocumentPart,

            @UI.hidden: true
            @Semantics.language: true
            @ObjectModel.foreignKey.association: '_Language'
  key       documentdesc.langu  as Language,

            @Semantics.text: true
            @EndUserText.label:'Document Description'
            @Search.defaultSearchElement: true 
            @Search.ranking: #HIGH
            @Search.fuzzinessThreshold: 0.8           
  key       documentdesc.dktxt  as DocumentDescription,

            @UI.hidden: true
            documentdesc.ltxin  as LongTextExists,

            // DMS: short texts in capital letters

            @UI.hidden: true
            @EndUserText.label:'Document Short Description'
            documentdesc.dktxt_uc as DocInfoRecdShortText,

            // Associations

            _Language,
            _DocumentType,
            _DocumentVersion,
            _DocumentPart,
            _DocumentNumber


} 
//where

  //documentdesc.langu = $session.system_language

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DRAT"
],
"ASSOCIATED":
[
"I_DOCINFORECDDOCUMENTPART",
"I_DOCINFORECDDOCUMENTTYPE",
"I_DOCINFORECDDOCUMENTVERSION",
"I_DOCINFORECDNUMBER",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/