I_DisplayCostRate

@AbapCatalog.sqlViewName: 'IDISPCOSTRATE'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Display Cost Rate'
@ClientHandling: {
  type:      #CLIENT_DEPENDENT,
  algorithm: #SESSION_VARIABLE
}
@VDM.viewType: #BASIC
@ObjectModel.usageType: {
        sizeCategory: #L,
        serviceQuality: #C,
        dataClass: #TRANSACTIONAL
    }

define view I_DisplayCostRate
  as select from            P_AccountingCostRate as _CostRate
    join                    I_CompanyCode        as _CompanyCode on _CompanyCode.CompanyCode = _CostRate.CompanyCode
    join                    I_FiscalYearPeriod   as _Period      on  _Period.FiscalYearVariant   =  _CompanyCode.FiscalYearVariant
                                                                 and _CostRate.ValidityStartDate <= _Period.FiscalPeriodEndDate
                                                                 and _CostRate.ValidityEndDate   >= _Period.FiscalPeriodEndDate
                                                                 and _Period.IsSpecialPeriod = ''
{
  key _CostRate.PlanningCategory,
  key _CostRate.BusinessTransactionType,
  key _CostRate.Ledger                                                                         as Ledger,
  key _Period.FiscalYear                                                                       as FiscalYear,
  key _Period.FiscalPeriod                                                                     as FiscalPeriod,
  key _CostRate.ControllingArea,
  key _CostRate.CompanyCode,
  key _CostRate.CostCenter,
  key _CostRate.ActivityType,
  key _CostRate.IsIntercompanyRate,
  key _CostRate.TimeSheetOvertimeCategory,
  key _CostRate.ReceivingCompanyCode,
  key _CostRate.ServiceCostLevel,
  key _CostRate.PersonnelNumber,
  key cast(_CostRate.WBSElementExternalID as ps_posid_edit) as WBSElementExternalID,
  key _CostRate.WorkItem,
  
      cast(_CostRate.WBSElementInternalID as ps_s4_pspnr) as WBSElementInternalID, 
      _CostRate.CostCtrActivityTypeQtyUnit,
      cast( _CostRate.CostRateTotalAmount as fins_vwcur12 )                                              as CostRateTotalAmountInTransCrcy,
      cast( _CostRate.CostRateFixedAmount as fins_vwcur12 )                                              as CostRateFixedAmountInTransCrcy,
      cast( _CostRate.CostRateTotalAmount - _CostRate.CostRateFixedAmount as fins_vwcur12 )                        as CostRateVarblAmountInTransCrcy,
      _CostRate.Currency                                                                       as TransactionCurrency,
      _CostRate.CostRateScaleFactor,
      cast( _CostRate.CostRateScaleFactor as fco_rate_scale_factor)                                      as CostRateFactor,
      _CostRate.ValidityStartDate,
      _CostRate.ValidityEndDate,
      cast((concat( _CostRate.ValidityStartFiscalYear, _CostRate.ValidityStartFiscalPeriod )) as fins_fyearperiod) as FromFiscalYearPeriod,
      cast((concat( _CostRate.ValidityEndFiscalYear, _CostRate.ValidityEndFiscalPeriod )) as fins_fyearperiod)     as ToFiscalYearPeriod,
      cast((concat( _Period.FiscalYear, _Period.FiscalPeriod )) as fins_fyearperiod)           as FiscalYearPeriod
}

where
       _CostRate.CostRateIsDeleted       = '' //only trans. curr.

  and  _CostRate.CurrencyRole            = '00'
  and(
       _CostRate.BusinessTransactionType = 'MSCR' //Manual Service Cost Rate

    or _CostRate.BusinessTransactionType = 'MPCR' //Plan Cost Rate

    or _CostRate.BusinessTransactionType = 'AACR' //Activity-based Actual Cost Rate

    or _CostRate.BusinessTransactionType = 'MACR' //Actual Cost Rate

  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"I_FISCALYEARPERIOD",
"P_ACCOUNTINGCOSTRATE"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/