I_DigitalVehiclePurOrderItem

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Vehicle Purchase Order'
@ObjectModel: {
    usageType: {
        sizeCategory: #XXL,
        serviceQuality: #C,
        dataClass:#MIXED
    },
      semanticKey: ['PurchasingDocument' , 'PurchaseOrderItem']
}
@VDM.viewType: #COMPOSITE
@Metadata.ignorePropagatedAnnotations:true
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
define view entity I_DigitalVehiclePurOrderItem
  as select from I_VMSVehicle             as _VMSVehicle  
    inner join   I_PurgDocScheduleLine    as _PurgDocScheduleLine    on _VMSVehicle.VMSVehicleBatch = _PurgDocScheduleLine.Batch
    inner join   I_PurchasingDocument     as _PurchasingDocument     on _PurgDocScheduleLine.PurchasingDocument = _PurchasingDocument.PurchasingDocument
    inner join   I_PurchasingDocumentItem as _PurchasingDocumentItem on _PurgDocScheduleLine.PurchasingDocument = _PurchasingDocumentItem.PurchasingDocument
                                                                    and _PurgDocScheduleLine.PurchasingDocumentItem = _PurchasingDocumentItem.PurchasingDocumentItem
  association to I_Plant as _plant on _plant.Plant = $projection.Plant
  association [1..1] to I_BusinessPartner         as _BusinessPartner     on _BusinessPartner.BusinessPartner = $projection.Supplier
  association [1..1] to I_DigitalVehPurOrdConfign as _DigitalVehPurOrdConfign on  _DigitalVehPurOrdConfign.PurchasingDocument = $projection.PurchasingDocument
                                                                              and _DigitalVehPurOrdConfign.PurchaseOrderItem = $projection.PurchaseOrderItem
{

  key  _PurchasingDocument.PurchasingDocument, 
  key  _PurchasingDocumentItem.PurchasingDocumentItem as PurchaseOrderItem,
       _VMSVehicle.VMSVehicleUUID,
       _VMSVehicle.VMSVehicleBatch,
       _PurchasingDocument.PurchasingDocumentType as PurchaseOrderType,
       _PurchasingDocument.CreationDate as PurchaseOrderDate, 
       _PurchasingDocument.Supplier,
       _PurchasingDocument.CompanyCode,
       _PurchasingDocument._CompanyCode.CompanyCodeName,
       _PurchasingDocument.PurchasingOrganization,
       _PurchasingDocument._PurchasingOrganization.PurchasingOrganizationName,
       _PurchasingDocument.PurchasingGroup,
       _PurchasingDocument._PurchasingGroup.PurchasingGroupName,
       _PurgDocScheduleLine.ScheduleLineDeliveryDate,
       _PurchasingDocumentItem.Plant,
       @Semantics.text:true
       _plant.PlantName,
       _PurchasingDocumentItem.Material,
       _PurchasingDocumentItem.OrderQuantityUnit as PurchaseOrderQuantityUnit,
       @Semantics.quantity.unitOfMeasure:'PurchaseOrderQuantityUnit'
       _PurchasingDocumentItem.OrderQuantity,
       @Semantics.amount.currencyCode: 'DocumentCurrency'
       _PurchasingDocumentItem.NetPriceAmount,
       _PurchasingDocumentItem.DocumentCurrency       as DocumentCurrency,
       _PurchasingDocumentItem.TaxCode,
       _DigitalVehPurOrdConfign.ConfigurationNumber,
       _VMSVehicle.DigitalVehicleReferenceID,
       _BusinessPartner


}
where
      _VMSVehicle.VMSVehicleBatch       is not initial
  and _PurgDocScheduleLine.ScheduleLine = '0001'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"I_DIGITALVEHPURORDCONFIGN",
"I_PLANT",
"I_PURCHASINGDOCUMENT",
"I_PURCHASINGDOCUMENTITEM",
"I_PURCHASINGGROUP",
"I_PURCHASINGORGANIZATION",
"I_PURGDOCSCHEDULELINE",
"I_VMSVEHICLE"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/